开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
entry.S
资源名称：linux-2.4.20.tar.gz　[点击查看]
上传用户：jlfgdled
上传日期：2013-04-10
资源大小：33168k
文件大小：33k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

entry.S：源码内容
  1. /* $Id: entry.S,v 1.39 2002/04/24 00:46:45 bjornw Exp $
  2.  *
  3.  *  linux/arch/cris/entry.S
  4.  *
  5.  *  Copyright (C) 2000, 2001, 2002 Axis Communications AB
  6.  *
  7.  *  Authors: Bjorn Wesen (bjornw@axis.com)
  8.  *
  9.  *  $Log: entry.S,v $
  10.  *  Revision 1.39  2002/04/24 00:46:45  bjornw
  11.  *  Added sys_tkill
  12.  *
  13.  *  Revision 1.38  2002/01/16 15:15:30  bjornw
  14.  *  Use a C-code compatible watchdog reset when NICE_DOGGY is enabled
  15.  *
  16.  *  Revision 1.37  2001/12/07 17:03:55  bjornw
  17.  *  Call a c-hook called watchdog_bite_hook instead of show_registers directly
  18.  *
  19.  *  Revision 1.36  2001/11/22 13:36:36  bjornw
  20.  *  * In ret_from_intr, check regs->dccr for usermode reentrance instead of
  21.  *    DCCR explicitely (because the latter might not reflect current reality)
  22.  *  * In mmu_bus_fault, set $r9 _after_ calling the C-code instead of before
  23.  *    since $r9 is call-clobbered and is potentially needed afterwards
  24.  *
  25.  *  Revision 1.35  2001/10/30 17:10:15  bjornw
  26.  *  Add some syscalls
  27.  *
  28.  *  Revision 1.34  2001/10/01 14:45:03  bjornw
  29.  *  Removed underscores and added register prefixes
  30.  *
  31.  *  Revision 1.33  2001/08/21 13:48:01  jonashg
  32.  *  Added fix by HP to avoid oops when doing a hard_reset_now.
  33.  *
  34.  *  Revision 1.32  2001/08/14 04:32:02  hp
  35.  *  In _resume, add comment why R9 is saved; don't sound like it's call-saved.
  36.  *
  37.  *  Revision 1.31  2001/07/25 16:07:42  bjornw
  38.  *  softirq_active/mask -> softirq_pending only
  39.  *
  40.  *  Revision 1.30  2001/07/05 01:03:32  hp
  41.  *  - include asm/errno.h to get ENOSYS.
  42.  *  - Use ENOSYS, not local constant LENOSYS; tweak comments.
  43.  *  - Explain why .include, not #include is used.
  44.  *  - Make oops-register-dump if watchdog bits and it's not expected.
  45.  *  - Don't jsr, use jump _hard_reset_now, and skip spurious nop.
  46.  *  - Use correct section attribute for section .rodata.
  47.  *  - Adjust sys_ni_syscall fill number.
  48.  *
  49.  *  Revision 1.29  2001/06/25 14:07:00  hp
  50.  *   Fix review comment.
  51.  *   * head.S: Use IO_STATE, IO_FIELD and IO_MASK constructs instead of
  52.  *   magic numbers.  Add comment that -traditional must not be used.
  53.  *   * entry.S (SYMBOL_NAME): Change redefinition to use ## concatenation.
  54.  *   Correct and update comment.
  55.  *   * Makefile (.S.o): Don't use -traditional.  Add comment why the
  56.  *   toplevel rule can't be used (now that there's a reason).
  57.  *
  58.  *  Revision 1.28  2001/06/21 02:00:40  hp
  59.  *   * entry.S: Include asm/unistd.h.
  60.  *   (_sys_call_table): Use section .rodata, not .data.
  61.  *   (_kernel_thread): Move from...
  62.  *   * process.c: ... here.
  63.  *   * entryoffsets.c (VAL): Break out from...
  64.  *   (OF): Use VAL.
  65.  *   (LCLONE_VM): New asmified value from CLONE_VM.
  66.  *
  67.  *  Revision 1.27  2001/05/29 11:25:27  markusl
  68.  *  In case of "spurious_interrupt", do hard_reset instead of hanging system in a loop...
  69.  *
  70.  *  Revision 1.26  2001/05/15 15:46:03  bjornw
  71.  *  Include config.h now that we use some CONFIG_ options
  72.  *
  73.  *  Revision 1.25  2001/05/15 05:38:47  hp
  74.  *  Tweaked code in _ret_from_sys_call
  75.  *
  76.  *  Revision 1.24  2001/05/15 05:27:49  hp
  77.  *  Save r9 in r1 over function call rather than on stack.
  78.  *
  79.  *  Revision 1.23  2001/05/15 05:10:00  hp
  80.  *  Generate entry.S structure offsets from C
  81.  *
  82.  *  Revision 1.22  2001/04/17 13:58:39  orjanf
  83.  *  * Renamed CONFIG_KGDB to CONFIG_ETRAX_KGDB.
  84.  *
  85.  *  Revision 1.21  2001/04/17 11:33:29  orjanf
  86.  *  Updated according to review:
  87.  *  * Included asm/sv_addr_ag.h to get macro for internal register.
  88.  *  * Corrected comment regarding system call argument passing.
  89.  *  * Removed comment about instruction being in a delay slot.
  90.  *  * Added comment about SYMBOL_NAME macro.
  91.  *
  92.  *  Revision 1.20  2001/04/12 08:51:07  hp
  93.  *  - Add entry for sys_fcntl64.  In fact copy last piece from i386 including ...
  94.  *  - .rept to fill table to safe state with sys_ni_syscall.
  95.  *
  96.  *  Revision 1.19  2001/04/04 09:43:32  orjanf
  97.  *  * Moved do_sigtrap from traps.c to entry.S.
  98.  *  * LTASK_PID need not be global anymore.
  99.  *
  100.  *  Revision 1.18  2001/03/26 09:25:02  markusl
  101.  *  Updated after review, should now handle USB interrupts correctly.
  102.  *
  103.  *  Revision 1.17  2001/03/21 16:12:55  bjornw
  104.  *  * Always make room for the cpu status record in the frame, in order to
  105.  *    use the same framelength and layout for both mmu busfaults and normal
  106.  *    irqs. No need to check for the explicit CRIS_FRAME_FIXUP type anymore.
  107.  *  * Fixed bug with using addq for popping the stack in the epilogue - it
  108.  *    destroyed the flag register. Use instructions that don't affect the
  109.  *    flag register instead.
  110.  *  * Removed write to R_PORT_PA_DATA during spurious_interrupt
  111.  *
  112.  *  Revision 1.16  2001/03/20 19:43:02  bjornw
  113.  *  * Get rid of esp0 setting
  114.  *  * Give a 7th argument to a systemcall - the stackframe
  115.  *
  116.  *  Revision 1.15  2001/03/05 13:14:30  bjornw
  117.  *  Spelling fix
  118.  *
  119.  *  Revision 1.14  2001/02/23 08:36:36  perf
  120.  *  New ABI; syscallnr=r9, arg5=mof, arg6=srp.
  121.  *  Corrected tracesys call check.
  122.  *
  123.  *  Revision 1.13  2001/02/15 08:40:55  perf
  124.  *  H-P by way of perf;
  125.  *  - (_system_call): Don't read system call function address into r1.
  126.  *  - (RBFExit): There is no such thing as a null pop.  Adjust sp by addq.
  127.  *  - (_system_call): Don't use r10 and don't save and restore it.
  128.  *  - (THREAD_ESP0): New constant.
  129.  *  - (_system_call): Inline set_esp0.
  130.  *
  131.  *  Revision 1.12  2001/01/31 17:56:25  orjanf
  132.  *  Added definition of LTASK_PID and made it global.
  133.  *
  134.  *  Revision 1.11  2001/01/10 21:13:29  bjornw
  135.  *  SYMBOL_NAME is defined incorrectly for the compiler options we currently use
  136.  *
  137.  *  Revision 1.10  2000/12/18 23:47:56  bjornw
  138.  *  * Added syscall trace support (ptrace), completely untested of course
  139.  *  * Removed redundant check for NULL entries in syscall_table
  140.  *
  141.  *  Revision 1.9  2000/11/21 16:40:51  bjornw
  142.  *  * New frame type used when an SBFS frame needs to be popped without
  143.  *    actually restarting the instruction
  144.  *  * Enable interrupts in signal_return (they did so in x86, I hope it's a good
  145.  *    idea)
  146.  *
  147.  *  Revision 1.8  2000/11/17 16:53:35  bjornw
  148.  *  Added detection of frame-type in Rexit, so that mmu_bus_fault can
  149.  *  use ret_from_intr in the return-path to check for signals (like SEGV)
  150.  *  and other foul things that might have occurred during the fault.
  151.  *
  152.  *  Revision 1.7  2000/10/06 15:04:28  bjornw
  153.  *  Include mof in register savings
  154.  *
  155.  *  Revision 1.6  2000/09/12 16:02:44  bjornw
  156.  *  Linux-2.4.0-test7 derived updates
  157.  *
  158.  *  Revision 1.5  2000/08/17 15:35:15  bjornw
  159.  *  2.4.0-test6 changed local_irq_count and friends API
  160.  *
  161.  *  Revision 1.4  2000/08/02 13:59:30  bjornw
  162.  *  Removed olduname and uname from the syscall list
  163.  *
  164.  *  Revision 1.3  2000/07/31 13:32:58  bjornw
  165.  *  * Export ret_from_intr
  166.  *  * _resume updated (prev/last tjohejsan)
  167.  *  * timer_interrupt obsolete
  168.  *  * SIGSEGV detection in mmu_bus_fault temporarily disabled
  169.  *
  170.  *
  171.  */
  173. /*
  174.  * entry.S contains the system-call and fault low-level handling routines.
  175.  *
  176.  * NOTE: This code handles signal-recognition, which happens every time
  177.  * after a timer-interrupt and after each system call.
  178.  *
  179.  * Stack layout in 'ret_from_system_call':
  180.  *  ptrace needs to have all regs on the stack.
  181.  * if the order here is changed, it needs to be 
  182.  * updated in fork.c:copy_process, signal.c:do_signal,
  183.  * ptrace.c and ptrace.h
  184.  *
  185.  */
  187. #include <linux/config.h>
  188. #include <linux/linkage.h>
  189. #include <linux/sys.h>
  190. #include <asm/unistd.h>
  191. #include <asm/sv_addr_ag.h>
  192. #include <asm/errno.h>
  194. ;; functions exported from this file
  196. .globl system_call
  197. .globl ret_from_intr
  198. .globl ret_from_sys_call
  199. .globl resume
  200. .globl multiple_interrupt
  201. .globl hwbreakpoint
  202. .globl IRQ1_interrupt
  203. .globl timer_interrupt
  204. .globl timer_shortcut
  205. .globl spurious_interrupt
  206. .globl hw_bp_trigs
  207. .globl mmu_bus_fault
  208. .globl do_sigtrap
  209. .globl gdb_handle_breakpoint
  211. .globl sys_call_table
  213. ;; Get values and offsets into various structs.  The file isn't
  214. ;; suitable for consumption by the preprocessor, so don't use
  215. ;; #include.
  216. .include "entryoffsets.s"
  218. ;; process bits for ptrace.  FIXME: Should be in a header file.
  220. PT_TRACESYS_BIT   = 1
  222. ;; below are various parts of system_call which are not in the fast-path
  224. ;; handle software irqs
  226. _handle_softirq:
  227. move.d $r9, $r1
  228. jsr do_softirq ; call the C routine for softirq handling
  229. move.d $r1, $r9
  231. ;; fall-through
  233. ret_from_intr:
  234. ;; check for resched only if we're going back to user-mode
  235. ;; this test matches the user_regs(regs) macro
  236. ;; we cannot simply test $dccr, because that does not necessarily
  237. ;; reflect what mode we'll return into.
  239. move.d [$sp + LDCCR], $r0; regs->dccr
  240. btstq 8, $r0 ; U-flag
  241. bpl _Rexit ; go back directly
  242. nop
  243. ba _ret_with_reschedule  ; go back but check schedule and signals first 
  244. nop
  246. _reschedule:
  247. ;; keep r9 intact
  248. move.d $r9, $r1
  249. jsr schedule
  250. ba ret_from_sys_call
  251. move.d $r1, $r9
  253. ;; return but call do_signal first
  254. _signal_return:
  255. ei ; we can get here from an interrupt
  256. move.d $r9, $r10 ; do_signals syscall/irq param
  257. moveq 0, $r11 ; oldset param - 0 in this case
  258. move.d $sp, $r12 ; another argument to do_signal (the regs param)
  259. jsr do_signal ; arch/cris/kernel/signal.c
  260. ba _Rexit
  261. nop
  263. ;; The system_call is called by a BREAK instruction, which works like
  264. ;; an interrupt call but it stores the return PC in BRP instead of IRP.
  265. ;; Since we dont really want to have two epilogues (one for system calls
  266. ;; and one for interrupts) we push the contents of BRP instead of IRP in the
  267. ;; system call prologue, to make it look like an ordinary interrupt on the
  268. ;; stackframe.
  269. ;;
  270. ;; Since we can't have system calls inside interrupts, it should not matter
  271. ;; that we don't stack IRP.
  272. ;; 
  273. ;; In r9 we have the wanted syscall number. Arguments come in r10,r11,r12,r13,mof,srp
  274. ;;
  275. ;; This function looks on the _surface_ like spaghetti programming, but it's
  276. ;; really designed so that the fast-path does not force cache-loading of non-used
  277. ;; instructions. Only the non-common cases cause the outlined code to run..
  279. system_call:
  280. ;; stack-frame similar to the irq heads, which is reversed in ret_from_sys_call
  281. move $brp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
  282. push $srp
  283. push $dccr
  284. push $mof
  285. subq 14*4, $sp ; make room for r0-r13
  286. movem $r13, [$sp] ; push r0-r13
  287. push $r10 ; push orig_r10
  288. clear.d [$sp=$sp-4] ; frametype == 0, normal stackframe
  290. movs.w -ENOSYS, $r0
  291. move.d $r0, [$sp+LR10] ; put the default return value in r10 in the frame
  293. ;; check if this process is syscall-traced
  295. movs.w -8192, $r0 ; THREAD_SIZE == 8192
  296. and.d $sp, $r0
  298. move.d [$r0+LTASK_PTRACE], $r0
  299. btstq PT_TRACESYS_BIT, $r0
  300. bmi _tracesys
  301. nop
  303. ;; check for sanity in the requested syscall number
  305. cmpu.w NR_syscalls, $r9
  306. bcc ret_from_sys_call
  307. lslq 2, $r9 ;  multiply by 4, in the delay slot
  309. ;; as a bonus 7th parameter, we give the location on the stack
  310. ;; of the register structure itself. some syscalls need this.
  312. push $sp
  314. ;; the parameter carrying registers r10, r11, r12 and 13 are intact.
  315. ;; the fifth and sixth parameters (if any) was in mof and srp 
  316. ;; respectively, and we need to put them on the stack.
  318. push $srp
  319. push $mof
  321. jsr [$r9+sys_call_table] ; actually do the system call
  322. addq 3*4, $sp ; pop the mof, srp and regs parameters
  323. move.d $r10, [$sp+LR10] ; save the return value
  325. moveq 1, $r9 ; "parameter" to ret_from_sys_call to show it was a sys call
  327. ;; fall through into ret_from_sys_call to return
  329. ret_from_sys_call:
  330. ;; r9 is a parameter - if 1, we came from a syscall, if 0, from an irq
  332. ;; check if any bottom halves need service
  334. test.d [irq_stat]        ; softirq_pending
  335. bne _handle_softirq
  336. nop
  338. _ret_with_reschedule:
  339. ;; first get the current task-struct pointer (see top for defs)
  341. move.d $sp, $r0
  342. and.d -8192, $r0 ; THREAD_SIZE == 8192
  344. ;; see if we want to reschedule into another process
  346. test.d [$r0+LTASK_NEEDRESCHED]
  347. bne _reschedule
  348. nop
  350. ;; see if we need to run signal checks (important that r9 is intact here)
  352. test.d [$r0+LTASK_SIGPENDING]
  353. bne _signal_return
  354. nop
  356. _Rexit:
  357. ;; this epilogue MUST match the prologues in multiple_interrupt, irq.h and ptregs.h
  358. pop $r10 ; frametype
  359. bne _RBFexit ; was not CRIS_FRAME_NORMAL, handle otherwise
  360. addq 4, $sp ; skip orig_r10, in delayslot
  361. movem [$sp+], $r13 ; registers r0-r13
  362. pop $mof ; multiply overflow register 
  363. pop $dccr ; condition codes
  364. pop $srp ; subroutine return pointer
  365. ;; now we have a 4-word SBFS frame which we do not want to restore
  366. ;; using RBF since it was not stacked with SBFS. instead we would like to
  367. ;; just get the PC value to restart it with, and skip the rest of
  368. ;; the frame.
  369. ;; Also notice that it's important to use instructions here that
  370. ;; keep the interrupts disabled (since we've already popped DCCR)
  371. move [$sp=$sp+16], $p8; pop the SBFS frame from the sp
  372. jmpu [$sp-16] ; return through the irp field in the sbfs frame
  374. _RBFexit:
  375. movem [$sp+], $r13 ; registers r0-r13, in delay slot
  376. pop $mof ; multiply overflow register 
  377. pop $dccr ; condition codes
  378. pop $srp ; subroutine return pointer
  379. rbf [$sp+] ; return by popping the CPU status
  381. _tracesys:
  382. ;; this first invocation of syscall_trace _requires_ that
  383. ;; LR10 in the frame contains -ENOSYS (as is set in the beginning
  384. ;; of system_call).
  386. jsr syscall_trace
  388. ;; now we should more or less do the same things as in the system_call
  389. ;; but since our argument regs got clobbered during syscall_trace and
  390. ;; because syscall_trace might want to alter them, we need to reload them
  391. ;; from the stack-frame as we use them.
  393. ;; check for sanity in the requested syscall number
  395. move.d [$sp+LR9], $r9
  396. movs.w -ENOSYS, $r10
  397. cmpu.w NR_syscalls, $r9
  398. bcc 1f
  399. lslq 2, $r9 ;  multiply by 4, in the delay slot
  401. ;; read the system call vector entry into r9
  403. move.d [$r9+sys_call_table], $r9
  405. ;; restore r10, r11, r12, r13, mof and srp into the needed registers
  407. move.d [$sp+LORIG_R10], $r10  ; LR10 is already filled with -ENOSYS.
  408. move.d [$sp+LR11],      $r11
  409. move.d [$sp+LR12],      $r12
  410. move.d [$sp+LR13],      $r13
  411. move [$sp+LMOF],      $mof
  412. move [$sp+LSRP],      $srp
  414. ;; as a bonus 7th parameter, we give the location on the stack
  415. ;; of the register structure itself. some syscalls need this.
  417. push $sp
  419. ;; the fifth and sixth parameters needs to be put on the stack for
  420. ;; the system call to find them
  422. push $srp
  423. push $mof
  425. jsr $r9 ; actually call the system-call
  426. addq 3*4, $sp ; pop the srp, mof and regs parameters
  428. 1: move.d $r10, [$sp+LR10]; save the return value
  430. ;; second call of syscall_trace, to let it grab the results
  432. jsr syscall_trace
  434. moveq 1, $r9 ; "parameter" to ret_from_sys_call to show it was a sys call
  435. ba ret_from_sys_call
  436. nop
  438. ;; resume performs the actual task-switching, by switching stack pointers
  439. ;; input arguments: r10 = prev, r11 = next, r12 = thread offset in task struct
  440. ;; returns old current in r10
  441. ;;
  442. ;; TODO:  see the i386 version. The switch_to which calls resume in our version
  443. ;;        could really be an inline asm of this.
  445. resume:
  446. push $srp          ; we keep the old/new PC on the stack 
  447. add.d $r12, $r10  ; r10 = current tasks tss
  448. move $dccr, [$r10+LTHREAD_DCCR] ; save irq enable state
  449. di
  451. move $usp, [$r10+LTHREAD_USP] ; save user-mode stackpointer
  453. ;; See copy_thread for the reason why register R9 is saved.
  454. subq 10*4, $sp
  455. movem $r9, [$sp]  ; save non-scratch registers and R9.
  457. move.d $sp, [$r10+LTHREAD_KSP]  ; save the kernel stack pointer for the old task
  458. move.d $sp, $r10  ; return last running task in r10
  459. and.d   -8192, $r10          ; get task ptr from stackpointer
  460. add.d $r12, $r11  ; find the new tasks tss
  461. move.d [$r11+LTHREAD_KSP], $sp  ; switch into the new stackframe by restoring kernel sp
  463. movem [$sp+], $r9  ; restore non-scratch registers and R9.
  465. move [$r11+LTHREAD_USP], $usp ; restore user-mode stackpointer
  467. move [$r11+LTHREAD_DCCR], $dccr ; restore irq enable status
  468. jump [$sp+]          ; restore PC
  470. ;; This is the MMU bus fault handler.
  471. ;; It needs to stack the CPU status and overall is different
  472. ;; from the other interrupt handlers.
  474. mmu_bus_fault:
  475. sbfs [$sp=$sp-16] ; push the internal CPU status
  476. ;; the first longword in the sbfs frame was the interrupted PC
  477. ;; which fits nicely with the "IRP" slot in pt_regs normally used to
  478. ;; contain the return address. used by Oops to print kernel errors..
  479. push $srp ; make a stackframe similar to pt_regs
  480. push $dccr
  481. push $mof
  482. di
  483. subq 14*4, $sp
  484. movem $r13, [$sp]
  485. push $r10 ; dummy orig_r10
  486. moveq 1, $r10
  487. push $r10 ; frametype == 1, BUSFAULT frame type
  489. move.d $sp, $r10 ; pt_regs argument to handle_mmu_bus_fault
  491. jsr handle_mmu_bus_fault  ; in arch/cris/mm/fault.c
  493. ;; now we need to return through the normal path, we cannot just
  494. ;; do the RBFexit since we might have killed off the running
  495. ;; process due to a SEGV, scheduled due to a page blocking or
  496. ;; whatever.
  498. moveq 0, $r9 ; busfault is equivalent to an irq
  500. ba ret_from_intr
  501. nop
  503. ;; special handlers for breakpoint and NMI
  504. #if 0
  505. hwbreakpoint:
  506. push $dccr
  507. di
  508. push $r10
  509. push $r11
  510. push $r12
  511. push $r13
  512. clearf b
  513. move $brp,$r11
  514. move.d [hw_bp_msg],$r10
  515. jsr printk
  516. setf b
  517. pop $r13
  518. pop $r12
  519. pop $r11
  520. pop $r10
  521. pop $dccr
  522. retb
  523. nop
  524. #else
  525. hwbreakpoint:
  526. push $dccr
  527. di
  528. #if 1
  529. push $r10
  530. push $r11
  531. move.d [hw_bp_trig_ptr],$r10
  532. move.d [$r10],$r11
  533. cmp.d 42,$r11
  534. beq 1f
  535. nop
  536. move $brp,$r11
  537. move.d $r11,[$r10+]
  538. move.d $r10,[hw_bp_trig_ptr]
  539. 1: pop $r11
  540. pop $r10
  541. #endif
  542. pop $dccr
  543. retb
  544. nop
  545. #endif
  547. IRQ1_interrupt:
  549. #if defined(CONFIG_ETRAX_WATCHDOG) && !defined(CONFIG_SVINTO_SIM)
  550. ;; If we receive a watchdog interrupt while it is not expected, then set
  551. ;; up a canonical frame and dump register contents before dying.
  553. ;; this prologue MUST match the one in irq.h and the struct in ptregs.h!!!
  554. move $brp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
  555. push $srp
  556. push $dccr
  557. push $mof
  558. di
  559. subq 14*4, $sp
  560. movem $r13, [$sp]
  561. push $r10 ; push orig_r10
  562. clear.d [$sp=$sp-4] ; frametype == 0, normal frame
  564. ;; We don't check that we actually were bit by the watchdog as opposed to
  565. ;; an external NMI, since there is currently no handler for external NMI.
  567. ;; Check if we're waiting for reset to happen, as signalled by
  568. ;; hard_reset_now setting cause_of_death to a magic value.  If so, just
  569. ;; get stuck until reset happens.
  570. .comm cause_of_death, 4 ;; Don't declare this anywhere.
  571. move.d [cause_of_death], $r10
  572. cmp.d 0xbedead, $r10
  573. _killed_by_death:
  574. beq _killed_by_death
  575. nop
  577. ;; We'll see this in ksymoops dumps.
  578. Watchdog_bite:
  580. #ifdef CONFIG_ETRAX_WATCHDOG_NICE_DOGGY
  581. ;; We just restart the watchdog here to be sure we dont get
  582. ;; hit while printing the watchdogmsg below
  583. ;; This restart is compatible with the rest of the C-code, so
  584. ;; the C-code can keep restarting the watchdog after this point.
  585. ;; The non-NICE_DOGGY code below though, disables the possibility
  586. ;; to restart since it changes the watchdog key, to avoid any
  587. ;; buggy loops etc. keeping the watchdog alive after this.
  588. jsr reset_watchdog
  589. #else
  590. ;; We need to extend the 3.3ms after the NMI at watchdog bite, so we have
  591. ;; time for an oops-dump over a 115k2 serial wire.  Another 100ms should do.
  593. ;; Change the watchdog key to an arbitrary 3-bit value and restart the
  594. ;; watchdog.
  595. #define WD_INIT 2
  596. moveq   IO_FIELD (R_WATCHDOG, key, WD_INIT), $r10
  597. move.d R_WATCHDOG, $r11
  599. move.d $r10, [$r11]
  600. moveq   IO_FIELD (R_WATCHDOG, key,
  601.     IO_EXTRACT (R_WATCHDOG, key,
  602. IO_MASK (R_WATCHDOG, key))
  603.     ^ WD_INIT)
  604. | IO_STATE (R_WATCHDOG, enable, start), $r10
  605. move.d $r10, [$r11]
  606. #endif
  608. ;; Note that we don't do "setf m" here (or after two necessary NOPs),
  609. ;; since *not* doing that saves us from re-entrancy checks.  We don't want
  610. ;; to get here again due to possible subsequent NMIs; we want the watchdog
  611. ;; to reset us.
  613. move.d _watchdogmsg,$r10
  614. jsr printk
  616. move.d $sp, $r10
  617. jsr watchdog_bite_hook
  619. ;; This nop is here so we see the "Watchdog_bite" label in ksymoops dumps
  620. ;; rather than "spurious_interrupt".
  621. nop
  622. ;; At this point we drop down into spurious_interrupt, which will do a
  623. ;; hard reset.
  625. .section .rodata,"a"
  626. _watchdogmsg:
  627. .ascii "Oops: bitten by watchdogn"
  628. .previous
  630. #endif /* CONFIG_ETRAX_WATCHDOG and not CONFIG_SVINTO_SIM */
  632. spurious_interrupt:
  633. di
  634. jump hard_reset_now
  636. ;; this handles the case when multiple interrupts arrive at the same time
  637. ;; we jump to the first set interrupt bit in a priority fashion
  638. ;; the hardware will call the unserved interrupts after the handler finishes
  640. multiple_interrupt:
  641. ;; this prologue MUST match the one in irq.h and the struct in ptregs.h!!!
  642. move $irp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
  643. push $srp
  644. push $dccr
  645. push $mof
  646. di
  647. subq 14*4, $sp
  648. movem $r13, [$sp]
  649. push $r10 ; push orig_r10
  650. clear.d [$sp=$sp-4] ; frametype == 0, normal frame
  652. move.d irq_shortcuts + 8, $r1
  653. moveq 2, $r2 ; first bit we care about is the timer0 irq
  654. move.d [R_VECT_MASK_RD], $r0; read the irq bits that triggered the multiple irq
  655. 1:
  656. btst $r2, $r0 ; check for the irq given by bit r2
  657. bmi _do_shortcut ; actually do the shortcut
  658. nop
  659. addq 1, $r2 ; next vector bit
  660. addq 4, $r1 ; next vector
  661. cmp.b 32, $r2
  662. bne 1b ; process all irq's up to and including number 31
  663. nop
  665. ;; strange, we didn't get any set vector bits.. oh well, just return
  667. ba _Rexit
  668. nop
  670. _do_shortcut:
  671. test.d [$r1]
  672. beq _Rexit
  673. nop
  674. jump [$r1] ; jump to the irq handlers shortcut
  676. do_sigtrap:
  677. ;; 
  678. ;; SIGTRAP the process that executed the break instruction.
  679. ;; Make a frame that Rexit in entry.S expects.
  680. ;;
  681. move $brp, [$sp=$sp-16] ; Push BRP while faking a cpu status record.
  682. push $srp ; Push subroutine return pointer.
  683. push $dccr ; Push condition codes.
  684. push $mof ; Push multiply overflow reg.
  685. di ; Need to disable irq's at this point.
  686. subq 14*4, $sp ; Make room for r0-r13.
  687. movem $r13, [$sp] ; Push the r0-r13 registers.
  688. push $r10 ; Push orig_r10.
  689. clear.d [$sp=$sp-4] ; Frametype - this is a normal stackframe.
  691. movs.w -8192,$r9 ; THREAD_SIZE == 8192
  692. and.d $sp, $r9
  693. move.d [$r9+LTASK_PID], $r10 ; current->pid as arg1.
  694. moveq 5, $r11 ; SIGTRAP as arg2.
  695. jsr sys_kill       
  696. jump ret_from_intr ; Use the return routine for interrupts.
  698. gdb_handle_breakpoint:
  699. push $dccr
  700. push $r0
  701. #ifdef CONFIG_ETRAX_KGDB
  702. move $dccr, $r0 ; U-flag not affected by previous insns. 
  703. btstq 8, $r0 ; Test the U-flag.
  704. bmi _ugdb_handle_breakpoint ; Go to user mode debugging. 
  705. nop ; Empty delay slot (cannot pop r0 here). 
  706. pop $r0 ; Restore r0.
  707. ba kgdb_handle_breakpoint ; Go to kernel debugging. 
  708. pop $dccr ; Restore dccr in delay slot.
  709. #endif
  711. _ugdb_handle_breakpoint:
  712. move $brp, $r0 ; Use r0 temporarily for calculation.
  713. subq 2, $r0 ; Set to address of previous instruction.
  714. move $r0, $brp
  715. pop $r0 ; Restore r0. 
  716. ba do_sigtrap ; SIGTRAP the offending process. 
  717. pop $dccr ; Restore dccr in delay slot.
  719. .data
  721. hw_bp_trigs:
  722. .space 64*4
  723. hw_bp_trig_ptr:
  724. .dword hw_bp_trigs
  726. /*
  727.  * This is the mechanism for creating a new kernel thread.
  728.  *
  729.  * NOTE! Only a kernel-only process (i.e. the swapper or direct descendants
  730.  * who haven't done an "execve()") should use this: it will work within
  731.  * a system call from a "real" process, but the process memory space will
  732.  * not be free'd until both the parent and the child have exited.
  733.  *
  734.  * This *can* be done in C with an single-asm-wrapped-in-a-function, but you
  735.  * get more or less gross code.  The safer you make the asm-constraints,
  736.  * the grosser the code, at least with the gcc version in cris-dist-1.13.
  737.  */
  739. /* int kernel_thread(int (*fn)(void *), void * arg, unsigned long flags) */
  740. /*                   r10                r11         r12  */
  742. .text
  743. .global kernel_thread
  744. kernel_thread:
  746. /* Save ARG for later.  */
  747. move.d $r11, $r13
  749. /* r11 is argument 2 to clone, the flags */
  750. move.d  $r12, $r11
  751. or.w LCLONE_VM, $r11
  753. /* Save FN for later.  */
  754. move.d $r10, $r12
  756. /* r9 contains syscall number, to sys_clone */
  757. movu.w __NR_clone, $r9
  759. /* r10 is argument 1 to clone */
  760. clear.d $r10
  762. /* call sys_clone, this will fork */
  763. break 13
  765. /* parent or child? child returns 0 here. */
  766. test.d $r10
  768. /* jump if parent */
  769. bne 1f
  770. nop              /* delay slot */
  772. /* set argument to function to call */
  773. move.d $r13, $r10
  775. /* call specified function */
  776. jsr $r12
  777. /* If we ever return from the function, something bad has happened.  */
  779. /* r9 is sys_exit syscall number */
  780. movu.w __NR_exit, $r9
  782. /* Give a really bad exit-value */
  783. moveq -1, $r10
  785. /* call sys_exit, killing the child */
  786. break 13
  787. 1:
  788. ret
  789. nop              /* delay slot */
  791. .section .rodata,"a"
  792. sys_call_table:
  793. .long SYMBOL_NAME(sys_ni_syscall) /* 0  -  old "setup()" system call*/
  794. .long SYMBOL_NAME(sys_exit)
  795. .long SYMBOL_NAME(sys_fork)
  796. .long SYMBOL_NAME(sys_read)
  797. .long SYMBOL_NAME(sys_write)
  798. .long SYMBOL_NAME(sys_open) /* 5 */
  799. .long SYMBOL_NAME(sys_close)
  800. .long SYMBOL_NAME(sys_waitpid)
  801. .long SYMBOL_NAME(sys_creat)
  802. .long SYMBOL_NAME(sys_link)
  803. .long SYMBOL_NAME(sys_unlink) /* 10 */
  804. .long SYMBOL_NAME(sys_execve)
  805. .long SYMBOL_NAME(sys_chdir)
  806. .long SYMBOL_NAME(sys_time)
  807. .long SYMBOL_NAME(sys_mknod)
  808. .long SYMBOL_NAME(sys_chmod) /* 15 */
  809. .long SYMBOL_NAME(sys_lchown16)
  810. .long SYMBOL_NAME(sys_ni_syscall) /* old break syscall holder */
  811. .long SYMBOL_NAME(sys_stat)
  812. .long SYMBOL_NAME(sys_lseek)
  813. .long SYMBOL_NAME(sys_getpid) /* 20 */
  814. .long SYMBOL_NAME(sys_mount)
  815. .long SYMBOL_NAME(sys_oldumount)
  816. .long SYMBOL_NAME(sys_setuid16)
  817. .long SYMBOL_NAME(sys_getuid16)
  818. .long SYMBOL_NAME(sys_stime) /* 25 */
  819. .long SYMBOL_NAME(sys_ptrace)
  820. .long SYMBOL_NAME(sys_alarm)
  821. .long SYMBOL_NAME(sys_fstat)
  822. .long SYMBOL_NAME(sys_pause)
  823. .long SYMBOL_NAME(sys_utime) /* 30 */
  824. .long SYMBOL_NAME(sys_ni_syscall) /* old stty syscall holder */
  825. .long SYMBOL_NAME(sys_ni_syscall) /* old gtty syscall holder */
  826. .long SYMBOL_NAME(sys_access)
  827. .long SYMBOL_NAME(sys_nice)
  828. .long SYMBOL_NAME(sys_ni_syscall) /* 35  old ftime syscall holder */
  829. .long SYMBOL_NAME(sys_sync)
  830. .long SYMBOL_NAME(sys_kill)
  831. .long SYMBOL_NAME(sys_rename)
  832. .long SYMBOL_NAME(sys_mkdir)
  833. .long SYMBOL_NAME(sys_rmdir) /* 40 */
  834. .long SYMBOL_NAME(sys_dup)
  835. .long SYMBOL_NAME(sys_pipe)
  836. .long SYMBOL_NAME(sys_times)
  837. .long SYMBOL_NAME(sys_ni_syscall) /* old prof syscall holder */
  838. .long SYMBOL_NAME(sys_brk) /* 45 */
  839. .long SYMBOL_NAME(sys_setgid16)
  840. .long SYMBOL_NAME(sys_getgid16)
  841. .long SYMBOL_NAME(sys_signal)
  842. .long SYMBOL_NAME(sys_geteuid16)
  843. .long SYMBOL_NAME(sys_getegid16) /* 50 */
  844. .long SYMBOL_NAME(sys_acct)
  845. .long SYMBOL_NAME(sys_umount) /* recycled never used phys() */
  846. .long SYMBOL_NAME(sys_ni_syscall) /* old lock syscall holder */
  847. .long SYMBOL_NAME(sys_ioctl)
  848. .long SYMBOL_NAME(sys_fcntl) /* 55 */
  849. .long SYMBOL_NAME(sys_ni_syscall) /* old mpx syscall holder */
  850. .long SYMBOL_NAME(sys_setpgid)
  851. .long SYMBOL_NAME(sys_ni_syscall) /* old ulimit syscall holder */
  852. .long SYMBOL_NAME(sys_ni_syscall)       /* old sys_olduname holder */
  853. .long SYMBOL_NAME(sys_umask) /* 60 */
  854. .long SYMBOL_NAME(sys_chroot)
  855. .long SYMBOL_NAME(sys_ustat)
  856. .long SYMBOL_NAME(sys_dup2)
  857. .long SYMBOL_NAME(sys_getppid)
  858. .long SYMBOL_NAME(sys_getpgrp) /* 65 */
  859. .long SYMBOL_NAME(sys_setsid)
  860. .long SYMBOL_NAME(sys_sigaction)
  861. .long SYMBOL_NAME(sys_sgetmask)
  862. .long SYMBOL_NAME(sys_ssetmask)
  863. .long SYMBOL_NAME(sys_setreuid16) /* 70 */
  864. .long SYMBOL_NAME(sys_setregid16)
  865. .long SYMBOL_NAME(sys_sigsuspend)
  866. .long SYMBOL_NAME(sys_sigpending)
  867. .long SYMBOL_NAME(sys_sethostname)
  868. .long SYMBOL_NAME(sys_setrlimit) /* 75 */
  869. .long SYMBOL_NAME(sys_old_getrlimit)
  870. .long SYMBOL_NAME(sys_getrusage)
  871. .long SYMBOL_NAME(sys_gettimeofday)
  872. .long SYMBOL_NAME(sys_settimeofday)
  873. .long SYMBOL_NAME(sys_getgroups16) /* 80 */
  874. .long SYMBOL_NAME(sys_setgroups16)
  875. .long SYMBOL_NAME(sys_select)           /* was old_select in Linux/E100 */
  876. .long SYMBOL_NAME(sys_symlink)
  877. .long SYMBOL_NAME(sys_lstat)
  878. .long SYMBOL_NAME(sys_readlink) /* 85 */
  879. .long SYMBOL_NAME(sys_uselib)
  880. .long SYMBOL_NAME(sys_swapon)
  881. .long SYMBOL_NAME(sys_reboot)
  882. .long SYMBOL_NAME(old_readdir)
  883. .long SYMBOL_NAME(old_mmap) /* 90 */
  884. .long SYMBOL_NAME(sys_munmap)
  885. .long SYMBOL_NAME(sys_truncate)
  886. .long SYMBOL_NAME(sys_ftruncate)
  887. .long SYMBOL_NAME(sys_fchmod)
  888. .long SYMBOL_NAME(sys_fchown16) /* 95 */
  889. .long SYMBOL_NAME(sys_getpriority)
  890. .long SYMBOL_NAME(sys_setpriority)
  891. .long SYMBOL_NAME(sys_ni_syscall) /* old profil syscall holder */
  892. .long SYMBOL_NAME(sys_statfs)
  893. .long SYMBOL_NAME(sys_fstatfs) /* 100 */
  894. .long SYMBOL_NAME(sys_ni_syscall)       /* sys_ioperm in i386 */
  895. .long SYMBOL_NAME(sys_socketcall)
  896. .long SYMBOL_NAME(sys_syslog)
  897. .long SYMBOL_NAME(sys_setitimer)
  898. .long SYMBOL_NAME(sys_getitimer) /* 105 */
  899. .long SYMBOL_NAME(sys_newstat)
  900. .long SYMBOL_NAME(sys_newlstat)
  901. .long SYMBOL_NAME(sys_newfstat)
  902. .long SYMBOL_NAME(sys_ni_syscall) /* old sys_uname holder */
  903. .long SYMBOL_NAME(sys_ni_syscall) /* sys_iopl in i386 */
  904. .long SYMBOL_NAME(sys_vhangup)
  905. .long SYMBOL_NAME(sys_ni_syscall) /* old "idle" system call */
  906. .long SYMBOL_NAME(sys_ni_syscall) /* vm86old in i386 */
  907. .long SYMBOL_NAME(sys_wait4)
  908. .long SYMBOL_NAME(sys_swapoff) /* 115 */
  909. .long SYMBOL_NAME(sys_sysinfo)
  910. .long SYMBOL_NAME(sys_ipc)
  911. .long SYMBOL_NAME(sys_fsync)
  912. .long SYMBOL_NAME(sys_sigreturn)
  913. .long SYMBOL_NAME(sys_clone) /* 120 */
  914. .long SYMBOL_NAME(sys_setdomainname)
  915. .long SYMBOL_NAME(sys_newuname)
  916. .long SYMBOL_NAME(sys_ni_syscall) /* TODO sys_modify_ldt - do something ?*/
  917. .long SYMBOL_NAME(sys_adjtimex)
  918. .long SYMBOL_NAME(sys_mprotect) /* 125 */
  919. .long SYMBOL_NAME(sys_sigprocmask)
  920. .long SYMBOL_NAME(sys_create_module)
  921. .long SYMBOL_NAME(sys_init_module)
  922. .long SYMBOL_NAME(sys_delete_module)
  923. .long SYMBOL_NAME(sys_get_kernel_syms) /* 130 */
  924. .long SYMBOL_NAME(sys_quotactl)
  925. .long SYMBOL_NAME(sys_getpgid)
  926. .long SYMBOL_NAME(sys_fchdir)
  927. .long SYMBOL_NAME(sys_bdflush)
  928. .long SYMBOL_NAME(sys_sysfs) /* 135 */
  929. .long SYMBOL_NAME(sys_personality)
  930. .long SYMBOL_NAME(sys_ni_syscall) /* for afs_syscall */
  931. .long SYMBOL_NAME(sys_setfsuid16)
  932. .long SYMBOL_NAME(sys_setfsgid16)
  933. .long SYMBOL_NAME(sys_llseek) /* 140 */
  934. .long SYMBOL_NAME(sys_getdents)
  935. .long SYMBOL_NAME(sys_select)
  936. .long SYMBOL_NAME(sys_flock)
  937. .long SYMBOL_NAME(sys_msync)
  938. .long SYMBOL_NAME(sys_readv) /* 145 */
  939. .long SYMBOL_NAME(sys_writev)
  940. .long SYMBOL_NAME(sys_getsid)
  941. .long SYMBOL_NAME(sys_fdatasync)
  942. .long SYMBOL_NAME(sys_sysctl)
  943. .long SYMBOL_NAME(sys_mlock) /* 150 */
  944. .long SYMBOL_NAME(sys_munlock)
  945. .long SYMBOL_NAME(sys_mlockall)
  946. .long SYMBOL_NAME(sys_munlockall)
  947. .long SYMBOL_NAME(sys_sched_setparam)
  948. .long SYMBOL_NAME(sys_sched_getparam)   /* 155 */
  949. .long SYMBOL_NAME(sys_sched_setscheduler)
  950. .long SYMBOL_NAME(sys_sched_getscheduler)
  951. .long SYMBOL_NAME(sys_sched_yield)
  952. .long SYMBOL_NAME(sys_sched_get_priority_max)
  953. .long SYMBOL_NAME(sys_sched_get_priority_min)  /* 160 */
  954. .long SYMBOL_NAME(sys_sched_rr_get_interval)
  955. .long SYMBOL_NAME(sys_nanosleep)
  956. .long SYMBOL_NAME(sys_mremap)
  957. .long SYMBOL_NAME(sys_setresuid16)
  958. .long SYMBOL_NAME(sys_getresuid16) /* 165 */
  959. .long SYMBOL_NAME(sys_ni_syscall) /* sys_vm86 */
  960. .long SYMBOL_NAME(sys_query_module)
  961. .long SYMBOL_NAME(sys_poll)
  962. .long SYMBOL_NAME(sys_nfsservctl)
  963. .long SYMBOL_NAME(sys_setresgid16) /* 170 */
  964. .long SYMBOL_NAME(sys_getresgid16)
  965. .long SYMBOL_NAME(sys_prctl)
  966. .long SYMBOL_NAME(sys_rt_sigreturn)
  967. .long SYMBOL_NAME(sys_rt_sigaction)
  968. .long SYMBOL_NAME(sys_rt_sigprocmask) /* 175 */
  969. .long SYMBOL_NAME(sys_rt_sigpending)
  970. .long SYMBOL_NAME(sys_rt_sigtimedwait)
  971. .long SYMBOL_NAME(sys_rt_sigqueueinfo)
  972. .long SYMBOL_NAME(sys_rt_sigsuspend)
  973. .long SYMBOL_NAME(sys_pread) /* 180 */
  974. .long SYMBOL_NAME(sys_pwrite)
  975. .long SYMBOL_NAME(sys_chown16)
  976. .long SYMBOL_NAME(sys_getcwd)
  977. .long SYMBOL_NAME(sys_capget)
  978. .long SYMBOL_NAME(sys_capset)           /* 185 */
  979. .long SYMBOL_NAME(sys_sigaltstack)
  980. .long SYMBOL_NAME(sys_sendfile)
  981. .long SYMBOL_NAME(sys_ni_syscall) /* streams1 */
  982. .long SYMBOL_NAME(sys_ni_syscall) /* streams2 */
  983. .long SYMBOL_NAME(sys_vfork)            /* 190 */
  984. .long SYMBOL_NAME(sys_getrlimit)
  985. .long SYMBOL_NAME(sys_mmap2)
  986. .long SYMBOL_NAME(sys_truncate64)
  987. .long SYMBOL_NAME(sys_ftruncate64)
  988. .long SYMBOL_NAME(sys_stat64) /* 195 */
  989. .long SYMBOL_NAME(sys_lstat64)
  990. .long SYMBOL_NAME(sys_fstat64)
  991. .long SYMBOL_NAME(sys_lchown)
  992. .long SYMBOL_NAME(sys_getuid)
  993. .long SYMBOL_NAME(sys_getgid) /* 200 */
  994. .long SYMBOL_NAME(sys_geteuid)
  995. .long SYMBOL_NAME(sys_getegid)
  996. .long SYMBOL_NAME(sys_setreuid)
  997. .long SYMBOL_NAME(sys_setregid)
  998. .long SYMBOL_NAME(sys_getgroups) /* 205 */
  999. .long SYMBOL_NAME(sys_setgroups)
  1000. .long SYMBOL_NAME(sys_fchown)
  1001. .long SYMBOL_NAME(sys_setresuid)
  1002. .long SYMBOL_NAME(sys_getresuid)
  1003. .long SYMBOL_NAME(sys_setresgid) /* 210 */
  1004. .long SYMBOL_NAME(sys_getresgid)
  1005. .long SYMBOL_NAME(sys_chown)
  1006. .long SYMBOL_NAME(sys_setuid)
  1007. .long SYMBOL_NAME(sys_setgid)
  1008. .long SYMBOL_NAME(sys_setfsuid) /* 215 */
  1009. .long SYMBOL_NAME(sys_setfsgid)
  1010. .long SYMBOL_NAME(sys_pivot_root)
  1011. .long SYMBOL_NAME(sys_mincore)
  1012. .long SYMBOL_NAME(sys_madvise)
  1013. .long SYMBOL_NAME(sys_getdents64)       /* 220 */
  1014. .long SYMBOL_NAME(sys_fcntl64)
  1015. .long SYMBOL_NAME(sys_ni_syscall) /* reserved for TUX */
  1016.         .long SYMBOL_NAME(sys_ni_syscall)       /* Reserved for Security */
  1017.         .long SYMBOL_NAME(sys_gettid)
  1018.         .long SYMBOL_NAME(sys_readahead)        /* 225 */
  1019. .long SYMBOL_NAME(sys_tkill)
  1021.         /*
  1022.          * NOTE!! This doesn't have to be exact - we just have
  1023.          * to make sure we have _enough_ of the "sys_ni_syscall"
  1024.          * entries. Don't panic if you notice that this hasn't
  1025.          * been shrunk every time we add a new system call.
  1026.          */
  1028. .rept NR_syscalls-(.-sys_call_table)/4
  1029. .long SYMBOL_NAME(sys_ni_syscall)
  1030. .endr