开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
trampoline.S
资源名称：linux-2.4.20.tar.gz　[点击查看]
上传用户：jlfgdled
上传日期：2013-04-10
资源大小：33168k
文件大小：6k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

trampoline.S：源码内容
  1. /* $Id: trampoline.S,v 1.24 2001/11/16 21:59:20 davem Exp $
  2.  * trampoline.S: Jump start slave processors on sparc64.
  3.  *
  4.  * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
  5.  */
  7. #include <asm/head.h>
  8. #include <asm/asi.h>
  9. #include <asm/lsu.h>
  10. #include <asm/dcr.h>
  11. #include <asm/dcu.h>
  12. #include <asm/pstate.h>
  13. #include <asm/page.h>
  14. #include <asm/pgtable.h>
  15. #include <asm/spitfire.h>
  16. #include <asm/processor.h>
  17. #include <asm/asm_offsets.h>
  19. .data
  20. .align 8
  21. call_method:
  22. .asciz "call-method"
  23. .align 8
  24. itlb_load:
  25. .asciz "SUNW,itlb-load"
  26. .align 8
  27. dtlb_load:
  28. .asciz "SUNW,dtlb-load"
  30. .text
  31. .align 8
  32. .globl sparc64_cpu_startup, sparc64_cpu_startup_end
  33. sparc64_cpu_startup:
  34. flushw
  36. BRANCH_IF_CHEETAH_BASE(g1,g5,cheetah_startup)
  37. BRANCH_IF_CHEETAH_PLUS_OR_FOLLOWON(g1,g5,cheetah_plus_startup)
  39. ba,pt %xcc, spitfire_startup
  40.  nop
  42. cheetah_plus_startup:
  43. /* Preserve OBP choosen DCU and DCR register settings.  */
  44. ba,pt %xcc, cheetah_generic_startup
  45.  nop
  47. cheetah_startup:
  48. mov DCR_BPE | DCR_RPE | DCR_SI | DCR_IFPOE | DCR_MS, %g1
  49. wr %g1, %asr18
  51. sethi %uhi(DCU_ME|DCU_RE|DCU_HPE|DCU_SPE|DCU_SL|DCU_WE), %g5
  52. or %g5, %ulo(DCU_ME|DCU_RE|DCU_HPE|DCU_SPE|DCU_SL|DCU_WE), %g5
  53. sllx %g5, 32, %g5
  54. or %g5, DCU_DM | DCU_IM | DCU_DC | DCU_IC, %g5
  55. stxa %g5, [%g0] ASI_DCU_CONTROL_REG
  56. membar #Sync
  58. cheetah_generic_startup:
  59. mov TSB_EXTENSION_P, %g3
  60. stxa %g0, [%g3] ASI_DMMU
  61. stxa %g0, [%g3] ASI_IMMU
  62. membar #Sync
  64. mov TSB_EXTENSION_S, %g3
  65. stxa %g0, [%g3] ASI_DMMU
  66. membar #Sync
  68. mov TSB_EXTENSION_N, %g3
  69. stxa %g0, [%g3] ASI_DMMU
  70. stxa %g0, [%g3] ASI_IMMU
  71. membar #Sync
  73. /* Disable STICK_INT interrupts. */
  74. sethi %hi(0x80000000), %g5
  75. sllx %g5, 32, %g5
  76. wr %g5, %asr25
  78. ba,pt %xcc, startup_continue
  79.  nop
  81. spitfire_startup:
  82. mov (LSU_CONTROL_IC | LSU_CONTROL_DC | LSU_CONTROL_IM | LSU_CONTROL_DM), %g1
  83. stxa %g1, [%g0] ASI_LSU_CONTROL
  84. membar #Sync
  86. startup_continue:
  87. wrpr %g0, 15, %pil
  88. wr %g0, 0, %tick_cmpr
  90. /* Call OBP by hand to lock KERNBASE into i/d tlbs. */
  91. mov %o0, %l0
  93. sethi %hi(prom_entry_lock), %g2
  94. 1: ldstub [%g2 + %lo(prom_entry_lock)], %g1
  95. brnz,pn %g1, 1b
  96.  membar #StoreLoad | #StoreStore
  98. sethi %hi(p1275buf), %g2
  99. or %g2, %lo(p1275buf), %g2
  100. ldx [%g2 + 0x10], %l2
  101. mov %sp, %l1
  102. add %l2, -(192 + 128), %sp
  103. flushw
  105. sethi %hi(call_method), %g2
  106. or %g2, %lo(call_method), %g2
  107. stx %g2, [%sp + 2047 + 128 + 0x00]
  108. mov 5, %g2
  109. stx %g2, [%sp + 2047 + 128 + 0x08]
  110. mov 1, %g2
  111. stx %g2, [%sp + 2047 + 128 + 0x10]
  112. sethi %hi(itlb_load), %g2
  113. or %g2, %lo(itlb_load), %g2
  114. stx %g2, [%sp + 2047 + 128 + 0x18]
  115. sethi %hi(mmu_ihandle_cache), %g2
  116. lduw [%g2 + %lo(mmu_ihandle_cache)], %g2
  117. stx %g2, [%sp + 2047 + 128 + 0x20]
  118. sethi %hi(KERNBASE), %g2
  119. stx %g2, [%sp + 2047 + 128 + 0x28]
  120. sethi %hi(kern_locked_tte_data), %g2
  121. ldx [%g2 + %lo(kern_locked_tte_data)], %g2
  122. stx %g2, [%sp + 2047 + 128 + 0x30]
  124. mov 15, %g2
  125. BRANCH_IF_ANY_CHEETAH(g1,g5,1f)
  127. mov 63, %g2
  128. 1:
  129. stx %g2, [%sp + 2047 + 128 + 0x38]
  130. sethi %hi(p1275buf), %g2
  131. or %g2, %lo(p1275buf), %g2
  132. ldx [%g2 + 0x08], %o1
  133. call %o1
  134.  add %sp, (2047 + 128), %o0
  136. sethi %hi(call_method), %g2
  137. or %g2, %lo(call_method), %g2
  138. stx %g2, [%sp + 2047 + 128 + 0x00]
  139. mov 5, %g2
  140. stx %g2, [%sp + 2047 + 128 + 0x08]
  141. mov 1, %g2
  142. stx %g2, [%sp + 2047 + 128 + 0x10]
  143. sethi %hi(dtlb_load), %g2
  144. or %g2, %lo(dtlb_load), %g2
  145. stx %g2, [%sp + 2047 + 128 + 0x18]
  146. sethi %hi(mmu_ihandle_cache), %g2
  147. lduw [%g2 + %lo(mmu_ihandle_cache)], %g2
  148. stx %g2, [%sp + 2047 + 128 + 0x20]
  149. sethi %hi(KERNBASE), %g2
  150. stx %g2, [%sp + 2047 + 128 + 0x28]
  151. sethi %hi(kern_locked_tte_data), %g2
  152. ldx [%g2 + %lo(kern_locked_tte_data)], %g2
  153. stx %g2, [%sp + 2047 + 128 + 0x30]
  155. mov 15, %g2
  156. BRANCH_IF_ANY_CHEETAH(g1,g5,1f)
  158. mov 63, %g2
  159. 1:
  161. stx %g2, [%sp + 2047 + 128 + 0x38]
  162. sethi %hi(p1275buf), %g2
  163. or %g2, %lo(p1275buf), %g2
  164. ldx [%g2 + 0x08], %o1
  165. call %o1
  166.  add %sp, (2047 + 128), %o0
  168. sethi %hi(prom_entry_lock), %g2
  169. stb %g0, [%g2 + %lo(prom_entry_lock)]
  170. membar #StoreStore | #StoreLoad
  172. mov %l1, %sp
  173. flushw
  175. mov %l0, %o0
  177. wrpr %g0, (PSTATE_PRIV | PSTATE_PEF), %pstate
  178. wr %g0, 0, %fprs
  180. sethi %uhi(PAGE_OFFSET), %g4
  181. sllx %g4, 32, %g4
  183. /* XXX Buggy PROM... */
  184. srl %o0, 0, %o0
  185. ldx [%o0], %g6
  187. wr %g0, ASI_P, %asi
  189. mov PRIMARY_CONTEXT, %g7
  190. stxa %g0, [%g7] ASI_DMMU
  191. membar #Sync
  192. mov SECONDARY_CONTEXT, %g7
  193. stxa %g0, [%g7] ASI_DMMU
  194. membar #Sync
  196. mov 1, %g5
  197. sllx %g5, THREAD_SHIFT, %g5
  198. sub %g5, (REGWIN_SZ + STACK_BIAS), %g5
  199. add %g6, %g5, %sp
  200. mov 0, %fp
  202. wrpr %g0, 0, %wstate
  203. wrpr %g0, 0, %tl
  205. /* Setup the trap globals, then we can resurface. */
  206. rdpr %pstate, %o1
  207. mov %g6, %o2
  208. wrpr %o1, PSTATE_AG, %pstate
  209. sethi %hi(sparc64_ttable_tl0), %g5
  210. wrpr %g5, %tba
  211. mov %o2, %g6
  213. wrpr %o1, PSTATE_MG, %pstate
  214. #define KERN_HIGHBITS ((_PAGE_VALID|_PAGE_SZ4MB)^0xfffff80000000000)
  215. #define KERN_LOWBITS (_PAGE_CP | _PAGE_CV | _PAGE_P | _PAGE_W)
  217. mov TSB_REG, %g1
  218. stxa %g0, [%g1] ASI_DMMU
  219. membar #Sync
  220. mov TLB_SFSR, %g1
  221. sethi %uhi(KERN_HIGHBITS), %g2
  222. or %g2, %ulo(KERN_HIGHBITS), %g2
  223. sllx %g2, 32, %g2
  224. or %g2, KERN_LOWBITS, %g2
  226. BRANCH_IF_ANY_CHEETAH(g3,g7,9f)
  228. ba,pt %xcc, 1f
  229.  nop
  231. 9:
  232. sethi %uhi(VPTE_BASE_CHEETAH), %g3
  233. or %g3, %ulo(VPTE_BASE_CHEETAH), %g3
  234. ba,pt %xcc, 2f
  235.  sllx %g3, 32, %g3
  236. 1:
  237. sethi %uhi(VPTE_BASE_SPITFIRE), %g3
  238. or %g3, %ulo(VPTE_BASE_SPITFIRE), %g3
  239. sllx %g3, 32, %g3
  241. 2:
  242. clr %g7
  243. #undef KERN_HIGHBITS
  244. #undef KERN_LOWBITS
  246. /* Setup interrupt globals, we are always SMP. */
  247. wrpr %o1, PSTATE_IG, %pstate
  249. /* Get our UPA MID. */
  250. lduw [%o2 + AOFF_task_processor], %g1
  251. sethi %hi(cpu_data), %g5
  252. or %g5, %lo(cpu_data), %g5
  254. /* In theory this is: &(cpu_data[this_upamid].irq_worklists[0]) */
  255. sllx %g1, 7, %g1
  256. add %g5, %g1, %g1
  257. add %g1, 64, %g6
  259. wrpr %g0, 0, %wstate
  260. or %o1, PSTATE_IE, %o1
  261. wrpr %o1, 0, %pstate
  263. call prom_set_trap_table
  264.  sethi %hi(sparc64_ttable_tl0), %o0
  266. call smp_callin
  267.  nop
  268. call cpu_idle
  269.  mov 0, %o0
  270. call cpu_panic
  271.  nop
  272. 1: b,a,pt %xcc, 1b
  274. .align 8
  275. sparc64_cpu_startup_end: