开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
misc.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：22k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

misc.S：源码内容
  1. /*
  2.  * BK Id: SCCS/s.misc.S 1.36 12/01/01 20:09:06 benh
  3.  */
  4. /*
  5.  * This file contains miscellaneous low-level functions.
  6.  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
  7.  *
  8.  * Largely rewritten by Cort Dougan (cort@cs.nmt.edu)
  9.  * and Paul Mackerras.
  10.  *
  11.  * This program is free software; you can redistribute it and/or
  12.  * modify it under the terms of the GNU General Public License
  13.  * as published by the Free Software Foundation; either version
  14.  * 2 of the License, or (at your option) any later version.
  15.  *
  16.  */
  18. #include <linux/config.h>
  19. #include <linux/sys.h>
  20. #include <asm/unistd.h>
  21. #include <asm/errno.h>
  22. #include <asm/processor.h>
  23. #include <asm/page.h>
  24. #include <asm/cache.h>
  25. #include <asm/cputable.h>
  26. #include "ppc_asm.h"
  28. .text
  30. .align 5
  31. _GLOBAL(__delay)
  32. cmpwi 0,r3,0
  33. mtctr r3
  34. beqlr
  35. 1: bdnz 1b
  36. blr
  38. /*
  39.  * Returns (address we're running at) - (address we were linked at)
  40.  * for use before the text and data are mapped to KERNELBASE.
  41.  */
  43. _GLOBAL(reloc_offset)
  44. mflr r0
  45. bl 1f
  46. 1: mflr r3
  47. lis r4,1b@ha
  48. addi r4,r4,1b@l
  49. subf r3,r4,r3
  50. mtlr r0
  51. blr
  53. /*
  54.  * identify_cpu,
  55.  * called with r3 = data offset and r4 = CPU number
  56.  * doesn't change r3
  57.  */
  58. _GLOBAL(identify_cpu)
  59. addis r8,r3,cpu_specs@ha
  60. addi r8,r8,cpu_specs@l
  61. mfpvr r7
  62. 1:
  63. lwz r5,CPU_SPEC_PVR_MASK(r8)
  64. and r5,r5,r7
  65. lwz r6,CPU_SPEC_PVR_VALUE(r8)
  66. cmplw 0,r6,r5
  67. beq 1f
  68. addi r8,r8,CPU_SPEC_ENTRY_SIZE
  69. b 1b
  70. 1:
  71. addis r6,r3,cur_cpu_spec@ha
  72. addi r6,r6,cur_cpu_spec@l
  73. slwi r4,r4,2
  74. sub r8,r8,r3
  75. stwx r8,r4,r6
  76. blr
  78. /*
  79.  * do_cpu_ftr_fixups - goes through the list of CPU feature fixups
  80.  * and writes nop's over sections of code that don't apply for this cpu.
  81.  * r3 = data offset (not changed)
  82.  */
  83. _GLOBAL(do_cpu_ftr_fixups)
  84. /* Get CPU 0 features */
  85. addis r6,r3,cur_cpu_spec@ha
  86. addi r6,r6,cur_cpu_spec@l
  87. lwz r4,0(r6)
  88. add r4,r4,r3
  89. lwz r4,CPU_SPEC_FEATURES(r4)
  91. /* Get the fixup table */
  92. addis r6,r3,__start___ftr_fixup@ha
  93. addi r6,r6,__start___ftr_fixup@l
  94. addis r7,r3,__stop___ftr_fixup@ha
  95. addi r7,r7,__stop___ftr_fixup@l
  97. /* Do the fixup */
  98. 1: cmplw 0,r6,r7
  99. bgelr
  100. addi r6,r6,16
  101. lwz r8,-16(r6) /* mask */
  102. and r8,r8,r4
  103. lwz r9,-12(r6) /* value */
  104. cmplw 0,r8,r9
  105. beq 1b
  106. lwz r8,-8(r6) /* section begin */
  107. lwz r9,-4(r6) /* section end */
  108. subf. r9,r8,r9
  109. beq 1b
  110. /* write nops over the section of code */
  111. /* todo: if large section, add a branch at the start of it */
  112. srwi r9,r9,2
  113. mtctr r9
  114. add r8,r8,r3
  115. lis r0,0x60000000@h /* nop */
  116. 3: stw r0,0(r8)
  117. andi. r10,r4,CPU_FTR_SPLIT_ID_CACHE@l
  118. beq 2f
  119. dcbst 0,r8 /* suboptimal, but simpler */
  120. sync
  121. icbi 0,r8
  122. 2: addi r8,r8,4
  123. bdnz 3b
  124. sync /* additional sync needed on g4 */
  125. isync
  126. b 1b
  128. /*
  129.  * call_setup_cpu - call the setup_cpu function for this cpu
  130.  * r3 = data offset, r24 = cpu number
  131.  *
  132.  * Don't change register layout, the setup function may rely
  133.  * on r5 containing a relocated pointer to the current cpu spec.
  134.  */
  135. _GLOBAL(call_setup_cpu)
  136. addis r5,r3,cur_cpu_spec@ha
  137. addi r5,r5,cur_cpu_spec@l
  138. slwi r4,r24,2
  139. lwzx r5,r4,r5
  140. add r5,r5,r3
  141. lwz r6,CPU_SPEC_SETUP(r5)
  142. add r6,r6,r3
  143. mtctr r6
  144. mr r3,r24
  145. bctr
  147. /* void __save_flags_ptr(unsigned long *flags) */
  148. _GLOBAL(__save_flags_ptr)
  149. mfmsr r4
  150. stw r4,0(r3)
  151. blr
  152. /* 
  153.  * Need these nops here for taking over save/restore to
  154.  * handle lost intrs
  155.  * -- Cort
  156.  */
  157. nop
  158. nop
  159. nop
  160. nop
  161. nop
  162. nop
  163. nop
  164. nop
  165. nop
  166. nop
  167. nop
  168. nop
  169. nop
  170. nop
  171. nop
  172. nop
  173. nop
  174. _GLOBAL(__save_flags_ptr_end)
  176. /* void __restore_flags(unsigned long flags) */
  177. _GLOBAL(__restore_flags)
  178. /*
  179.  * Just set/clear the MSR_EE bit through restore/flags but do not
  180.  * change anything else.  This is needed by the RT system and makes
  181.  * sense anyway.
  182.  *    -- Cort
  183.  */
  184. mfmsr  r4
  185. /* Copy all except the MSR_EE bit from r4 (current MSR value)
  186.    to r3.  This is the sort of thing the rlwimi instruction is
  187.    designed for.  -- paulus. */
  188. rlwimi r3,r4,0,17,15
  189.  /* Check if things are setup the way we want _already_. */
  190. cmpw 0,r3,r4
  191. beqlr
  192. 1: SYNC
  193. mtmsr r3
  194. SYNC
  195. blr
  196. nop
  197. nop
  198. nop
  199. nop
  200. nop
  201. nop
  202. nop
  203. nop
  204. nop
  205. nop
  206. nop
  207. nop
  208. nop
  209. nop
  210. nop
  211. nop
  212. nop
  213. nop
  214. nop
  215. _GLOBAL(__restore_flags_end)
  217. _GLOBAL(__cli)
  218. mfmsr r0 /* Get current interrupt state */
  219. rlwinm r3,r0,16+1,32-1,31 /* Extract old value of 'EE' */
  220. rlwinm r0,r0,0,17,15 /* clear MSR_EE in r0 */
  221. SYNC /* Some chip revs have problems here... */
  222. mtmsr r0 /* Update machine state */
  223. blr /* Done */
  224. /* 
  225.  * Need these nops here for taking over save/restore to
  226.  * handle lost intrs
  227.  * -- Cort
  228.  */
  229. nop
  230. nop
  231. nop
  232. nop
  233. nop
  234. nop
  235. nop
  236. nop
  237. nop
  238. nop
  239. nop
  240. nop
  241. nop
  242. nop
  243. nop
  244. _GLOBAL(__cli_end)
  246. _GLOBAL(__sti)
  247. mfmsr r3 /* Get current state */
  248. ori r3,r3,MSR_EE /* Turn on 'EE' bit */
  249. SYNC /* Some chip revs have problems here... */
  250. mtmsr r3 /* Update machine state */
  251. blr
  252. /* 
  253.  * Need these nops here for taking over save/restore to
  254.  * handle lost intrs
  255.  * -- Cort
  256.  */
  257. nop
  258. nop
  259. nop
  260. nop
  261. nop
  262. nop
  263. nop
  264. nop
  265. nop
  266. nop
  267. nop
  268. nop
  269. nop
  270. nop
  271. nop
  272. nop
  273. _GLOBAL(__sti_end)
  276. /*
  277.  * complement mask on the msr then "or" some values on.
  278.  *     _nmask_and_or_msr(nmask, value_to_or)
  279.  */
  280. _GLOBAL(_nmask_and_or_msr)
  281. mfmsr r0 /* Get current msr */
  282. andc r0,r0,r3 /* And off the bits set in r3 (first parm) */
  283. or r0,r0,r4 /* Or on the bits in r4 (second parm) */
  284. SYNC /* Some chip revs have problems here... */
  285. mtmsr r0 /* Update machine state */
  286. isync
  287. blr /* Done */
  290. /*
  291.  * Flush MMU TLB
  292.  */
  293. _GLOBAL(_tlbia)
  294. #if defined(CONFIG_SMP)
  295. mfmsr r10
  296. SYNC
  297. rlwinm r0,r10,0,17,15 /* clear bit 16 (MSR_EE) */
  298. mtmsr r0
  299. SYNC
  300. lis r9,hash_table_lock@h
  301. ori r9,r9,hash_table_lock@l
  302. lwz r8,PROCESSOR(r2)
  303. oris r8,r8,10
  304. 10: lwarx r7,0,r9
  305. cmpi 0,r7,0
  306. bne- 10b
  307. stwcx. r8,0,r9
  308. bne- 10b
  309. #endif /* CONFIG_SMP */
  310. sync
  311. tlbia
  312. sync
  313. #ifdef CONFIG_SMP
  314. TLBSYNC
  315. li r0,0
  316. stw r0,0(r9) /* clear hash_table_lock */
  317. mtmsr r10
  318. SYNC
  319. #endif
  320. blr
  322. /*
  323.  * Flush MMU TLB for a particular address
  324.  */
  325. _GLOBAL(_tlbie)
  326. #if defined(CONFIG_SMP)
  327. mfmsr r10
  328. SYNC
  329. rlwinm r0,r10,0,17,15 /* clear bit 16 (MSR_EE) */
  330. mtmsr r0
  331. SYNC
  332. lis r9,hash_table_lock@h
  333. ori r9,r9,hash_table_lock@l
  334. lwz r8,PROCESSOR(r2)
  335. oris r8,r8,11
  336. 10: lwarx r7,0,r9
  337. cmpi 0,r7,0
  338. bne- 10b
  339. stwcx. r8,0,r9
  340. bne- 10b
  341. eieio
  342. #endif /* CONFIG_SMP */
  343. tlbie r3
  344. sync
  345. #ifdef CONFIG_SMP
  346. TLBSYNC
  347. li r0,0
  348. stw r0,0(r9) /* clear hash_table_lock */
  349. mtmsr r10
  350. SYNC
  351. #endif
  352. blr
  354. /*
  355.  * Flush instruction cache.
  356.  * This is a no-op on the 601.
  357.  */
  358. _GLOBAL(flush_instruction_cache)
  359. #if defined(CONFIG_8xx)
  360. isync
  361. lis r5, IDC_INVALL@h
  362. mtspr IC_CST, r5
  363. #elif defined(CONFIG_4xx)
  364. lis r3, KERNELBASE@h
  365. iccci 0,r3
  366. #else
  367. mfspr r3,PVR
  368. rlwinm r3,r3,16,16,31
  369. cmpi 0,r3,1
  370. beqlr /* for 601, do nothing */
  371. /* 603/604 processor - use invalidate-all bit in HID0 */
  372. mfspr r3,HID0
  373. ori r3,r3,HID0_ICFI
  374. mtspr HID0,r3
  375. #endif /* CONFIG_8xx */
  376. isync
  377. blr
  379. /*
  380.  * Write any modified data cache blocks out to memory
  381.  * and invalidate the corresponding instruction cache blocks.
  382.  * This is a no-op on the 601.
  383.  *
  384.  * flush_icache_range(unsigned long start, unsigned long stop)
  385.  */
  386. _GLOBAL(flush_icache_range)
  387. mfspr r5,PVR
  388. rlwinm r5,r5,16,16,31
  389. cmpi 0,r5,1
  390. beqlr /* for 601, do nothing */
  391. li r5,L1_CACHE_LINE_SIZE-1
  392. andc r3,r3,r5
  393. subf r4,r3,r4
  394. add r4,r4,r5
  395. srwi. r4,r4,LG_L1_CACHE_LINE_SIZE
  396. beqlr
  397. mtctr r4
  398. mr r6,r3
  399. 1: dcbst 0,r3
  400. addi r3,r3,L1_CACHE_LINE_SIZE
  401. bdnz 1b
  402. sync /* wait for dcbst's to get to ram */
  403. mtctr r4
  404. 2: icbi 0,r6
  405. addi r6,r6,L1_CACHE_LINE_SIZE
  406. bdnz 2b
  407. sync /* additional sync needed on g4 */
  408. isync
  409. blr
  410. /*
  411.  * Write any modified data cache blocks out to memory.
  412.  * Does not invalidate the corresponding cache lines (especially for
  413.  * any corresponding instruction cache).
  414.  *
  415.  * clean_dcache_range(unsigned long start, unsigned long stop)
  416.  */
  417. _GLOBAL(clean_dcache_range)
  418. li r5,L1_CACHE_LINE_SIZE-1
  419. andc r3,r3,r5
  420. subf r4,r3,r4
  421. add r4,r4,r5
  422. srwi. r4,r4,LG_L1_CACHE_LINE_SIZE
  423. beqlr
  424. mtctr r4
  426. 1: dcbst 0,r3
  427. addi r3,r3,L1_CACHE_LINE_SIZE
  428. bdnz 1b
  429. sync /* wait for dcbst's to get to ram */
  430. blr
  432. /*
  433.  * Write any modified data cache blocks out to memory and invalidate them.
  434.  * Does not invalidate the corresponding instruction cache blocks.
  435.  *
  436.  * flush_dcache_range(unsigned long start, unsigned long stop)
  437.  */
  438. _GLOBAL(flush_dcache_range)
  439. li r5,L1_CACHE_LINE_SIZE-1
  440. andc r3,r3,r5
  441. subf r4,r3,r4
  442. add r4,r4,r5
  443. srwi. r4,r4,LG_L1_CACHE_LINE_SIZE
  444. beqlr
  445. mtctr r4
  447. 1: dcbf 0,r3
  448. addi r3,r3,L1_CACHE_LINE_SIZE
  449. bdnz 1b
  450. sync /* wait for dcbst's to get to ram */
  451. blr
  453. /*
  454.  * Like above, but invalidate the D-cache.  This is used by the 8xx
  455.  * to invalidate the cache so the PPC core doesn't get stale data
  456.  * from the CPM (no cache snooping here :-).
  457.  *
  458.  * invalidate_dcache_range(unsigned long start, unsigned long stop)
  459.  */
  460. _GLOBAL(invalidate_dcache_range)
  461. li r5,L1_CACHE_LINE_SIZE-1
  462. andc r3,r3,r5
  463. subf r4,r3,r4
  464. add r4,r4,r5
  465. srwi. r4,r4,LG_L1_CACHE_LINE_SIZE
  466. beqlr
  467. mtctr r4
  469. 1: dcbi 0,r3
  470. addi r3,r3,L1_CACHE_LINE_SIZE
  471. bdnz 1b
  472. sync /* wait for dcbi's to get to ram */
  473. blr
  475. /*
  476.  * Flush a particular page from the data cache to RAM.
  477.  * Note: this is necessary because the instruction cache does *not*
  478.  * snoop from the data cache.
  479.  * This is a no-op on the 601 which has a unified cache.
  480.  *
  481.  * void __flush_page_to_ram(void *page)
  482.  */
  483. _GLOBAL(__flush_page_to_ram)
  484. mfspr r5,PVR
  485. rlwinm r5,r5,16,16,31
  486. cmpi 0,r5,1
  487. beqlr /* for 601, do nothing */
  488. rlwinm r3,r3,0,0,19 /* Get page base address */
  489. li r4,4096/L1_CACHE_LINE_SIZE /* Number of lines in a page */
  490. mtctr r4
  491. mr r6,r3
  492. 0: dcbst 0,r3 /* Write line to ram */
  493. addi r3,r3,L1_CACHE_LINE_SIZE
  494. bdnz 0b
  495. sync
  496. mtctr r4
  497. 1: icbi 0,r6
  498. addi r6,r6,L1_CACHE_LINE_SIZE
  499. bdnz 1b
  500. sync
  501. isync
  502. blr
  504. /*
  505.  * Flush a particular page from the instruction cache.
  506.  * Note: this is necessary because the instruction cache does *not*
  507.  * snoop from the data cache.
  508.  * This is a no-op on the 601 which has a unified cache.
  509.  *
  510.  * void __flush_icache_page(void *page)
  511.  */
  512. _GLOBAL(__flush_icache_page)
  513. mfspr r5,PVR
  514. rlwinm r5,r5,16,16,31
  515. cmpi 0,r5,1
  516. beqlr /* for 601, do nothing */
  517. li r4,4096/L1_CACHE_LINE_SIZE /* Number of lines in a page */
  518. mtctr r4
  519. 1: icbi 0,r3
  520. addi r3,r3,L1_CACHE_LINE_SIZE
  521. bdnz 1b
  522. sync
  523. isync
  524. blr
  526. /*
  527.  * Clear a page using the dcbz instruction, which doesn't cause any
  528.  * memory traffic (except to write out any cache lines which get
  529.  * displaced).  This only works on cacheable memory.
  530.  */
  531. _GLOBAL(clear_page)
  532. li r0,4096/L1_CACHE_LINE_SIZE
  533. mtctr r0
  534. #ifdef CONFIG_8xx
  535. li r4, 0
  536. 1: stw r4, 0(r3)
  537. stw r4, 4(r3)
  538. stw r4, 8(r3)
  539. stw r4, 12(r3)
  540. #else
  541. 1: dcbz 0,r3
  542. #endif
  543. addi r3,r3,L1_CACHE_LINE_SIZE
  544. bdnz 1b
  545. blr
  547. /*
  548.  * Copy a whole page.  We use the dcbz instruction on the destination
  549.  * to reduce memory traffic (it eliminates the unnecessary reads of
  550.  * the destination into cache).  This requires that the destination
  551.  * is cacheable.
  552.  */
  553. #define COPY_16_BYTES
  554. lwz r6,4(r4);
  555. lwz r7,8(r4);
  556. lwz r8,12(r4);
  557. lwzu r9,16(r4);
  558. stw r6,4(r3);
  559. stw r7,8(r3);
  560. stw r8,12(r3);
  561. stwu r9,16(r3)
  563. _GLOBAL(copy_page)
  564. addi r3,r3,-4
  565. addi r4,r4,-4
  566. li r5,4
  568. #ifndef CONFIG_8xx
  569. #if MAX_L1_COPY_PREFETCH > 1
  570. li r0,MAX_L1_COPY_PREFETCH
  571. li r11,4
  572. mtctr r0
  573. 11: dcbt r11,r4
  574. addi r11,r11,L1_CACHE_LINE_SIZE
  575. bdnz 11b
  576. #else /* MAX_L1_COPY_PREFETCH == 1 */
  577. dcbt r5,r4
  578. li r11,L1_CACHE_LINE_SIZE+4
  579. #endif /* MAX_L1_COPY_PREFETCH */
  580. #endif /* CONFIG_8xx */
  582. li r0,4096/L1_CACHE_LINE_SIZE
  583. mtctr r0
  584. 1:
  585. #ifndef CONFIG_8xx
  586. dcbt r11,r4
  587. dcbz r5,r3
  588. #endif
  589. COPY_16_BYTES
  590. #if L1_CACHE_LINE_SIZE >= 32
  591. COPY_16_BYTES
  592. #if L1_CACHE_LINE_SIZE >= 64
  593. COPY_16_BYTES
  594. COPY_16_BYTES
  595. #if L1_CACHE_LINE_SIZE >= 128
  596. COPY_16_BYTES
  597. COPY_16_BYTES
  598. COPY_16_BYTES
  599. COPY_16_BYTES
  600. #endif
  601. #endif
  602. #endif
  603. bdnz 1b
  604. blr
  606. /*
  607.  * Atomic [test&set] exchange
  608.  *
  609.  * unsigned long xchg_u32(void *ptr, unsigned long val)
  610.  * Changes the memory location '*ptr' to be val and returns
  611.  * the previous value stored there.
  612.  */
  613. _GLOBAL(xchg_u32)
  614. mr r5,r3 /* Save pointer */
  615. 10: lwarx r3,0,r5 /* Fetch old value & reserve */
  616. stwcx. r4,0,r5 /* Update with new value */
  617. bne- 10b /* Retry if "reservation" (i.e. lock) lost */
  618. blr
  620. /*
  621.  * void atomic_clear_mask(atomic_t mask, atomic_t *addr)
  622.  * void atomic_set_mask(atomic_t mask, atomic_t *addr);
  623.  */
  624. _GLOBAL(atomic_clear_mask)
  625. 10: lwarx r5,0,r4
  626. andc r5,r5,r3
  627. stwcx. r5,0,r4
  628. bne- 10b
  629. blr
  630. _GLOBAL(atomic_set_mask)
  631. 10: lwarx r5,0,r4
  632. or r5,r5,r3
  633. stwcx. r5,0,r4
  634. bne- 10b
  635. blr
  637. /*
  638.  * I/O string operations
  639.  *
  640.  * insb(port, buf, len)
  641.  * outsb(port, buf, len)
  642.  * insw(port, buf, len)
  643.  * outsw(port, buf, len)
  644.  * insl(port, buf, len)
  645.  * outsl(port, buf, len)
  646.  * insw_ns(port, buf, len)
  647.  * outsw_ns(port, buf, len)
  648.  * insl_ns(port, buf, len)
  649.  * outsl_ns(port, buf, len)
  650.  *
  651.  * The *_ns versions don't do byte-swapping.
  652.  */
  653. _GLOBAL(_insb)
  654. cmpwi 0,r5,0
  655. mtctr r5
  656. subi r4,r4,1
  657. blelr-
  658. 00: lbz r5,0(r3)
  659. eieio
  660. stbu r5,1(r4)
  661. bdnz 00b
  662. blr
  664. _GLOBAL(_outsb)
  665. cmpwi 0,r5,0
  666. mtctr r5
  667. subi r4,r4,1
  668. blelr-
  669. 00: lbzu r5,1(r4)
  670. stb r5,0(r3)
  671. eieio
  672. bdnz 00b
  673. blr
  675. _GLOBAL(_insw)
  676. cmpwi 0,r5,0
  677. mtctr r5
  678. subi r4,r4,2
  679. blelr-
  680. 00: lhbrx r5,0,r3
  681. eieio
  682. sthu r5,2(r4)
  683. bdnz 00b
  684. blr
  686. _GLOBAL(_outsw)
  687. cmpwi 0,r5,0
  688. mtctr r5
  689. subi r4,r4,2
  690. blelr-
  691. 00: lhzu r5,2(r4)
  692. eieio
  693. sthbrx r5,0,r3
  694. bdnz 00b
  695. blr
  697. _GLOBAL(_insl)
  698. cmpwi 0,r5,0
  699. mtctr r5
  700. subi r4,r4,4
  701. blelr-
  702. 00: lwbrx r5,0,r3
  703. eieio
  704. stwu r5,4(r4)
  705. bdnz 00b
  706. blr
  708. _GLOBAL(_outsl)
  709. cmpwi 0,r5,0
  710. mtctr r5
  711. subi r4,r4,4
  712. blelr-
  713. 00: lwzu r5,4(r4)
  714. stwbrx r5,0,r3
  715. eieio
  716. bdnz 00b
  717. blr
  719. _GLOBAL(ide_insw)
  720. _GLOBAL(_insw_ns)
  721. cmpwi 0,r5,0
  722. mtctr r5
  723. subi r4,r4,2
  724. blelr-
  725. 00: lhz r5,0(r3)
  726. eieio
  727. sthu r5,2(r4)
  728. bdnz 00b
  729. blr
  731. _GLOBAL(ide_outsw)
  732. _GLOBAL(_outsw_ns)
  733. cmpwi 0,r5,0
  734. mtctr r5
  735. subi r4,r4,2
  736. blelr-
  737. 00: lhzu r5,2(r4)
  738. sth r5,0(r3)
  739. eieio
  740. bdnz 00b
  741. blr
  743. _GLOBAL(_insl_ns)
  744. cmpwi 0,r5,0
  745. mtctr r5
  746. subi r4,r4,4
  747. blelr-
  748. 00: lwz r5,0(r3)
  749. eieio
  750. stwu r5,4(r4)
  751. bdnz 00b
  752. blr
  754. _GLOBAL(_outsl_ns)
  755. cmpwi 0,r5,0
  756. mtctr r5
  757. subi r4,r4,4
  758. blelr-
  759. 00: lwzu r5,4(r4)
  760. stw r5,0(r3)
  761. eieio
  762. bdnz 00b
  763. blr
  765. /*
  766.  * Extended precision shifts.
  767.  * 
  768.  * Updated to be valid for shift counts from 0 to 63 inclusive.
  769.  * -- Gabriel
  770.  *
  771.  * R3/R4 has 64 bit value
  772.  * R5    has shift count
  773.  * result in R3/R4
  774.  *
  775.  *  ashrdi3: arithmetic right shift (sign propagation)     
  776.  *  lshrdi3: logical right shift
  777.  *  ashldi3: left shift
  778.  */
  779. _GLOBAL(__ashrdi3)
  780. subfic r6,r5,32
  781. srw r4,r4,r5 # LSW = count > 31 ? 0 : LSW >> count
  782. addi r7,r5,32 # could be xori, or addi with -32
  783. slw r6,r3,r6 # t1 = count > 31 ? 0 : MSW << (32-count)
  784. rlwinm r8,r7,0,32 # t3 = (count < 32) ? 32 : 0
  785. sraw r7,r3,r7 # t2 = MSW >> (count-32)
  786. or r4,r4,r6 # LSW |= t1
  787. slw r7,r7,r8 # t2 = (count < 32) ? 0 : t2
  788. sraw r3,r3,r5 # MSW = MSW >> count
  789. or r4,r4,r7 # LSW |= t2
  790. blr
  792. _GLOBAL(__ashldi3)
  793. subfic r6,r5,32
  794. slw r3,r3,r5 # MSW = count > 31 ? 0 : MSW << count
  795. addi r7,r5,32 # could be xori, or addi with -32
  796. srw r6,r4,r6 # t1 = count > 31 ? 0 : LSW >> (32-count)
  797. slw r7,r4,r7 # t2 = count < 32 ? 0 : LSW << (count-32)
  798. or r3,r3,r6 # MSW |= t1
  799. slw r4,r4,r5 # LSW = LSW << count
  800. or r3,r3,r7 # MSW |= t2
  801. blr
  803. _GLOBAL(__lshrdi3)
  804. subfic r6,r5,32
  805. srw r4,r4,r5 # LSW = count > 31 ? 0 : LSW >> count
  806. addi r7,r5,32 # could be xori, or addi with -32
  807. slw r6,r3,r6 # t1 = count > 31 ? 0 : MSW << (32-count)
  808. srw r7,r3,r7 # t2 = count < 32 ? 0 : MSW >> (count-32)
  809. or r4,r4,r6 # LSW |= t1
  810. srw r3,r3,r5 # MSW = MSW >> count
  811. or r4,r4,r7 # LSW |= t2 
  812. blr
  814. _GLOBAL(abs)
  815. srawi r4,r3,31
  816. xor r3,r3,r4
  817. sub r3,r3,r4
  818. blr
  820. _GLOBAL(_get_SP)
  821. mr r3,r1 /* Close enough */
  822. blr
  824. /*
  825.  * These are used in the alignment trap handler when emulating
  826.  * single-precision loads and stores.
  827.  * We restore and save the fpscr so the task gets the same result
  828.  * and exceptions as if the cpu had performed the load or store.
  829.  */
  831. #if defined(CONFIG_4xx)
  832. _GLOBAL(cvt_fd)
  833. lfs 0,0(r3)
  834. stfd 0,0(r4)
  835. blr
  837. _GLOBAL(cvt_df)
  838. lfd 0,0(r3)
  839. stfs 0,0(r4)
  840. blr
  841. #else
  842. _GLOBAL(cvt_fd)
  843. lfd 0,-4(r5) /* load up fpscr value */
  844. mtfsf 0xff,0
  845. lfs 0,0(r3)
  846. stfd 0,0(r4)
  847. mffs 0 /* save new fpscr value */
  848. stfd 0,-4(r5)
  849. blr
  851. _GLOBAL(cvt_df)
  852. lfd 0,-4(r5) /* load up fpscr value */
  853. mtfsf 0xff,0
  854. lfd 0,0(r3)
  855. stfs 0,0(r4)
  856. mffs 0 /* save new fpscr value */
  857. stfd 0,-4(r5)
  858. blr
  859. #endif
  861. /*
  862.  * Create a kernel thread
  863.  *   kernel_thread(fn, arg, flags)
  864.  */
  865. _GLOBAL(kernel_thread)
  866. mr r6,r3 /* function */
  867. ori r3,r5,CLONE_VM /* flags */
  868. li r0,__NR_clone
  869. sc
  870. cmpi 0,r3,0 /* parent or child? */
  871. bnelr /* return if parent */
  872. li r0,0 /* make top-level stack frame */
  873. stwu r0,-16(r1)
  874. mtlr r6              /* fn addr in lr */
  875. mr r3,r4         /* load arg and call fn */
  876. blrl
  877. li r0,__NR_exit /* exit after child exits */
  878. li r3,0
  879. sc
  881. /*
  882.  * This routine is just here to keep GCC happy - sigh...
  883.  */
  884. _GLOBAL(__main)
  885. blr
  887. #define SYSCALL(name) 
  888. _GLOBAL(name) 
  889. li r0,__NR_##name; 
  890. sc; 
  891. bnslr; 
  892. lis r4,errno@ha; 
  893. stw r3,errno@l(r4); 
  894. li r3,-1; 
  895. blr
  897. #define __NR__exit __NR_exit
  899. SYSCALL(sync)
  900. SYSCALL(setsid)
  901. SYSCALL(write)
  902. SYSCALL(dup)
  903. SYSCALL(execve)
  904. SYSCALL(open)
  905. SYSCALL(close)
  906. SYSCALL(waitpid)
  907. SYSCALL(fork)
  908. SYSCALL(delete_module)
  909. SYSCALL(_exit)
  910. SYSCALL(lseek)
  911. SYSCALL(read)
  913. /* Why isn't this a) automatic, b) written in 'C'? */
  914. .data
  915. .align 4
  916. _GLOBAL(sys_call_table)
  917. .long sys_ni_syscall /* 0  -  old "setup()" system call */
  918. .long sys_exit
  919. .long sys_fork
  920. .long sys_read
  921. .long sys_write
  922. .long sys_open /* 5 */
  923. .long sys_close
  924. .long sys_waitpid
  925. .long sys_creat
  926. .long sys_link
  927. .long sys_unlink /* 10 */
  928. .long sys_execve
  929. .long sys_chdir
  930. .long sys_time
  931. .long sys_mknod
  932. .long sys_chmod /* 15 */
  933. .long sys_lchown
  934. .long sys_ni_syscall /* old break syscall holder */
  935. .long sys_stat
  936. .long sys_lseek
  937. .long sys_getpid /* 20 */
  938. .long sys_mount
  939. .long sys_oldumount
  940. .long sys_setuid
  941. .long sys_getuid
  942. .long sys_stime /* 25 */
  943. .long sys_ptrace
  944. .long sys_alarm
  945. .long sys_fstat
  946. .long sys_pause
  947. .long sys_utime /* 30 */
  948. .long sys_ni_syscall /* old stty syscall holder */
  949. .long sys_ni_syscall /* old gtty syscall holder */
  950. .long sys_access
  951. .long sys_nice
  952. .long sys_ni_syscall /* 35 */ /* old ftime syscall holder */
  953. .long sys_sync
  954. .long sys_kill
  955. .long sys_rename
  956. .long sys_mkdir
  957. .long sys_rmdir /* 40 */
  958. .long sys_dup
  959. .long sys_pipe
  960. .long sys_times
  961. .long sys_ni_syscall /* old prof syscall holder */
  962. .long sys_brk /* 45 */
  963. .long sys_setgid
  964. .long sys_getgid
  965. .long sys_signal
  966. .long sys_geteuid
  967. .long sys_getegid /* 50 */
  968. .long sys_acct
  969. .long sys_umount /* recycled never used phys() */
  970. .long sys_ni_syscall /* old lock syscall holder */
  971. .long sys_ioctl
  972. .long sys_fcntl /* 55 */
  973. .long sys_ni_syscall /* old mpx syscall holder */
  974. .long sys_setpgid
  975. .long sys_ni_syscall /* old ulimit syscall holder */
  976. .long sys_olduname
  977. .long sys_umask /* 60 */
  978. .long sys_chroot
  979. .long sys_ustat
  980. .long sys_dup2
  981. .long sys_getppid
  982. .long sys_getpgrp /* 65 */
  983. .long sys_setsid
  984. .long sys_sigaction
  985. .long sys_sgetmask
  986. .long sys_ssetmask
  987. .long sys_setreuid /* 70 */
  988. .long sys_setregid
  989. .long sys_sigsuspend
  990. .long sys_sigpending
  991. .long sys_sethostname
  992. .long sys_setrlimit /* 75 */
  993. .long sys_old_getrlimit
  994. .long sys_getrusage
  995. .long sys_gettimeofday
  996. .long sys_settimeofday
  997. .long sys_getgroups /* 80 */
  998. .long sys_setgroups
  999. .long ppc_select
  1000. .long sys_symlink
  1001. .long sys_lstat
  1002. .long sys_readlink /* 85 */
  1003. .long sys_uselib
  1004. .long sys_swapon
  1005. .long sys_reboot
  1006. .long old_readdir
  1007. .long sys_mmap /* 90 */
  1008. .long sys_munmap
  1009. .long sys_truncate
  1010. .long sys_ftruncate
  1011. .long sys_fchmod
  1012. .long sys_fchown /* 95 */
  1013. .long sys_getpriority
  1014. .long sys_setpriority
  1015. .long sys_ni_syscall /* old profil syscall holder */
  1016. .long sys_statfs
  1017. .long sys_fstatfs /* 100 */
  1018. .long sys_ioperm
  1019. .long sys_socketcall
  1020. .long sys_syslog
  1021. .long sys_setitimer
  1022. .long sys_getitimer /* 105 */
  1023. .long sys_newstat
  1024. .long sys_newlstat
  1025. .long sys_newfstat
  1026. .long sys_uname
  1027. .long sys_iopl /* 110 */
  1028. .long sys_vhangup
  1029. .long sys_ni_syscall /* old 'idle' syscall */
  1030. .long sys_vm86
  1031. .long sys_wait4
  1032. .long sys_swapoff /* 115 */
  1033. .long sys_sysinfo
  1034. .long sys_ipc
  1035. .long sys_fsync
  1036. .long sys_sigreturn
  1037. .long sys_clone /* 120 */
  1038. .long sys_setdomainname
  1039. .long sys_newuname
  1040. .long sys_modify_ldt
  1041. .long sys_adjtimex
  1042. .long sys_mprotect /* 125 */
  1043. .long sys_sigprocmask
  1044. .long sys_create_module
  1045. .long sys_init_module
  1046. .long sys_delete_module
  1047. .long sys_get_kernel_syms /* 130 */
  1048. .long sys_quotactl
  1049. .long sys_getpgid
  1050. .long sys_fchdir
  1051. .long sys_bdflush
  1052. .long sys_sysfs /* 135 */
  1053. .long sys_personality
  1054. .long sys_ni_syscall /* for afs_syscall */
  1055. .long sys_setfsuid
  1056. .long sys_setfsgid
  1057. .long sys_llseek /* 140 */
  1058. .long sys_getdents
  1059. .long ppc_select
  1060. .long sys_flock
  1061. .long sys_msync
  1062. .long sys_readv /* 145 */
  1063. .long sys_writev
  1064. .long sys_getsid
  1065. .long sys_fdatasync
  1066. .long sys_sysctl
  1067. .long sys_mlock /* 150 */
  1068. .long sys_munlock
  1069. .long sys_mlockall
  1070. .long sys_munlockall
  1071. .long sys_sched_setparam
  1072. .long sys_sched_getparam /* 155 */
  1073. .long sys_sched_setscheduler
  1074. .long sys_sched_getscheduler
  1075. .long sys_sched_yield
  1076. .long sys_sched_get_priority_max
  1077. .long sys_sched_get_priority_min  /* 160 */
  1078. .long sys_sched_rr_get_interval
  1079. .long sys_nanosleep
  1080. .long sys_mremap
  1081. .long sys_setresuid
  1082. .long sys_getresuid /* 165 */
  1083. .long sys_query_module
  1084. .long sys_poll
  1085. .long sys_nfsservctl
  1086. .long sys_setresgid
  1087. .long sys_getresgid /* 170 */
  1088. .long sys_prctl
  1089. .long sys_rt_sigreturn
  1090. .long sys_rt_sigaction
  1091. .long sys_rt_sigprocmask
  1092. .long sys_rt_sigpending /* 175 */
  1093. .long sys_rt_sigtimedwait
  1094. .long sys_rt_sigqueueinfo
  1095. .long sys_rt_sigsuspend
  1096. .long sys_pread
  1097. .long sys_pwrite /* 180 */
  1098. .long sys_chown
  1099. .long sys_getcwd
  1100. .long sys_capget
  1101. .long sys_capset
  1102. .long sys_sigaltstack /* 185 */
  1103. .long sys_sendfile
  1104. .long sys_ni_syscall /* streams1 */
  1105. .long sys_ni_syscall /* streams2 */
  1106. .long sys_vfork
  1107. .long sys_getrlimit /* 190 */
  1108. .long sys_readahead
  1109. .long sys_mmap2
  1110. .long sys_truncate64
  1111. .long sys_ftruncate64
  1112. .long sys_stat64 /* 195 */
  1113. .long sys_lstat64
  1114. .long sys_fstat64
  1115. .long sys_pciconfig_read
  1116. .long sys_pciconfig_write 
  1117. .long sys_pciconfig_iobase  /* 200 */
  1118. .long sys_ni_syscall /* 201 - reserved - MacOnLinux - new */
  1119. .long sys_getdents64
  1120. .long sys_pivot_root
  1121. .long sys_fcntl64
  1122. .long sys_madvise /* 205 */
  1123. .long sys_mincore
  1124. .long sys_gettid
  1125. .rept NR_syscalls-(.-sys_call_table)/4
  1126. .long sys_ni_syscall
  1127. .endr