开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
entry.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：10k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

entry.S：源码内容
  1. /*
  2.  * BK Id: SCCS/s.entry.S 1.26 01/25/02 15:15:24 benh
  3.  */
  4. /*
  5.  *  PowerPC version 
  6.  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
  7.  *  Rewritten by Cort Dougan (cort@fsmlabs.com) for PReP
  8.  *    Copyright (C) 1996 Cort Dougan <cort@fsmlabs.com>
  9.  *  Adapted for Power Macintosh by Paul Mackerras.
  10.  *  Low-level exception handlers and MMU support
  11.  *  rewritten by Paul Mackerras.
  12.  *    Copyright (C) 1996 Paul Mackerras.
  13.  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  14.  *
  15.  *  This file contains the system call entry code, context switch
  16.  *  code, and exception/interrupt return code for PowerPC.
  17.  *
  18.  *  This program is free software; you can redistribute it and/or
  19.  *  modify it under the terms of the GNU General Public License
  20.  *  as published by the Free Software Foundation; either version
  21.  *  2 of the License, or (at your option) any later version.
  22.  *
  23.  */
  25. #include "ppc_asm.h"
  26. #include <linux/config.h>
  27. #include <linux/errno.h>
  28. #include <linux/sys.h>
  29. #include <linux/threads.h>
  30. #include <asm/processor.h>
  31. #include <asm/page.h>
  32. #include <asm/mmu.h>
  33. #include <asm/cputable.h>
  35. #undef SHOW_SYSCALLS
  36. #undef SHOW_SYSCALLS_TASK
  38. #ifdef SHOW_SYSCALLS_TASK
  39. .data
  40. show_syscalls_task:
  41. .long -1
  42. #endif
  44. /*
  45.  * Handle a system call.
  46.  */
  47. .text
  48. _GLOBAL(DoSyscall)
  49. stw r0,THREAD+LAST_SYSCALL(r2)
  50. lwz r11,_CCR(r1) /* Clear SO bit in CR */
  51. lis r10,0x1000
  52. andc r11,r11,r10
  53. stw r11,_CCR(r1)
  54. #ifdef SHOW_SYSCALLS
  55. #ifdef SHOW_SYSCALLS_TASK
  56. lis r31,show_syscalls_task@ha
  57. lwz r31,show_syscalls_task@l(r31)
  58. cmp 0,r2,r31
  59. bne 1f
  60. #endif
  61. lis r3,7f@ha
  62. addi r3,r3,7f@l
  63. lwz r4,GPR0(r1)
  64. lwz r5,GPR3(r1)
  65. lwz r6,GPR4(r1)
  66. lwz r7,GPR5(r1)
  67. lwz r8,GPR6(r1)
  68. lwz r9,GPR7(r1)
  69. bl printk
  70. lis r3,77f@ha
  71. addi r3,r3,77f@l
  72. lwz r4,GPR8(r1)
  73. lwz r5,GPR9(r1)
  74. mr r6,r2
  75. bl printk
  76. lwz r0,GPR0(r1)
  77. lwz r3,GPR3(r1)
  78. lwz r4,GPR4(r1)
  79. lwz r5,GPR5(r1)
  80. lwz r6,GPR6(r1)
  81. lwz r7,GPR7(r1)
  82. lwz r8,GPR8(r1)
  83. 1:
  84. #endif /* SHOW_SYSCALLS */
  85. cmpi 0,r0,0x7777 /* Special case for 'sys_sigreturn' */
  86. beq- 10f
  87. cmpi    0,r0,0x6666     /* Special case for 'sys_rt_sigreturn' */
  88. beq-    16f
  89. lwz r10,TASK_PTRACE(r2)
  90. andi. r10,r10,PT_TRACESYS
  91. bne- 50f
  92. cmpli 0,r0,NR_syscalls
  93. bge- 66f
  94. lis r10,sys_call_table@h
  95. ori r10,r10,sys_call_table@l
  96. slwi r0,r0,2
  97. lwzx r10,r10,r0 /* Fetch system call handler [ptr] */
  98. cmpi 0,r10,0
  99. beq- 66f
  100. mtlr r10
  101. addi r9,r1,STACK_FRAME_OVERHEAD
  102. blrl /* Call handler */
  103. .globl ret_from_syscall_1
  104. ret_from_syscall_1:
  105. 20: stw r3,RESULT(r1) /* Save result */
  106. #ifdef SHOW_SYSCALLS
  107. #ifdef SHOW_SYSCALLS_TASK
  108. cmp 0,r2,r31
  109. bne 91f
  110. #endif
  111. mr r4,r3
  112. lis r3,79f@ha
  113. addi r3,r3,79f@l
  114. bl printk
  115. lwz r3,RESULT(r1)
  116. 91:
  117. #endif
  118. li r10,-_LAST_ERRNO
  119. cmpl 0,r3,r10
  120. blt 30f
  121. neg r3,r3
  122. cmpi 0,r3,ERESTARTNOHAND
  123. bne 22f
  124. li r3,EINTR
  125. 22: lwz r10,_CCR(r1) /* Set SO bit in CR */
  126. oris r10,r10,0x1000
  127. stw r10,_CCR(r1)
  128. 30: stw r3,GPR3(r1) /* Update return value */
  129. b ret_from_except
  130. 66: li r3,ENOSYS
  131. b 22b
  132. /* sys_sigreturn */
  133. 10: addi r3,r1,STACK_FRAME_OVERHEAD
  134. bl sys_sigreturn
  135. cmpi    0,r3,0          /* Check for restarted system call */
  136. bge     ret_from_except
  137. b       20b
  138. /* sys_rt_sigreturn */
  139. 16: addi    r3,r1,STACK_FRAME_OVERHEAD
  140. bl      sys_rt_sigreturn
  141. cmpi 0,r3,0 /* Check for restarted system call */
  142. bge ret_from_except
  143. b 20b
  144. /* Traced system call support */
  145. 50: bl syscall_trace
  146. lwz r0,GPR0(r1) /* Restore original registers */
  147. lwz r3,GPR3(r1)
  148. lwz r4,GPR4(r1)
  149. lwz r5,GPR5(r1)
  150. lwz r6,GPR6(r1)
  151. lwz r7,GPR7(r1)
  152. lwz r8,GPR8(r1)
  153. lwz r9,GPR9(r1)
  154. cmpli 0,r0,NR_syscalls
  155. bge- 66f
  156. lis r10,sys_call_table@h
  157. ori r10,r10,sys_call_table@l
  158. slwi r0,r0,2
  159. lwzx r10,r10,r0 /* Fetch system call handler [ptr] */
  160. cmpi 0,r10,0
  161. beq- 66f
  162. mtlr r10
  163. addi r9,r1,STACK_FRAME_OVERHEAD
  164. blrl /* Call handler */
  165. .globl ret_from_syscall_2
  166. ret_from_syscall_2:
  167. stw r3,RESULT(r1) /* Save result */
  168. stw r3,GPR0(r1) /* temporary gross hack to make strace work */
  169. li r10,-_LAST_ERRNO
  170. cmpl 0,r3,r10
  171. blt 60f
  172. neg r3,r3
  173. cmpi 0,r3,ERESTARTNOHAND
  174. bne 52f
  175. li r3,EINTR
  176. 52: lwz r10,_CCR(r1) /* Set SO bit in CR */
  177. oris r10,r10,0x1000
  178. stw r10,_CCR(r1)
  179. 60: stw r3,GPR3(r1) /* Update return value */
  180. bl syscall_trace
  181. b ret_from_except
  182. 66: li r3,ENOSYS
  183. b 52b
  184. #ifdef SHOW_SYSCALLS
  185. 7: .string "syscall %d(%x, %x, %x, %x, %x, "
  186. 77: .string "%x, %x), current=%pn"
  187. 79: .string " -> %xn"
  188. .align 2,0
  189. #endif
  191. /*
  192.  * This routine switches between two different tasks.  The process
  193.  * state of one is saved on its kernel stack.  Then the state
  194.  * of the other is restored from its kernel stack.  The memory
  195.  * management hardware is updated to the second process's state.
  196.  * Finally, we can return to the second process.
  197.  * On entry, r3 points to the THREAD for the current task, r4
  198.  * points to the THREAD for the new task.
  199.  *
  200.  * Note: there are two ways to get to the "going out" portion
  201.  * of this code; either by coming in via the entry (_switch)
  202.  * or via "fork" which must set up an environment equivalent
  203.  * to the "_switch" path.  If you change this , you'll have to
  204.  * change the fork code also.
  205.  *
  206.  * The code which creates the new task context is in 'copy_thread'
  207.  * in arch/ppc/kernel/process.c
  208.  */
  209. _GLOBAL(_switch)
  210. stwu r1,-INT_FRAME_SIZE(r1)
  211. stw r0,GPR0(r1)
  212. lwz r0,0(r1)
  213. stw r0,GPR1(r1)
  214. /* r3-r13 are caller saved -- Cort */
  215. SAVE_GPR(2, r1)
  216. SAVE_8GPRS(14, r1)
  217. SAVE_10GPRS(22, r1)
  218. mflr r20 /* Return to switch caller */
  219. stw r20,INT_FRAME_SIZE+4(r1)
  220. mfmsr r22
  221. li r0,MSR_FP /* Disable floating-point */
  222. #ifdef CONFIG_ALTIVEC
  223. BEGIN_FTR_SECTION
  224. oris r0,r0,MSR_VEC@h /* Disable altivec */
  225. END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
  226. #endif /* CONFIG_ALTIVEC */
  227. and. r0,r0,r22 /* FP or altivec enabled? */
  228. beq+ 1f
  229. andc r22,r22,r0
  230. mtmsr r22
  231. isync
  232. 1: stw r20,_NIP(r1)
  233. stw r22,_MSR(r1)
  234. stw r20,_LINK(r1)
  235. mfcr r20
  236. mfctr r22
  237. mfspr r23,XER
  238. stw r20,_CCR(r1)
  239. stw r22,_CTR(r1)
  240. stw r23,_XER(r1)
  241. li r0,0x0ff0
  242. stw r0,TRAP(r1)
  243. stw r1,KSP(r3) /* Set old stack pointer */
  245. tophys(r0,r4)
  246. CLR_TOP32(r0)
  247. mtspr SPRG3,r0 /* Update current THREAD phys addr */
  248. lwz r1,KSP(r4) /* Load new stack pointer */
  249. /* save the old current 'last' for return value */
  250. mr r3,r2
  251. addi r2,r4,-THREAD /* Update current */
  252. lwz r0,_CCR(r1)
  253. mtcrf 0xFF,r0
  254. /* r3-r13 are destroyed -- Cort */
  255. REST_2GPRS(14, r1)
  256. REST_8GPRS(16, r1)
  257. REST_8GPRS(24, r1)
  259. lwz r4,_NIP(r1) /* Return to _switch caller in new task */
  260. mtlr r4
  261. addi r1,r1,INT_FRAME_SIZE
  262. blr
  264. .globl ret_from_fork
  265. ret_from_fork:
  266. bl schedule_tail
  267. lwz r0,TASK_PTRACE(r2)
  268. andi. r0,r0,PT_TRACESYS
  269. bnel- syscall_trace
  270. b ret_from_except
  272. .globl ret_from_intercept
  273. ret_from_intercept:
  274. /*
  275.  * We may be returning from RTL and cannot do the normal checks
  276.  * -- Cort
  277.  */
  278. cmpi 0,r3,0
  279. beq restore
  280. .globl ret_from_except
  281. ret_from_except:
  282. lwz r3,_MSR(r1) /* Returning to user mode? */
  283. andi. r3,r3,MSR_PR
  284. beq+ do_signal_ret /* if so, check need_resched and signals */
  285. lwz r3,NEED_RESCHED(r2)
  286. cmpi 0,r3,0 /* check need_resched flag */
  287. beq+ 7f
  288. bl schedule
  289. 7: lwz r5,SIGPENDING(r2) /* Check for pending unblocked signals */
  290. cmpwi 0,r5,0
  291. beq+ do_signal_ret
  292. li r3,0
  293. addi r4,r1,STACK_FRAME_OVERHEAD
  294. bl do_signal
  295. .globl do_signal_ret
  296. do_signal_ret:
  297. .globl ret_to_user_hook
  298. ret_to_user_hook:
  299. nop
  300. restore:
  301. lwz r3,_XER(r1)
  302. mtspr XER,r3
  303. REST_10GPRS(9,r1)
  304. REST_10GPRS(19,r1)
  305. REST_2GPRS(29,r1)
  306. REST_GPR(31,r1)
  308. /* make sure we hard disable here, even if rtl is active, to protect
  309.  * SRR[01] and SPRG2 -- Cort 
  310.  */
  311. mfmsr r0 /* Get current interrupt state */
  312. rlwinm r0,r0,0,17,15 /* clear MSR_EE in r0 */
  313. SYNC /* Some chip revs have problems here... */
  314. mtmsr r0 /* Update machine state */
  316. stwcx. r0,0,r1 /* to clear the reservation */
  318. /* if returning to user mode, set new sprg2 and save kernel SP */
  319. lwz r0,_MSR(r1)
  320. andi. r0,r0,MSR_PR
  321. beq+ 1f
  322. #ifdef CONFIG_ALTIVEC
  323. BEGIN_FTR_SECTION
  324. lwz r0,THREAD+THREAD_VRSAVE(r2)
  325. mtspr SPRN_VRSAVE,r0 /* if G4, restore VRSAVE reg */
  326. END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
  327. #endif /* CONFIG_ALTIVEC */
  328. addi r0,r1,INT_FRAME_SIZE /* size of frame */
  329. stw r0,THREAD+KSP(r2) /* save kernel stack pointer */
  330. tophys(r8,r1)
  331. CLR_TOP32(r8)
  332. mtspr SPRG2,r8 /* phys exception stack pointer */
  333. 1:
  334. lwz r3,_CTR(r1)
  335. lwz r0,_LINK(r1)
  336. mtctr r3
  337. mtlr r0
  338. REST_4GPRS(3, r1)
  339. REST_2GPRS(7, r1)
  341. #ifndef CONFIG_SMP
  342. /* We have to "dummy" load from the context save area in case
  343.  * these instructions cause an MMU fault.  If this happens
  344.  * after we load SRR0/SRR1, our return context is hosed.  -- Dan
  345.  * 
  346.  * This workaround is not enough, we must also make sure the
  347.  * actual code for this routine is in the TLB or BAT mapped.
  348.  * For 6xx/Power3, we know the code is in a BAT, so this should
  349.  * be enough in UP. In SMP, I limit lowmem to the amount of
  350.  * RAM that can be BAT mapped. Other CPUs may need additional
  351.  * tweaks, especially if used SMP or if the code for this routine
  352.  * crosses page boundaries. The TLB pin down for 4xx should help
  353.  * for example. --BenH.
  354.  */
  355. lwz r0,GPR0(r1)
  356. lwz r0,GPR2(r1)
  357. lwz r0,GPR1(r1)
  358. #endif /* ndef CONFIG_SMP */
  360. /* We re-use r3,r4 here (the load above was to cause the MMU
  361.  * fault if necessary).  Using r3,r4 removes the need to "dummy"
  362.  * load the CCR and NIP.  Since we load them we may as well
  363.  * use them.
  364.  */
  365. lwz r3,_CCR(r1)
  366. lwz r4,_NIP(r1)
  368. lwz r0,_MSR(r1)
  369. FIX_SRR1(r0,r2)
  370. mtspr SRR1,r0
  371. mtcrf 0xFF,r3
  372. mtspr SRR0,r4
  373. lwz r0,GPR0(r1)
  374. lwz r2,GPR2(r1)
  375. lwz r3,GPR3(r1)
  376. lwz r4,GPR4(r1)
  377. lwz r1,GPR1(r1)
  378. SYNC
  379. RFI
  382. /*
  383.  * PROM code for specific machines follows.  Put it 
  384.  * here so it's easy to add arch-specific sections later.
  385.  * -- Cort
  386.  */
  387. #if defined(CONFIG_ALL_PPC)
  388. /*
  389.  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
  390.  * called with the MMU off.
  391.  */
  392. .globl enter_rtas
  393. enter_rtas:
  394. mflr r0
  395. stw r0,20(r1)
  396. lis r4,rtas_data@ha
  397. lwz r4,rtas_data@l(r4)
  398. lis r6,1f@ha /* physical return address for rtas */
  399. addi r6,r6,1f@l
  400. addis r6,r6,-KERNELBASE@h
  401. subi r7,r1,INT_FRAME_SIZE
  402. addis r7,r7,-KERNELBASE@h
  403. lis r8,rtas_entry@ha
  404. lwz r8,rtas_entry@l(r8)
  405. mfmsr r9
  406. stw r9,8(r1)
  407. li r0,0
  408. ori r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_FE0|MSR_FE1
  409. andc r0,r9,r0
  410. li r10,MSR_IR|MSR_DR|MSR_FP
  411. andc r9,r0,r10
  412. SYNC /* disable interrupts so SRR0/1 */
  413. mtmsr r0 /* don't get trashed */
  414. mtlr r6
  415. CLR_TOP32(r7)
  416. mtspr SPRG2,r7
  417. mtspr SRR0,r8
  418. mtspr SRR1,r9
  419. RFI
  420. 1: addis r9,r1,-KERNELBASE@h
  421. lwz r8,20(r9) /* get return address */
  422. lwz r9,8(r9) /* original msr value */
  423. FIX_SRR1(r9,r0)
  424. li r0,0
  425. mtspr SPRG2,r0
  426. mtspr SRR0,r8
  427. mtspr SRR1,r9
  428. RFI /* return to caller */
  429. #endif /* CONFIG_ALL_PPC */