开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
checksum.S
资源名称：linux-2.4.20.tar.gz　[点击查看]
上传用户：jlfgdled
上传日期：2013-04-10
资源大小：33168k
文件大小：17k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

checksum.S：源码内容
  1. /* checksum.S: Sparc optimized checksum code.
  2.  *
  3.  *  Copyright(C) 1995 Linus Torvalds
  4.  *  Copyright(C) 1995 Miguel de Icaza
  5.  *  Copyright(C) 1996 David S. Miller
  6.  *  Copyright(C) 1997 Jakub Jelinek
  7.  *
  8.  * derived from:
  9.  * Linux/Alpha checksum c-code
  10.  *      Linux/ix86 inline checksum assembly
  11.  *      RFC1071 Computing the Internet Checksum (esp. Jacobsons m68k code)
  12.  * David Mosberger-Tang for optimized reference c-code
  13.  * BSD4.4 portable checksum routine
  14.  */
  16. #include <asm/cprefix.h>
  17. #include <asm/errno.h>
  19. #define CSUM_BIGCHUNK(buf, offset, sum, t0, t1, t2, t3, t4, t5)
  20. ldd [buf + offset + 0x00], t0;
  21. ldd [buf + offset + 0x08], t2;
  22. addxcc t0, sum, sum;
  23. addxcc t1, sum, sum;
  24. ldd [buf + offset + 0x10], t4;
  25. addxcc t2, sum, sum;
  26. addxcc t3, sum, sum;
  27. ldd [buf + offset + 0x18], t0;
  28. addxcc t4, sum, sum;
  29. addxcc t5, sum, sum;
  30. addxcc t0, sum, sum;
  31. addxcc t1, sum, sum;
  33. #define CSUM_LASTCHUNK(buf, offset, sum, t0, t1, t2, t3)
  34. ldd [buf - offset - 0x08], t0;
  35. ldd [buf - offset - 0x00], t2;
  36. addxcc t0, sum, sum;
  37. addxcc t1, sum, sum;
  38. addxcc t2, sum, sum;
  39. addxcc t3, sum, sum;
  41. /* Do end cruft out of band to get better cache patterns. */
  42. csum_partial_end_cruft:
  43. be 1f ! caller asks %o1 & 0x8
  44.  andcc %o1, 4, %g0 ! nope, check for word remaining
  45. ldd [%o0], %g2 ! load two
  46. addcc %g2, %o2, %o2 ! add first word to sum
  47. addxcc %g3, %o2, %o2 ! add second word as well
  48. add %o0, 8, %o0 ! advance buf ptr
  49. addx %g0, %o2, %o2 ! add in final carry
  50. andcc %o1, 4, %g0 ! check again for word remaining
  51. 1: be 1f ! nope, skip this code
  52.  andcc %o1, 3, %o1 ! check for trailing bytes
  53. ld [%o0], %g2 ! load it
  54. addcc %g2, %o2, %o2 ! add to sum
  55. add %o0, 4, %o0 ! advance buf ptr
  56. addx %g0, %o2, %o2 ! add in final carry
  57. andcc %o1, 3, %g0 ! check again for trailing bytes
  58. 1: be 1f ! no trailing bytes, return
  59.  addcc %o1, -1, %g0 ! only one byte remains?
  60. bne 2f ! at least two bytes more
  61.  subcc %o1, 2, %o1 ! only two bytes more?
  62. b 4f ! only one byte remains
  63.  or %g0, %g0, %o4 ! clear fake hword value
  64. 2: lduh [%o0], %o4 ! get hword
  65. be 6f ! jmp if only hword remains
  66.  add %o0, 2, %o0 ! advance buf ptr either way
  67. sll %o4, 16, %o4 ! create upper hword
  68. 4: ldub [%o0], %o5 ! get final byte
  69. sll %o5, 8, %o5 ! put into place
  70. or %o5, %o4, %o4 ! coalese with hword (if any)
  71. 6: addcc %o4, %o2, %o2 ! add to sum
  72. 1: retl ! get outta here
  73.  addx %g0, %o2, %o0 ! add final carry into retval
  75. /* Also do alignment out of band to get better cache patterns. */
  76. csum_partial_fix_alignment:
  77. cmp %o1, 6
  78. bl cpte - 0x4
  79.  andcc %o0, 0x2, %g0
  80. be 1f
  81.  andcc %o0, 0x4, %g0
  82. lduh [%o0 + 0x00], %g2
  83. sub %o1, 2, %o1
  84. add %o0, 2, %o0
  85. sll %g2, 16, %g2
  86. addcc %g2, %o2, %o2
  87. srl %o2, 16, %g3
  88. addx %g0, %g3, %g2
  89. sll %o2, 16, %o2
  90. sll %g2, 16, %g3
  91. srl %o2, 16, %o2
  92. andcc %o0, 0x4, %g0
  93. or %g3, %o2, %o2
  94. 1: be cpa
  95.  andcc %o1, 0xffffff80, %o3
  96. ld [%o0 + 0x00], %g2
  97. sub %o1, 4, %o1
  98. addcc %g2, %o2, %o2
  99. add %o0, 4, %o0
  100. addx %g0, %o2, %o2
  101. b cpa
  102.  andcc %o1, 0xffffff80, %o3
  104. /* The common case is to get called with a nicely aligned
  105.  * buffer of size 0x20.  Follow the code path for that case.
  106.  */
  107. .globl C_LABEL(csum_partial)
  108. C_LABEL(csum_partial): /* %o0=buf, %o1=len, %o2=sum */
  109. andcc %o0, 0x7, %g0 ! alignment problems?
  110. bne csum_partial_fix_alignment ! yep, handle it
  111.  sethi %hi(cpte - 8), %g7 ! prepare table jmp ptr
  112. andcc %o1, 0xffffff80, %o3 ! num loop iterations
  113. cpa: be 3f ! none to do
  114.  andcc %o1, 0x70, %g1 ! clears carry flag too
  115. 5: CSUM_BIGCHUNK(%o0, 0x00, %o2, %o4, %o5, %g2, %g3, %g4, %g5)
  116. CSUM_BIGCHUNK(%o0, 0x20, %o2, %o4, %o5, %g2, %g3, %g4, %g5)
  117. CSUM_BIGCHUNK(%o0, 0x40, %o2, %o4, %o5, %g2, %g3, %g4, %g5)
  118. CSUM_BIGCHUNK(%o0, 0x60, %o2, %o4, %o5, %g2, %g3, %g4, %g5)
  119. addx %g0, %o2, %o2 ! sink in final carry
  120. subcc %o3, 128, %o3 ! detract from loop iters
  121. bne 5b ! more to do
  122.  add %o0, 128, %o0 ! advance buf ptr
  123. andcc %o1, 0x70, %g1 ! clears carry flag too
  124. 3: be cpte ! nope
  125.  andcc %o1, 0xf, %g0 ! anything left at all?
  126. srl %g1, 1, %o4 ! compute offset
  127. sub %g7, %g1, %g7 ! adjust jmp ptr
  128. sub %g7, %o4, %g7 ! final jmp ptr adjust
  129. jmp %g7 + %lo(cpte - 8) ! enter the table
  130.  add %o0, %g1, %o0 ! advance buf ptr
  131. cptbl: CSUM_LASTCHUNK(%o0, 0x68, %o2, %g2, %g3, %g4, %g5)
  132. CSUM_LASTCHUNK(%o0, 0x58, %o2, %g2, %g3, %g4, %g5)
  133. CSUM_LASTCHUNK(%o0, 0x48, %o2, %g2, %g3, %g4, %g5)
  134. CSUM_LASTCHUNK(%o0, 0x38, %o2, %g2, %g3, %g4, %g5)
  135. CSUM_LASTCHUNK(%o0, 0x28, %o2, %g2, %g3, %g4, %g5)
  136. CSUM_LASTCHUNK(%o0, 0x18, %o2, %g2, %g3, %g4, %g5)
  137. CSUM_LASTCHUNK(%o0, 0x08, %o2, %g2, %g3, %g4, %g5)
  138. addx %g0, %o2, %o2 ! fetch final carry
  139. andcc %o1, 0xf, %g0 ! anything left at all?
  140. cpte: bne csum_partial_end_cruft ! yep, handle it
  141.  andcc %o1, 8, %g0 ! check how much
  142. cpout: retl ! get outta here
  143.  mov %o2, %o0 ! return computed csum
  145. .globl C_LABEL(__csum_partial_copy_start), C_LABEL(__csum_partial_copy_end)
  146. C_LABEL(__csum_partial_copy_start):
  148. #define EX(x,y,a,b,z)                           
  149. 98:     x,y;                                    
  150.         .section .fixup,z##alloc,z##execinstr;  
  151.         .align  4;                              
  152. 99:     ba 30f;                                 
  153.          a, b, %o3;                             
  154.         .section __ex_table,z##alloc;           
  155.         .align  4;                              
  156.         .word   98b, 99b;                       
  157.         .text;                                  
  158.         .align  4
  160. #define EX2(x,y,z)                          
  161. 98:     x,y;                                    
  162.         .section __ex_table,z##alloc;           
  163.         .align  4;                              
  164.         .word   98b, 30f;                       
  165.         .text;                                  
  166.         .align  4
  168. #define EX3(x,y,z)                          
  169. 98:     x,y;                                    
  170.         .section __ex_table,z##alloc;           
  171.         .align  4;                              
  172.         .word   98b, 96f;                       
  173.         .text;                                  
  174.         .align  4
  176. #define EXT(start,end,handler,z)                
  177.         .section __ex_table,z##alloc;           
  178.         .align  4;                              
  179.         .word   start, 0, end, handler;         
  180.         .text;                                  
  181.         .align  4
  183. /* This aligned version executes typically in 8.5 superscalar cycles, this
  184.  * is the best I can do.  I say 8.5 because the final add will pair with
  185.  * the next ldd in the main unrolled loop.  Thus the pipe is always full.
  186.  * If you change these macros (including order of instructions),
  187.  * please check the fixup code below as well.
  188.  */
  189. #define CSUMCOPY_BIGCHUNK_ALIGNED(src, dst, sum, off, t0, t1, t2, t3, t4, t5, t6, t7)
  190. ldd [src + off + 0x00], t0;
  191. ldd [src + off + 0x08], t2;
  192. addxcc t0, sum, sum;
  193. ldd [src + off + 0x10], t4;
  194. addxcc t1, sum, sum;
  195. ldd [src + off + 0x18], t6;
  196. addxcc t2, sum, sum;
  197. std t0, [dst + off + 0x00];
  198. addxcc t3, sum, sum;
  199. std t2, [dst + off + 0x08];
  200. addxcc t4, sum, sum;
  201. std t4, [dst + off + 0x10];
  202. addxcc t5, sum, sum;
  203. std t6, [dst + off + 0x18];
  204. addxcc t6, sum, sum;
  205. addxcc t7, sum, sum;
  207. /* 12 superscalar cycles seems to be the limit for this case,
  208.  * because of this we thus do all the ldd's together to get
  209.  * Viking MXCC into streaming mode.  Ho hum...
  210.  */
  211. #define CSUMCOPY_BIGCHUNK(src, dst, sum, off, t0, t1, t2, t3, t4, t5, t6, t7)
  212. ldd [src + off + 0x00], t0;
  213. ldd [src + off + 0x08], t2;
  214. ldd [src + off + 0x10], t4;
  215. ldd [src + off + 0x18], t6;
  216. st t0, [dst + off + 0x00];
  217. addxcc t0, sum, sum;
  218. st t1, [dst + off + 0x04];
  219. addxcc t1, sum, sum;
  220. st t2, [dst + off + 0x08];
  221. addxcc t2, sum, sum;
  222. st t3, [dst + off + 0x0c];
  223. addxcc t3, sum, sum;
  224. st t4, [dst + off + 0x10];
  225. addxcc t4, sum, sum;
  226. st t5, [dst + off + 0x14];
  227. addxcc t5, sum, sum;
  228. st t6, [dst + off + 0x18];
  229. addxcc t6, sum, sum;
  230. st t7, [dst + off + 0x1c];
  231. addxcc t7, sum, sum;
  233. /* Yuck, 6 superscalar cycles... */
  234. #define CSUMCOPY_LASTCHUNK(src, dst, sum, off, t0, t1, t2, t3)
  235. ldd [src - off - 0x08], t0;
  236. ldd [src - off - 0x00], t2;
  237. addxcc t0, sum, sum;
  238. st t0, [dst - off - 0x08];
  239. addxcc t1, sum, sum;
  240. st t1, [dst - off - 0x04];
  241. addxcc t2, sum, sum;
  242. st t2, [dst - off - 0x00];
  243. addxcc t3, sum, sum;
  244. st t3, [dst - off + 0x04];
  246. /* Handle the end cruft code out of band for better cache patterns. */
  247. cc_end_cruft:
  248. be 1f
  249.  andcc %o3, 4, %g0
  250. EX(ldd [%o0 + 0x00], %g2, and %o3, 0xf,#)
  251. add %o1, 8, %o1
  252. addcc %g2, %g7, %g7
  253. add %o0, 8, %o0
  254. addxcc %g3, %g7, %g7
  255. EX2(st %g2, [%o1 - 0x08],#)
  256. addx %g0, %g7, %g7
  257. andcc %o3, 4, %g0
  258. EX2(st %g3, [%o1 - 0x04],#)
  259. 1: be 1f
  260.  andcc %o3, 3, %o3
  261. EX(ld [%o0 + 0x00], %g2, add %o3, 4,#)
  262. add %o1, 4, %o1
  263. addcc %g2, %g7, %g7
  264. EX2(st %g2, [%o1 - 0x04],#)
  265. addx %g0, %g7, %g7
  266. andcc %o3, 3, %g0
  267. add %o0, 4, %o0
  268. 1: be 1f
  269.  addcc %o3, -1, %g0
  270. bne 2f
  271.  subcc %o3, 2, %o3
  272. b 4f
  273.  or %g0, %g0, %o4
  274. 2: EX(lduh [%o0 + 0x00], %o4, add %o3, 2,#)
  275. add %o0, 2, %o0
  276. EX2(sth %o4, [%o1 + 0x00],#)
  277. be 6f
  278.  add %o1, 2, %o1
  279. sll %o4, 16, %o4
  280. 4: EX(ldub [%o0 + 0x00], %o5, add %g0, 1,#)
  281. EX2(stb %o5, [%o1 + 0x00],#)
  282. sll %o5, 8, %o5
  283. or %o5, %o4, %o4
  284. 6: addcc %o4, %g7, %g7
  285. 1: retl
  286.  addx %g0, %g7, %o0
  288. /* Also, handle the alignment code out of band. */
  289. cc_dword_align:
  290. cmp %g1, 6
  291. bl,a ccte
  292.  andcc %g1, 0xf, %o3
  293. andcc %o0, 0x1, %g0
  294. bne ccslow
  295.  andcc %o0, 0x2, %g0
  296. be 1f
  297.  andcc %o0, 0x4, %g0
  298. EX(lduh [%o0 + 0x00], %g4, add %g1, 0,#)
  299. sub %g1, 2, %g1
  300. EX2(sth %g4, [%o1 + 0x00],#)
  301. add %o0, 2, %o0
  302. sll %g4, 16, %g4
  303. addcc %g4, %g7, %g7
  304. add %o1, 2, %o1
  305. srl %g7, 16, %g3
  306. addx %g0, %g3, %g4
  307. sll %g7, 16, %g7
  308. sll %g4, 16, %g3
  309. srl %g7, 16, %g7
  310. andcc %o0, 0x4, %g0
  311. or %g3, %g7, %g7
  312. 1: be 3f
  313.  andcc %g1, 0xffffff80, %g0
  314. EX(ld [%o0 + 0x00], %g4, add %g1, 0,#)
  315. sub %g1, 4, %g1
  316. EX2(st %g4, [%o1 + 0x00],#)
  317. add %o0, 4, %o0
  318. addcc %g4, %g7, %g7
  319. add %o1, 4, %o1
  320. addx %g0, %g7, %g7
  321. b 3f
  322.  andcc %g1, 0xffffff80, %g0
  324. /* Sun, you just can't beat me, you just can't.  Stop trying,
  325.  * give up.  I'm serious, I am going to kick the living shit
  326.  * out of you, game over, lights out.
  327.  */
  328. .align 8
  329. .globl C_LABEL(__csum_partial_copy_sparc_generic)
  330. C_LABEL(__csum_partial_copy_sparc_generic):
  331. /* %o0=src, %o1=dest, %g1=len, %g7=sum */
  332. xor %o0, %o1, %o4 ! get changing bits
  333. andcc %o4, 3, %g0 ! check for mismatched alignment
  334. bne ccslow ! better this than unaligned/fixups
  335.  andcc %o0, 7, %g0 ! need to align things?
  336. bne cc_dword_align ! yes, we check for short lengths there
  337.  andcc %g1, 0xffffff80, %g0 ! can we use unrolled loop?
  338. 3: be 3f ! nope, less than one loop remains
  339.  andcc %o1, 4, %g0 ! dest aligned on 4 or 8 byte boundry?
  340. be ccdbl + 4 ! 8 byte aligned, kick ass
  341. 5: CSUMCOPY_BIGCHUNK(%o0,%o1,%g7,0x00,%o4,%o5,%g2,%g3,%g4,%g5,%o2,%o3)
  342. CSUMCOPY_BIGCHUNK(%o0,%o1,%g7,0x20,%o4,%o5,%g2,%g3,%g4,%g5,%o2,%o3)
  343. CSUMCOPY_BIGCHUNK(%o0,%o1,%g7,0x40,%o4,%o5,%g2,%g3,%g4,%g5,%o2,%o3)
  344. CSUMCOPY_BIGCHUNK(%o0,%o1,%g7,0x60,%o4,%o5,%g2,%g3,%g4,%g5,%o2,%o3)
  345. 10: EXT(5b, 10b, 20f,#) ! note for exception handling
  346. sub %g1, 128, %g1 ! detract from length
  347. addx %g0, %g7, %g7 ! add in last carry bit
  348. andcc %g1, 0xffffff80, %g0 ! more to csum?
  349. add %o0, 128, %o0 ! advance src ptr
  350. bne 5b ! we did not go negative, continue looping
  351.  add %o1, 128, %o1 ! advance dest ptr
  352. 3: andcc %g1, 0x70, %o2 ! can use table?
  353. ccmerge:be ccte ! nope, go and check for end cruft
  354.  andcc %g1, 0xf, %o3 ! get low bits of length (clears carry btw)
  355. srl %o2, 1, %o4 ! begin negative offset computation
  356. sethi %hi(12f), %o5 ! set up table ptr end
  357. add %o0, %o2, %o0 ! advance src ptr
  358. sub %o5, %o4, %o5 ! continue table calculation
  359. sll %o2, 1, %g2 ! constant multiplies are fun...
  360. sub %o5, %g2, %o5 ! some more adjustments
  361. jmp %o5 + %lo(12f) ! jump into it, duff style, wheee...
  362.  add %o1, %o2, %o1 ! advance dest ptr (carry is clear btw)
  363. cctbl: CSUMCOPY_LASTCHUNK(%o0,%o1,%g7,0x68,%g2,%g3,%g4,%g5)
  364. CSUMCOPY_LASTCHUNK(%o0,%o1,%g7,0x58,%g2,%g3,%g4,%g5)
  365. CSUMCOPY_LASTCHUNK(%o0,%o1,%g7,0x48,%g2,%g3,%g4,%g5)
  366. CSUMCOPY_LASTCHUNK(%o0,%o1,%g7,0x38,%g2,%g3,%g4,%g5)
  367. CSUMCOPY_LASTCHUNK(%o0,%o1,%g7,0x28,%g2,%g3,%g4,%g5)
  368. CSUMCOPY_LASTCHUNK(%o0,%o1,%g7,0x18,%g2,%g3,%g4,%g5)
  369. CSUMCOPY_LASTCHUNK(%o0,%o1,%g7,0x08,%g2,%g3,%g4,%g5)
  370. 12: EXT(cctbl, 12b, 22f,#) ! note for exception table handling
  371. addx %g0, %g7, %g7
  372. andcc %o3, 0xf, %g0 ! check for low bits set
  373. ccte: bne cc_end_cruft ! something left, handle it out of band
  374.  andcc %o3, 8, %g0 ! begin checks for that code
  375. retl ! return
  376.  mov %g7, %o0 ! give em the computed checksum
  377. ccdbl: CSUMCOPY_BIGCHUNK_ALIGNED(%o0,%o1,%g7,0x00,%o4,%o5,%g2,%g3,%g4,%g5,%o2,%o3)
  378. CSUMCOPY_BIGCHUNK_ALIGNED(%o0,%o1,%g7,0x20,%o4,%o5,%g2,%g3,%g4,%g5,%o2,%o3)
  379. CSUMCOPY_BIGCHUNK_ALIGNED(%o0,%o1,%g7,0x40,%o4,%o5,%g2,%g3,%g4,%g5,%o2,%o3)
  380. CSUMCOPY_BIGCHUNK_ALIGNED(%o0,%o1,%g7,0x60,%o4,%o5,%g2,%g3,%g4,%g5,%o2,%o3)
  381. 11: EXT(ccdbl, 11b, 21f,#) ! note for exception table handling
  382. sub %g1, 128, %g1 ! detract from length
  383. addx %g0, %g7, %g7 ! add in last carry bit
  384. andcc %g1, 0xffffff80, %g0 ! more to csum?
  385. add %o0, 128, %o0 ! advance src ptr
  386. bne ccdbl ! we did not go negative, continue looping
  387.  add %o1, 128, %o1 ! advance dest ptr
  388. b ccmerge ! finish it off, above
  389.  andcc %g1, 0x70, %o2 ! can use table? (clears carry btw)
  391. ccslow: cmp %g1, 0
  392. mov 0, %g5
  393. bleu 4f
  394.  andcc %o0, 1, %o5
  395. be,a 1f
  396.  srl %g1, 1, %g4
  397. sub %g1, 1, %g1
  398. EX(ldub [%o0], %g5, add %g1, 1,#)
  399. add %o0, 1, %o0
  400. EX2(stb %g5, [%o1],#)
  401. srl %g1, 1, %g4
  402. add %o1, 1, %o1
  403. 1: cmp %g4, 0
  404. be,a 3f
  405.  andcc %g1, 1, %g0
  406. andcc %o0, 2, %g0
  407. be,a 1f
  408.  srl %g4, 1, %g4
  409. EX(lduh [%o0], %o4, add %g1, 0,#)
  410. sub %g1, 2, %g1
  411. srl %o4, 8, %g2
  412. sub %g4, 1, %g4
  413. EX2(stb %g2, [%o1],#)
  414. add %o4, %g5, %g5
  415. EX2(stb %o4, [%o1 + 1],#)
  416. add %o0, 2, %o0
  417. srl %g4, 1, %g4
  418. add %o1, 2, %o1
  419. 1: cmp %g4, 0
  420. be,a 2f
  421.  andcc %g1, 2, %g0
  422. EX3(ld [%o0], %o4,#)
  423. 5: srl %o4, 24, %g2
  424. srl %o4, 16, %g3
  425. EX2(stb %g2, [%o1],#)
  426. srl %o4, 8, %g2
  427. EX2(stb %g3, [%o1 + 1],#)
  428. add %o0, 4, %o0
  429. EX2(stb %g2, [%o1 + 2],#)
  430. addcc %o4, %g5, %g5
  431. EX2(stb %o4, [%o1 + 3],#)
  432. addx %g5, %g0, %g5 ! I am now to lazy to optimize this (question it
  433. add %o1, 4, %o1 ! is worthy). Maybe some day - with the sll/srl
  434. subcc %g4, 1, %g4 ! tricks
  435. bne,a 5b
  436.  EX3(ld [%o0], %o4,#)
  437. sll %g5, 16, %g2
  438. srl %g5, 16, %g5
  439. srl %g2, 16, %g2
  440. andcc %g1, 2, %g0
  441. add %g2, %g5, %g5 
  442. 2: be,a 3f
  443.  andcc %g1, 1, %g0
  444. EX(lduh [%o0], %o4, and %g1, 3,#)
  445. andcc %g1, 1, %g0
  446. srl %o4, 8, %g2
  447. add %o0, 2, %o0
  448. EX2(stb %g2, [%o1],#)
  449. add %g5, %o4, %g5
  450. EX2(stb %o4, [%o1 + 1],#)
  451. add %o1, 2, %o1
  452. 3: be,a 1f
  453.  sll %g5, 16, %o4
  454. EX(ldub [%o0], %g2, add %g0, 1,#)
  455. sll %g2, 8, %o4
  456. EX2(stb %g2, [%o1],#)
  457. add %g5, %o4, %g5
  458. sll %g5, 16, %o4
  459. 1: addcc %o4, %g5, %g5
  460. srl %g5, 16, %o4
  461. addx %g0, %o4, %g5
  462. orcc %o5, %g0, %g0
  463. be 4f
  464.  srl %g5, 8, %o4
  465. and %g5, 0xff, %g2
  466. and %o4, 0xff, %o4
  467. sll %g2, 8, %g2
  468. or %g2, %o4, %g5
  469. 4: addcc %g7, %g5, %g7
  470. retl
  471.  addx %g0, %g7, %o0
  472. C_LABEL(__csum_partial_copy_end):
  474. /* We do these strange calculations for the csum_*_from_user case only, ie.
  475.  * we only bother with faults on loads... */
  477. /* o2 = ((g2%20)&3)*8
  478.  * o3 = g1 - (g2/20)*32 - o2 */
  479. 20:
  480. cmp %g2, 20
  481. blu,a 1f
  482.  and %g2, 3, %o2
  483. sub %g1, 32, %g1
  484. b 20b
  485.  sub %g2, 20, %g2
  486. 1:
  487. sll %o2, 3, %o2
  488. b 31f
  489.  sub %g1, %o2, %o3
  491. /* o2 = (!(g2 & 15) ? 0 : (((g2 & 15) + 1) & ~1)*8)
  492.  * o3 = g1 - (g2/16)*32 - o2 */
  493. 21:
  494. andcc %g2, 15, %o3
  495. srl %g2, 4, %g2
  496. be,a 1f
  497.  clr %o2
  498. add %o3, 1, %o3
  499. and %o3, 14, %o3
  500. sll %o3, 3, %o2
  501. 1:
  502. sll %g2, 5, %g2
  503. sub %g1, %g2, %o3
  504. b 31f
  505.  sub %o3, %o2, %o3
  507. /* o0 += (g2/10)*16 - 0x70
  508.  * 01 += (g2/10)*16 - 0x70
  509.  * o2 = (g2 % 10) ? 8 : 0
  510.  * o3 += 0x70 - (g2/10)*16 - o2 */
  511. 22:
  512. cmp %g2, 10
  513. blu,a 1f
  514.  sub %o0, 0x70, %o0
  515. add %o0, 16, %o0
  516. add %o1, 16, %o1
  517. sub %o3, 16, %o3
  518. b 22b
  519.  sub %g2, 10, %g2
  520. 1:
  521. sub %o1, 0x70, %o1
  522. add %o3, 0x70, %o3
  523. clr %o2
  524. tst %g2
  525. bne,a 1f
  526.  mov 8, %o2
  527. 1:
  528. b 31f
  529.  sub %o3, %o2, %o3
  530. 96:
  531. and %g1, 3, %g1
  532. sll %g4, 2, %g4
  533. add %g1, %g4, %o3
  534. 30:
  535. /* %o1 is dst
  536.  * %o3 is # bytes to zero out
  537.  * %o4 is faulting address
  538.  * %o5 is %pc where fault occurred */
  539. clr %o2
  540. 31:
  541. /* %o0 is src
  542.  * %o1 is dst
  543.  * %o2 is # of bytes to copy from src to dst
  544.  * %o3 is # bytes to zero out
  545.  * %o4 is faulting address
  546.  * %o5 is %pc where fault occurred */
  547. save %sp, -104, %sp
  548.         mov     %i5, %o0
  549.         mov     %i7, %o1
  550.         mov %i4, %o2
  551.         call    C_LABEL(lookup_fault)
  552.  mov %g7, %i4
  553. cmp %o0, 2
  554. bne 1f
  555.  add %g0, -EFAULT, %i5
  556. tst %i2
  557. be 2f
  558.  mov %i0, %o1
  559. mov %i1, %o0
  560. 5:
  561. call C_LABEL(__memcpy)
  562.  mov %i2, %o2
  563. tst %o0
  564. bne,a 2f
  565.  add %i3, %i2, %i3
  566. add %i1, %i2, %i1
  567. 2:
  568. mov %i1, %o0
  569. 6:
  570. call C_LABEL(__bzero)
  571.  mov %i3, %o1
  572. 1:
  573. ld [%sp + 168], %o2 ! struct_ptr of parent
  574. st %i5, [%o2]
  575. ret
  576.  restore
  578.         .section __ex_table,#alloc
  579.         .align 4
  580.         .word 5b,2
  581. .word 6b,2