开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
head64.S
资源名称：linux-2.4.20.tar.gz　[点击查看]
上传用户：jlfgdled
上传日期：2013-04-10
资源大小：33168k
文件大小：8k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

head64.S：源码内容
  1. /*
  2.  *
  3.  * This file is subject to the terms and conditions of the GNU General Public
  4.  * License.  See the file "COPYING" in the main directory of this archive
  5.  * for more details.
  6.  *
  7.  * Copyright (C) 1999 by Helge Deller
  8.  * Copyright 1999 SuSE GmbH (Philipp Rumpf)
  9.  * Copyright 1999 Philipp Rumpf (prumpf@tux.org)
  10.  * Copyright 2000 Hewlett Packard (Paul Bame, bame@puffin.external.hp.com)
  11.  * Copyright (C) 2001 Grant Grundler (Hewlett Packard)
  12.  *
  13.  * Initial Version 04-23-1999 by Helge Deller <deller@gmx.de>
  14.  */
  17. #include <linux/autoconf.h> /* for CONFIG_SMP */
  19. #include <asm/offset.h>
  20. #include <asm/psw.h>
  22. #include <asm/assembly.h>
  23. #include <asm/pgtable.h>
  24. #include <asm/pdc.h> /* for PDC_PSW defines */
  27. .level 2.0
  29. .section .initcall.init
  30. .align 4
  31. .export __initcall_start
  32. __initcall_start:
  33. .export __initcall_end
  34. __initcall_end:
  35. .export __setup_start
  36. __setup_start:
  37. .export __setup_end
  38. __setup_end:
  40. .data
  42. .export boot_args
  43. boot_args:
  44. .word 0 /* arg0 */
  45. .word 0 /* arg1 */
  46. .word 0 /* arg2 */
  47. .word 0 /* arg3 */
  49. .text
  50. .align 4
  52. .export stext
  53. .export _stext,data /* Kernel want it this way! */
  54. _stext:
  55. stext:
  56. .proc
  57. .callinfo
  59. /* Make sure sr4-sr7 are set to zero for the kernel address space */
  60. mtsp %r0,%sr4
  61. mtsp %r0,%sr5
  62. mtsp %r0,%sr6
  63. mtsp %r0,%sr7
  65. /* Clear BSS (shouldn't the boot loader do this?) */
  67. .import _edata,data
  68. .import _end,data
  70. ldil            L%PA(_edata),%r3
  71. ldo             R%PA(_edata)(%r3),%r3
  72. ldil            L%PA(_end),%r4
  73. ldo             R%PA(_end)(%r4),%r4
  74. $bss_loop:
  75. cmpb,<<,n       %r3,%r4,$bss_loop
  76. stb,ma          %r0,1(%r3)
  78. /* Save away the arguments the boot loader passed in (32 bit args) */
  80. ldil            L%PA(boot_args),%r1
  81. ldo             R%PA(boot_args)(%r1),%r1
  82. stw,ma          %arg0,4(%r1)
  83. stw,ma          %arg1,4(%r1)
  84. stw,ma          %arg2,4(%r1)
  85. stw,ma          %arg3,4(%r1)
  87. /* Initialize startup VM. Just map first 8 MB of memory */
  89. ldil L%PA(pg0),%r1
  90. ldo R%PA(pg0)(%r1),%r1
  92. ldil L%PA(pmd0),%r5
  93. ldo R%PA(pmd0)(%r5),%r5
  94. ldo _PAGE_TABLE(%r5),%r3
  96. ldil L%PA(swapper_pg_dir),%r4
  97. ldo R%PA(swapper_pg_dir)(%r4),%r4
  99. mtctl %r4,%cr24 /* Initialize kernel root pointer */
  100. mtctl %r4,%cr25 /* Initialize user root pointer */
  102. #if (__PAGE_OFFSET != 0x10000000UL)
  103. Error! Code below (the next five std's) needs to be changed
  104. #endif
  106. std             %r3,0x00(%r4)   /* Hardwired 0x1... kernel Vaddr start*/
  108. ldo _PAGE_TABLE(%r1),%r3
  109. std             %r3,0x400(%r5)  /* Hardwired 0x1... kernel Vaddr start*/
  110. ldo 0x1000(%r3),%r3
  111. std             %r3,0x408(%r5)
  112. ldo 0x1000(%r3),%r3
  113. std             %r3,0x410(%r5)
  114. ldo 0x1000(%r3),%r3
  115. std             %r3,0x418(%r5)
  117. ldo _PAGE_KERNEL(%r0),%r3 /* Hardwired 0 phys addr start */
  118. $pgt_fill_loop:
  119. std,ma %r3,8(%r1)
  120. ldo 0x1000(%r3),%r3
  121. bb,>= %r3,8,$pgt_fill_loop
  122. nop
  124. /* And the RFI Target address too */
  125. load32          start_kernel, %r11
  127. /* And the stack pointer too */
  128. load32 PA(init_task_union+TASK_SZ_ALGN),%sp
  130. /* And the initial task pointer */
  132. load32          init_task_union,%r6
  133. mtctl           %r6,%cr30
  135. /* And the interrupt stack */
  137. load32          interrupt_stack,%r6
  138. mtctl           %r6,%cr31
  140. /* Act like PDC just called us - that's how slave CPUs enter */
  141. #define MEM_PDC_LO 0x388
  142. #define MEM_PDC_HI 0x35C
  143. ldw MEM_PDC_LO(%r0),%r3
  144. ldw MEM_PDC_HI(%r0),%r6
  145. depd %r6, 31, 32, %r3 /* move to upper word */
  147. #ifdef CONFIG_SMP
  148. /* Set the smp rendevous address into page zero.
  149. ** It would be safer to do this in init_smp_config() but
  150. ** it's just way easier to deal with here because
  151. ** of 64-bit function ptrs and the address is local to this file.
  152. */
  153. ldil L%PA(smp_slave_stext),%r10
  154. ldo R%PA(smp_slave_stext)(%r10),%r10
  155. stw %r10,0x10(%r0) /* MEM_RENDEZ */
  156. stw %r0,0x28(%r0) /* MEM_RENDEZ_HI - assume addr < 4GB */
  158. /* FALLTHROUGH */
  159. .procend
  161. /*
  162. ** Code Common to both Monarch and Slave processors.
  163. ** Entry:
  164. **    %r3 PDCE_PROC address
  165. **    %r11 RFI target address.
  166. **
  167. ** Caller must init: SR4-7, %sp, %r10, %cr24/25, 
  168. */
  169. common_stext:
  170. .proc
  171. .callinfo
  172. #else /* CONFIG_SMP */
  173. /* Clear PDC's CPU handoff address - we won't use it */
  174. stw %r0,0x10(%r0) /* MEM_RENDEZ */
  175. stw %r0,0x28(%r0) /* MEM_RENDEZ_HI */
  176. #endif /* CONFIG_SMP */
  178. /* Save the rfi target address */
  179. std %r11,  TASK_PT_GR11-TASK_SZ_ALGN(%sp)
  181. #ifndef CONFIG_PDC_NARROW
  182. /* Switch to wide mode; Superdome doesn't support narrow PDC
  183. ** calls.
  184. */
  185. 1: mfia %rp /* clear upper part of pcoq */
  186. ldo 2f-1b(%rp),%rp
  187. depdi 0,31,32,%rp
  188. bv (%rp)
  189. ssm PSW_SM_W,%r0
  190. 2:
  191. #endif /* CONFIG_PDC_NARROW */
  193. /* Set Wide mode as the "Default" (eg for traps)
  194. ** First trap occurs *right* after (or part of) rfi for slave CPUs.
  195. ** Someday, palo might not do this for the Monarch either.
  196. */
  198. ldo PDC_PSW(%r0),%arg0 /* 21 */
  199. ldo PDC_PSW_SET_DEFAULTS(%r0),%arg1 /* 2 */
  200. ldo PDC_PSW_WIDE_BIT(%r0),%arg2 /* 2 */
  202. load32 PA(stext_pdc_ret), %rp
  204. bv (%r3)
  205. copy %r0,%arg3
  207. stext_pdc_ret:
  208. /* restore rfi target address*/
  209. ldd TASK_PT_GR11-TASK_SZ_ALGN(%sp), %r11
  211. /* PARANOID: clear user scratch/user space SR's */
  212. mtsp %r0,%sr0
  213. mtsp %r0,%sr1
  214. mtsp %r0,%sr2
  215. mtsp %r0,%sr3
  217. /* Initialize Protection Registers */
  218. mtctl %r0,%cr8
  219. mtctl %r0,%cr9
  220. mtctl %r0,%cr12
  221. mtctl %r0,%cr13
  223. /* Prepare to RFI! Man all the cannons! */
  224. tovirt_r1       %sp
  226. /* Initialize the global data pointer */
  227. load32 __gp,%dp
  229. /* Set up our interrupt table.  HPMCs might not work after this! */
  230. ldil L%PA(fault_vector_20),%r10
  231. ldo R%PA(fault_vector_20)(%r10),%r10
  232. mtctl %r10,%cr14
  234. b aligned_rfi
  235. nop
  237. /* the magic spell */
  238. .align          256
  239. aligned_rfi:
  240. ssm 0,0
  241. nop /* 1 */
  242. nop /* 2 */
  243. nop /* 3 */
  244. nop /* 4 */
  245. nop /* 5 */
  246. nop /* 6 */
  247. nop /* 7 */
  248. nop /* 8 */
  250. /* turn off troublesome PSW bits */
  251. rsm PSW_Q+PSW_I+PSW_D+PSW_P+PSW_R, %r0
  253. /* kernel PSW:
  254.  *  - no interruptions except HPMC and TOC (which are handled by PDC)
  255.  *  - Q bit set (IODC / PDC interruptions)
  256.  *  - big-endian
  257.  *  - virtually mapped
  258.  */
  259. load32 KERNEL_PSW,%r10
  260. mtctl %r10,%ipsw
  262. /* Set the space pointers for the post-RFI world
  263. ** Clear the two-level IIA Space Queue, effectively setting
  264. ** Kernel space.
  265. */
  266. mtctl %r0,%cr17
  267. mtctl %r0,%cr17
  269. /* Load RFI target into PC queue */
  270. mtctl %r11,%cr18
  271. ldo 4(%r11),%r11
  272. mtctl %r11,%cr18
  274. /* Jump to hyperspace */
  275. rfi
  276. nop
  278. .procend
  281. #ifdef CONFIG_SMP
  283. .import smp_init_current_idle_task,data
  284. .import smp_callin,code
  286. /***************************************************************************
  287. *
  288. * smp_slave_stext is executed by all non-monarch Processors when the Monarch
  289. * pokes the slave CPUs in smp.c:smp_boot_cpus().
  290. *
  291. * Once here, registers values are initialized in order to branch to virtual
  292. * mode. Once all available/eligible CPUs are in virtual mode, all are
  293. * released and start out by executing their own idle task.
  294. *****************************************************************************/
  297. smp_slave_stext:
  298.         .proc
  299. .callinfo
  301. /*
  302. ** Initialize Space registers
  303. */
  304. mtsp    %r0,%sr4
  305. mtsp    %r0,%sr5
  306. mtsp    %r0,%sr6
  307. mtsp    %r0,%sr7
  309. /*  Initialize the SP - monarch sets up smp_init_current_idle_task */
  310. load32 PA(smp_init_current_idle_task),%sp
  311. ldd 0(%sp),%sp /* load task address */
  312. mtctl           %sp,%cr30       /* store in cr30 */
  313. ldo             TASK_SZ_ALGN(%sp),%sp
  314. tophys_r1       %sp
  316. /* point CPU to kernel page tables */
  317. load32 PA(swapper_pg_dir),%r4
  318. mtctl %r4,%cr24 /* Initialize kernel root pointer */
  319. mtctl %r4,%cr25 /* Initialize user root pointer */
  321. /* Setup PDCE_PROC entry */
  322. copy %arg0,%r3
  324. /* Load RFI target address.  */
  325. load32 smp_callin, %r11
  327. /* ok...common code can handle the rest */
  328. b common_stext
  329. nop
  331. .procend
  332. #endif /* CONFIG_SMP */