开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
head.S
资源名称：linux-2.4.20.tar.gz　[点击查看]
上传用户：jlfgdled
上传日期：2013-04-10
资源大小：33168k
文件大小：28k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

head.S：源码内容
  1. /* $Id: head.S,v 1.44 2002/02/05 15:39:57 bjornw Exp $
  2.  * 
  3.  * Head of the kernel - alter with care
  4.  *
  5.  * Copyright (C) 2000, 2001 Axis Communications AB
  6.  *
  7.  * Authors: Bjorn Wesen (bjornw@axis.com)
  8.  * 
  9.  * $Log: head.S,v $
  10.  * Revision 1.44  2002/02/05 15:39:57  bjornw
  11.  * Oops.. non-CRAMFS_MAGIC should jump over the copying, not into it...
  12.  *
  13.  * Revision 1.43  2001/11/08 15:09:43  starvik
  14.  * Only start MII clock if Ethernet is configured
  15.  *
  16.  * Revision 1.42  2001/11/08 14:37:34  starvik
  17.  * Start MII clock early to make sure that it is running at tranceiver reset
  18.  *
  19.  * Revision 1.41  2001/10/29 14:55:58  pkj
  20.  * Corrected pa$r0 to par0.
  21.  *
  22.  * Revision 1.40  2001/10/03 14:59:57  pkj
  23.  * Added support for resetting the Bluetooth hardware.
  24.  *
  25.  * Revision 1.39  2001/10/01 14:45:03  bjornw
  26.  * Removed underscores and added register prefixes
  27.  *
  28.  * Revision 1.38  2001/09/21 07:14:11  jonashg
  29.  * Made root filesystem (cramfs) use mtdblock driver when booting from flash.
  30.  *
  31.  * Revision 1.37  2001/09/11 13:44:29  orjanf
  32.  * Decouple usage of serial ports for debug and kgdb.
  33.  *
  34.  * Revision 1.36  2001/06/29 12:39:31  pkj
  35.  * Added support for mirroring the first flash to just below the
  36.  * second one, to make them look consecutive to cramfs.
  37.  *
  38.  * Revision 1.35  2001/06/25 14:07:00  hp
  39.  *  Fix review comment.
  40.  *  * head.S: Use IO_STATE, IO_FIELD and IO_MASK constructs instead of
  41.  *  magic numbers.  Add comment that -traditional must not be used.
  42.  *  * entry.S (SYMBOL_NAME): Change redefinition to use ## concatenation.
  43.  *  Correct and update comment.
  44.  *  * Makefile (.S.o): Don't use -traditional.  Add comment why the
  45.  *  toplevel rule can't be used (now that there's a reason).
  46.  *
  47.  * Revision 1.34  2001/05/15 07:08:14  hp
  48.  * Tweak "notice" to reflect that both r8 r9 are used
  49.  *
  50.  * Revision 1.33  2001/05/15 06:40:05  hp
  51.  * Put bulk of code in .text.init, data in .data.init
  52.  *
  53.  * Revision 1.32  2001/05/15 06:18:56  hp
  54.  * Execute review comment: s/bcc/bhs/g; s/bcs/blo/g
  55.  *
  56.  * Revision 1.31  2001/05/15 06:08:40  hp
  57.  * Add sentence about autodetecting the bit31-MMU-bug
  58.  *
  59.  * Revision 1.30  2001/05/15 06:00:05  hp
  60.  * Update comment: LOW_MAP is not forced on xsim anymore.
  61.  *
  62.  * Revision 1.29  2001/04/18 12:51:59  orjanf
  63.  * * Reverted review change regarding the use of bcs/bcc.
  64.  * * Removed non-working LED-clearing code.
  65.  *
  66.  * Revision 1.28  2001/04/17 13:58:39  orjanf
  67.  * * Renamed CONFIG_KGDB to CONFIG_ETRAX_KGDB.
  68.  *
  69.  * Revision 1.27  2001/04/17 11:42:35  orjanf
  70.  * Changed according to review:
  71.  * * Added comment explaining memory map bug.
  72.  * * Changed bcs and bcc to blo and bhs, respectively.
  73.  * * Removed mentioning of Stallone and Olga boards.
  74.  *
  75.  * Revision 1.26  2001/04/06 12:31:07  jonashg
  76.  * Check for cramfs in flash before RAM instead of RAM before flash.
  77.  *
  78.  * Revision 1.25  2001/04/04 06:23:53  starvik
  79.  * Initialize DRAM if not already initialized
  80.  *
  81.  * Revision 1.24  2001/04/03 11:12:00  starvik
  82.  * Removed dram init (done by rescue or etrax100boot
  83.  * Corrected include
  84.  *
  85.  * Revision 1.23  2001/04/03 09:53:03  starvik
  86.  * Include hw_settings.S
  87.  *
  88.  * Revision 1.22  2001/03/26 14:23:26  bjornw
  89.  * Namechange of some config options
  90.  *
  91.  * Revision 1.21  2001/03/08 12:14:41  bjornw
  92.  * * Config name for ETRAX IDE was renamed
  93.  * * Removed G27 auto-setting when JULIETTE is chosen (need to make this
  94.  *   a new config option later)
  95.  *
  96.  * Revision 1.20  2001/02/23 12:47:56  bjornw
  97.  * MMU regs during LOW_MAP updated to reflect a newer reality
  98.  *
  99.  * Revision 1.19  2001/02/19 11:12:07  bjornw
  100.  * Changed comment header format
  101.  *
  102.  * Revision 1.18  2001/02/15 07:25:38  starvik
  103.  * Added support for synchronous serial ports
  104.  *
  105.  * Revision 1.17  2001/02/08 15:53:13  starvik
  106.  * Last commit removed some important ifdefs
  107.  *
  108.  * Revision 1.16  2001/02/08 15:20:38  starvik
  109.  * Include dram_init.S as inline
  110.  *
  111.  * Revision 1.15  2001/01/29 18:12:01  bjornw
  112.  * Corrected some comments
  113.  *
  114.  * Revision 1.14  2001/01/29 13:11:29  starvik
  115.  * Include dram_init.S (with DRAM/SDRAM initialization)
  116.  *
  117.  * Revision 1.13  2001/01/23 14:54:57  markusl
  118.  * Updated for USB
  119.  * i.e. added r_gen_config settings
  120.  *
  121.  * Revision 1.12  2001/01/19 16:16:29  perf
  122.  * Added temporary mapping of 0x0c->0x0c to avoid flash loading confusion.
  123.  * Renamed serial options from ETRAX100 to ETRAX.
  124.  *
  125.  * Revision 1.11  2001/01/16 16:31:38  bjornw
  126.  * * Changed name and semantics of running_from_flash to romfs_in_flash,
  127.  *   set by head.S to indicate to setup.c whether there is a cramfs image
  128.  *   after the kernels BSS or not. Should work for all three boot-cases
  129.  *   (DRAM with cramfs in DRAM, DRAM with cramfs in flash (compressed boot),
  130.  *    and flash with cramfs in flash)
  131.  *
  132.  * Revision 1.10  2001/01/16 14:12:21  bjornw
  133.  * * Check for cramfs start passed in r9 from the decompressor, if all other
  134.  *   cramfs options fail (if we boot from DRAM but don't find a cramfs image
  135.  *   after the kernel in DRAM, it is probably still in the flash)
  136.  * * Check magic in cramfs detection when booting from flash directly
  137.  *
  138.  * Revision 1.9  2001/01/15 17:17:02  bjornw
  139.  * * Corrected the code that detects the cramfs lengths
  140.  * * Added a comment saying that the above does not work due to other
  141.  *   reasons..
  142.  *
  143.  * Revision 1.8  2001/01/15 16:27:51  jonashg
  144.  * Made boot after flashing work.
  145.  * * end destination is __vmlinux_end in RAM.
  146.  * * _romfs_start moved because of virtual memory.
  147.  *
  148.  * Revision 1.7  2000/11/21 13:55:29  bjornw
  149.  * Use CONFIG_CRIS_LOW_MAP for the low VM map instead of explicit CPU type
  150.  *
  151.  * Revision 1.6  2000/10/06 12:36:55  bjornw
  152.  * Forgot swapper_pg_dir when changing memory map..
  153.  *
  154.  * Revision 1.5  2000/10/04 16:49:30  bjornw
  155.  * * Fixed memory mapping in LX
  156.  * * Check for cramfs instead of romfs
  157.  *
  158.  */
  160. #include <linux/config.h>
  161. #define ASSEMBLER_MACROS_ONLY
  162. /* The IO_* macros use the ## token concatenation operator, so
  163.    -traditional must not be used when assembling this file.  */
  164. #include <asm/sv_addr_ag.h>
  166. #define CRAMFS_MAGIC 0x28cd3d45
  167. #define RAM_INIT_MAGIC 0x56902387
  169. #define START_ETHERNET_CLOCK IO_STATE(R_NETWORK_GEN_CONFIG, enable, on) |
  170.                              IO_STATE(R_NETWORK_GEN_CONFIG, phy, mii_clk)
  172. ;; exported symbols
  174. .globl etrax_irv
  175. .globl romfs_start
  176. .globl romfs_length
  177. .globl romfs_in_flash
  178. .globl  swapper_pg_dir
  180. .text
  182. ;; This is the entry point of the kernel. We are in supervisor mode.
  183. ;; 0x00000000 if Flash, 0x40004000 if DRAM
  184. ;; since etrax actually starts at address 2 when booting from flash, we
  185. ;; put a nop (2 bytes) here first so we dont accidentally skip the di
  186. ;;
  187. ;; NOTICE! The registers r8 and r9 are used as parameters carrying
  188. ;; information from the decompressor (if the kernel was compressed). 
  189. ;; They should not be used in the code below until read.
  191. nop
  192. di
  194. ;; First setup the kseg_c mapping from where the kernel is linked
  195. ;; to 0x40000000 (where the actual DRAM resides) otherwise
  196. ;; we cannot do very much! See arch/cris/README.mm
  197. ;;
  198. ;; Notice that since we're potentially running at 0x00 or 0x40 right now,
  199. ;; we will get a fault as soon as we enable the MMU if we dont
  200. ;; temporarily map those segments linearily.
  201. ;;
  202. ;; Due to a bug in Etrax-100 LX version 1 we need to map the memory
  203. ;; slightly different.  The bug is that you can't remap bit 31 of
  204. ;; an address.  Though we can check the version register for
  205. ;; whether the bug is present, some constants would then have to
  206. ;; be variables, so we don't.  The drawback is that you can "only" map
  207. ;; 1G per process with CONFIG_CRIS_LOW_MAP.
  209. #ifdef CONFIG_CRIS_LOW_MAP
  210. ; kseg mappings, temporary map of 0xc0->0x40
  211.   move.d   IO_FIELD (R_MMU_KBASE_HI, base_c, 4)
  212. | IO_FIELD (R_MMU_KBASE_HI, base_b, 0xb)
  213. | IO_FIELD (R_MMU_KBASE_HI, base_9, 9)
  214. | IO_FIELD (R_MMU_KBASE_HI, base_8, 8), $r0
  215. move.d $r0, [R_MMU_KBASE_HI]
  217. ; temporary map of 0x40->0x40 and 0x60->0x40 
  218.   move.d   IO_FIELD (R_MMU_KBASE_LO, base_6, 4)
  219. | IO_FIELD (R_MMU_KBASE_LO, base_4, 4), $r0
  220. move.d $r0, [R_MMU_KBASE_LO]
  222. ; mmu enable, segs e,c,b,a,6,5,4,0 segment mapped
  223.   move.d   IO_STATE (R_MMU_CONFIG, mmu_enable, enable)
  224. | IO_STATE (R_MMU_CONFIG, inv_excp, enable)
  225. | IO_STATE (R_MMU_CONFIG, acc_excp, enable)
  226. | IO_STATE (R_MMU_CONFIG, we_excp, enable)
  227. | IO_STATE (R_MMU_CONFIG, seg_f, page)
  228. | IO_STATE (R_MMU_CONFIG, seg_e, seg)
  229. | IO_STATE (R_MMU_CONFIG, seg_d, page)
  230. | IO_STATE (R_MMU_CONFIG, seg_c, seg)
  231. | IO_STATE (R_MMU_CONFIG, seg_b, seg)
  232. | IO_STATE (R_MMU_CONFIG, seg_a, seg)
  233. | IO_STATE (R_MMU_CONFIG, seg_9, page)
  234. | IO_STATE (R_MMU_CONFIG, seg_8, page)
  235. | IO_STATE (R_MMU_CONFIG, seg_7, page)
  236. | IO_STATE (R_MMU_CONFIG, seg_6, seg)
  237. | IO_STATE (R_MMU_CONFIG, seg_5, seg)
  238. | IO_STATE (R_MMU_CONFIG, seg_4, seg)
  239. | IO_STATE (R_MMU_CONFIG, seg_3, page)
  240. | IO_STATE (R_MMU_CONFIG, seg_2, page)
  241. | IO_STATE (R_MMU_CONFIG, seg_1, page)
  242. | IO_STATE (R_MMU_CONFIG, seg_0, seg), $r0
  243. move.d $r0, [R_MMU_CONFIG]
  244. #else
  245. ; kseg mappings
  246.   move.d   IO_FIELD (R_MMU_KBASE_HI, base_e, 8)
  247. | IO_FIELD (R_MMU_KBASE_HI, base_c, 4)
  248. | IO_FIELD (R_MMU_KBASE_HI, base_b, 0xb), $r0
  249. move.d $r0, [R_MMU_KBASE_HI]
  251. ; temporary map of 0x40->0x40 and 0x00->0x00 
  252. move.d   IO_FIELD (R_MMU_KBASE_LO, base_4, 4), $r0
  253. move.d $r0, [R_MMU_KBASE_LO]
  255. ; mmu enable, segs f,e,c,b,4,0 segment mapped
  256.   move.d   IO_STATE (R_MMU_CONFIG, mmu_enable, enable)
  257. | IO_STATE (R_MMU_CONFIG, inv_excp, enable)
  258. | IO_STATE (R_MMU_CONFIG, acc_excp, enable)
  259. | IO_STATE (R_MMU_CONFIG, we_excp, enable)
  260. | IO_STATE (R_MMU_CONFIG, seg_f, seg)
  261. | IO_STATE (R_MMU_CONFIG, seg_e, seg)
  262. | IO_STATE (R_MMU_CONFIG, seg_d, page)
  263. | IO_STATE (R_MMU_CONFIG, seg_c, seg)
  264. | IO_STATE (R_MMU_CONFIG, seg_b, seg)
  265. | IO_STATE (R_MMU_CONFIG, seg_a, page)
  266. | IO_STATE (R_MMU_CONFIG, seg_9, page)
  267. | IO_STATE (R_MMU_CONFIG, seg_8, page)
  268. | IO_STATE (R_MMU_CONFIG, seg_7, page)
  269. | IO_STATE (R_MMU_CONFIG, seg_6, page)
  270. | IO_STATE (R_MMU_CONFIG, seg_5, page)
  271. | IO_STATE (R_MMU_CONFIG, seg_4, seg)
  272. | IO_STATE (R_MMU_CONFIG, seg_3, page)
  273. | IO_STATE (R_MMU_CONFIG, seg_2, page)
  274. | IO_STATE (R_MMU_CONFIG, seg_1, page)
  275. | IO_STATE (R_MMU_CONFIG, seg_0, seg), $r0
  276. move.d $r0, [R_MMU_CONFIG]
  277. #endif
  279. ;; Now we need to sort out the segments and their locations in RAM or
  280. ;; Flash. The image in the Flash (or in DRAM) consists of 3 pieces:
  281. ;; 1) kernel text, 2) kernel data, 3) ROM filesystem image
  282. ;; But the linker has linked the kernel to expect this layout in
  283. ;; DRAM memory:
  284. ;; 1) kernel text, 2) kernel data, 3) kernel BSS
  285. ;; (the location of the ROM filesystem is determined by the krom driver)
  286. ;; If we boot this from Flash, we want to keep the ROM filesystem in
  287. ;; the flash, we want to copy the text and need to copy the data to DRAM.
  288. ;; But if we boot from DRAM, we need to move the ROMFS image
  289. ;; from its position after kernel data, to after kernel BSS, BEFORE the
  290. ;; kernel starts using the BSS area (since its "overlayed" with the ROMFS)
  291. ;;
  292. ;; In both cases, we start in un-cached mode, and need to jump into a
  293. ;; cached PC after we're done fiddling around with the segments.
  294. ;; 
  295. ;; arch/etrax100/etrax100.ld sets some symbols that define the start
  296. ;; and end of each segment.
  298. ;; Check if we start from DRAM or FLASH by testing PC
  300. move.d $pc,$r0
  301. and.d 0x7fffffff,$r0 ; get rid of the non-cache bit
  302. cmp.d 0x10000,$r0 ; arbitrary... just something above this code
  303. blo _inflash0
  304. nop
  306. jump _inram ; enter cached ram
  308. ;; Jumpgate for branches.
  309. _inflash0:
  310. jump _inflash
  312. ;; Put this in a suitable section where we can reclaim storage
  313. ;; after init.
  314. .section ".text.init"
  315. _inflash:
  316. #ifdef CONFIG_ETRAX_ETHERNET
  317. ;; Start MII clock to make sure it is running when tranceiver is reset
  318. move.d START_ETHERNET_CLOCK, $r0
  319. move.d $r0, [R_NETWORK_GEN_CONFIG]
  320. #endif
  322. ;; We need to initialze DRAM registers before we start using the DRAM
  324. cmp.d RAM_INIT_MAGIC, $r8 ; Already initialized?
  325. beq _dram_init_finished
  326. nop
  328. #include "../lib/dram_init.S"
  330. _dram_init_finished:
  331. ;; Copy text+data to DRAM
  332. ;; This is fragile - the calculation of r4 as the image size depends
  333. ;; on that the labels below actually are the first and last positions
  334. ;; in the linker-script.
  335. ;;
  336. ;; Then the locating of the cramfs image depends on the aforementioned
  337. ;; image being located in the flash at 0. This is most often not true,
  338. ;; thus the following does not work (normally there is a rescue-block
  339. ;; between the physical start of the flash and the flash-image start,
  340. ;; and when run with compression, the kernel is actually unpacked to
  341. ;; DRAM and we never get here in the first place :))
  343. moveq 0, $r0 ; source
  344. move.d text_start, $r1 ; destination
  345. move.d __vmlinux_end, $r2 ; end destination
  346. move.d $r2, $r4
  347. sub.d $r1, $r4 ; r4=__vmlinux_end in flash, used below
  348. 1: move.w [$r0+], $r3
  349. move.w $r3, [$r1+]
  350. cmp.d $r2, $r1
  351. blo 1b
  352. nop
  354. ;; We keep the cramfs in the flash.
  355. ;; There might be none, but that does not matter because
  356. ;; we don't do anything than read some bytes here.
  358. moveq 0, $r0
  359. move.d $r0, [romfs_length] ; default if there is no cramfs
  361. move.d  [$r4], $r0 ; cramfs_super.magic
  362. cmp.d CRAMFS_MAGIC, $r0
  363. bne 1f
  364. nop
  365. move.d [$r4 + 4], $r0 ; cramfs_super.size
  366. move.d $r0, [romfs_length]
  367. #ifdef CONFIG_CRIS_LOW_MAP
  368. add.d   0x50000000, $r4 ; add flash start in virtual memory (cached)
  369. #else
  370. add.d   0xf0000000, $r4 ; add flash start in virtual memory (cached)
  371. #endif
  372. move.d $r4, [romfs_start]
  373. 1:
  374. moveq 1, $r0
  375. move.d $r0, [romfs_in_flash]
  377. jump _start_it ; enter code, cached this time
  379. _inram:
  380. ;; Move the ROM fs to after BSS end. This assumes that the cramfs
  381. ;; second longword contains the length of the cramfs
  383. moveq 0, $r0
  384. move.d $r0, [romfs_length] ; default if there is no cramfs
  386. ;; The kernel could have been unpacked to DRAM by the loader, but
  387. ;; the cramfs image could still be in the Flash directly after the
  388. ;; compressed kernel image. The loader passes the address of the
  389. ;; byte succeeding the last compressed byte in the flash in the
  390. ;; register r9 when starting the kernel. Check if r9 points to a
  391. ;; decent cramfs image!
  392. ;; (Notice that if this is not booted from the loader, r9 will be
  393. ;;  garbage but we do sanity checks on it, the chance that it points
  394. ;;  to a cramfs magic is small.. )
  396. cmp.d 0x0ffffff8, $r9
  397. bhs _no_romfs_in_flash ; r9 points outside the flash area
  398. nop
  399. move.d [$r9], $r0 ; cramfs_super.magic
  400. cmp.d CRAMFS_MAGIC, $r0
  401. bne _no_romfs_in_flash
  402. nop
  403. move.d [$r9+4], $r0 ; cramfs_super.length
  404. move.d $r0, [romfs_length]
  405. #ifdef CONFIG_CRIS_LOW_MAP
  406. add.d   0x50000000, $r9 ; add flash start in virtual memory (cached)
  407. #else
  408. add.d   0xf0000000, $r9 ; add flash start in virtual memory (cached)
  409. #endif
  410. move.d $r9, [romfs_start]
  412. moveq 1, $r0
  413. move.d $r0, [romfs_in_flash]
  415. jump _start_it ; enter code, cached this time
  417. _no_romfs_in_flash:
  418. ;; Check if there is a cramfs (magic value).
  419. ;; Notice that we check for cramfs magic value - which is
  420. ;; the "rom fs" we'll possibly use in 2.4 if not JFFS (which does
  421. ;; not need this mechanism anyway)
  423. move.d __vmlinux_end, $r0; the image will be after the vmlinux end address
  424. move.d [$r0], $r1 ; cramfs assumes same endian on host/target
  425. cmp.d CRAMFS_MAGIC, $r1; magic value in cramfs superblock
  426. bne 2f
  427. nop
  429. ;; Ok. What is its size ? 
  431. move.d [$r0 + 4], $r2 ; cramfs_super.size (again, no need to swapwb)
  433. ;; We want to copy it to the end of the BSS
  435. move.d _end, $r1
  437. ;; Remember values so cramfs and setup can find this info
  439. move.d $r1, [romfs_start] ; new romfs location
  440. move.d $r2, [romfs_length]
  442. ;; We need to copy it backwards, since they can be overlapping
  444. add.d $r2, $r0
  445. add.d $r2, $r1
  447. ;; Go ahead. Make my loop.
  449. lsrq 1, $r2 ; size is in bytes, we copy words
  451. 1: move.w [$r0=$r0-2],$r3
  452. move.w $r3,[$r1=$r1-2]
  453. subq 1, $r2
  454. bne 1b
  455. nop
  457. 2:
  458. ;; Dont worry that the BSS is tainted. It will be cleared later.
  460. moveq 0, $r0
  461. move.d $r0, [romfs_in_flash]
  463. jump _start_it ; better skip the additional cramfs check below
  465. _start_it:
  466. ;; the kernel stack is overlayed with the task structure for each
  467. ;; task. thus the initial kernel stack is in the same page as the
  468. ;; init_task (but starts in the top of the page, size 8192)
  469. move.d init_task_union + 8192, $sp
  470. move.d ibr_start,$r0 ; this symbol is set by the linker script 
  471. move $r0,$ibr
  472. move.d $r0,[etrax_irv] ; set the interrupt base register and pointer
  474. ;; Clear BSS region, from _bss_start to _end
  476. move.d __bss_start, $r0
  477. move.d _end, $r1
  478. 1: clear.d [$r0+]
  479. cmp.d $r1, $r0
  480. blo 1b
  481. nop
  483. #ifdef CONFIG_BLK_DEV_ETRAXIDE
  484. ;; disable ATA before enabling it in genconfig below
  485. moveq 0,$r0
  486. move.d $r0,[R_ATA_CTRL_DATA]
  487. move.d $r0,[R_ATA_TRANSFER_CNT]
  488. move.d $r0,[R_ATA_CONFIG]
  489. #if 0
  490. move.d R_PORT_G_DATA, $r1
  491. move.d $r0, [$r1]; assert ATA bus-reset
  492. nop
  493. nop
  494. nop
  495. nop
  496. nop
  497. nop
  498. move.d 0x08000000,$r0
  499. move.d $r0,[$r1]
  500. #endif
  501. #endif
  503. #ifdef CONFIG_JULIETTE
  504. ;; configure external DMA channel 0 before enabling it in genconfig
  506. moveq 0,$r0
  507. move.d $r0,[R_EXT_DMA_0_ADDR]
  508. ; cnt enable, word size, output, stop, size 0
  509. move.d   IO_STATE (R_EXT_DMA_0_CMD, cnt, enable)
  510. | IO_STATE (R_EXT_DMA_0_CMD, rqpol, ahigh)
  511. | IO_STATE (R_EXT_DMA_0_CMD, apol, ahigh)
  512. | IO_STATE (R_EXT_DMA_0_CMD, rq_ack, burst)
  513. | IO_STATE (R_EXT_DMA_0_CMD, wid, word)
  514. | IO_STATE (R_EXT_DMA_0_CMD, dir, output)
  515. | IO_STATE (R_EXT_DMA_0_CMD, run, stop)
  516. | IO_FIELD (R_EXT_DMA_0_CMD, trf_count, 0),$r0
  517. move.d $r0,[R_EXT_DMA_0_CMD]
  519. ;; reset dma4 and wait for completion
  521. moveq IO_STATE (R_DMA_CH4_CMD, cmd, reset),$r0
  522. move.b $r0,[R_DMA_CH4_CMD]
  523. 1: move.b [R_DMA_CH4_CMD],$r0
  524. and.b IO_MASK (R_DMA_CH4_CMD, cmd),$r0
  525. cmp.b IO_STATE (R_DMA_CH4_CMD, cmd, reset),$r0
  526. beq 1b
  527. nop
  529. ;; reset dma5 and wait for completion
  531. moveq IO_STATE (R_DMA_CH5_CMD, cmd, reset),$r0
  532. move.b $r0,[R_DMA_CH5_CMD]
  533. 1: move.b [R_DMA_CH5_CMD],$r0
  534. and.b IO_MASK (R_DMA_CH5_CMD, cmd),$r0
  535. cmp.b IO_STATE (R_DMA_CH5_CMD, cmd, reset),$r0
  536. beq 1b
  537. nop
  538. #endif
  540. ;; Etrax product HW genconfig setup
  542. moveq 0,$r0
  543. #if (!defined(CONFIG_ETRAX_KGDB) || !defined(CONFIG_ETRAX_DEBUG_PORT0)) 
  544. && !defined(CONFIG_DMA_MEMCPY)
  545. ; DMA channels 6 and 7 to ser0, kgdb doesnt want DMA
  546. or.d   IO_STATE (R_GEN_CONFIG, dma7, serial0)
  547. | IO_STATE (R_GEN_CONFIG, dma6, serial0),$r0
  548. #endif
  549. #if !defined(CONFIG_ETRAX_KGDB) || !defined(CONFIG_ETRAX_DEBUG_PORT1)
  550. ; DMA channels 8 and 9 to ser1, kgdb doesnt want DMA
  551. or.d   IO_STATE (R_GEN_CONFIG, dma9, serial1)
  552. | IO_STATE (R_GEN_CONFIG, dma8, serial1),$r0
  553. #endif
  554. #ifdef CONFIG_DMA_MEMCPY
  555. ; 6/7 memory-memory DMA
  556. or.d   IO_STATE (R_GEN_CONFIG, dma7, intdma6)
  557. | IO_STATE (R_GEN_CONFIG, dma6, intdma7),$r0
  558. #endif
  559. #ifdef CONFIG_ETRAX_SERIAL_PORT2
  560. ; Enable serial port 2
  561. or.w IO_STATE (R_GEN_CONFIG, ser2, select),$r0
  562. #if !defined(CONFIG_ETRAX_KGDB) || !defined(CONFIG_ETRAX_DEBUG_PORT2)
  563. ; DMA channels 2 and 3 to ser2, kgdb doesnt want DMA
  564. or.d   IO_STATE (R_GEN_CONFIG, dma3, serial2)
  565. | IO_STATE (R_GEN_CONFIG, dma2, serial2),$r0
  566. #endif
  567. #endif
  568. #if defined(CONFIG_ETRAX_SERIAL_PORT3) || defined(CONFIG_ETRAX_SYNCHRONOUS_SERIAL_PORT1)
  569. ; Enable serial port 3
  570. or.w IO_STATE (R_GEN_CONFIG, ser3, select),$r0
  571. #if !defined(CONFIG_ETRAX_KGDB) || !defined(CONFIG_ETRAX_DEBUG_PORT3)
  572. ; DMA channels 4 and 5 to ser3, kgdb doesnt want DMA
  573. or.d   IO_STATE (R_GEN_CONFIG, dma5, serial3)
  574. | IO_STATE (R_GEN_CONFIG, dma4, serial3),$r0
  575. #endif
  576. #endif
  577. #if defined(CONFIG_ETRAX_PARALLEL_PORT0) || defined(CONFIG_ETRAX_ETHERNET_LPSLAVE)
  578. ; parport 0 enabled using DMA 2/3
  579. or.w IO_STATE (R_GEN_CONFIG, par0, select),$r0
  580. #endif
  581. #if defined(CONFIG_ETRAX_PARALLEL_PORT1) || defined(CONFIG_ETRAX_ETHERNET_LPSLAVE)
  582. ; parport 1 enabled using DMA 4/5
  583. or.w IO_STATE (R_GEN_CONFIG, par1, select),$r0
  584. #endif
  585. #ifdef CONFIG_ETRAX_IDE
  586. ; DMA channels 2 and 3 to ATA, ATA enabled
  587. or.d   IO_STATE (R_GEN_CONFIG, dma3, ata)
  588. | IO_STATE (R_GEN_CONFIG, dma2, ata)
  589. | IO_STATE (R_GEN_CONFIG, ata, select),$r0
  590. #endif
  592. #ifdef CONFIG_ETRAX_USB_HOST_PORT1
  593. ; Set the USB port 1 enable bit
  594. or.d IO_STATE (R_GEN_CONFIG, usb1, select),$r0
  595. #endif
  596. #ifdef CONFIG_ETRAX_USB_HOST_PORT2
  597. ; Set the USB port 2 enable bit
  598. or.d IO_STATE (R_GEN_CONFIG, usb2, select),$r0
  599. #endif
  600. #ifdef CONFIG_ETRAX_USB_HOST
  601. ; Connect DMA channels 8 and 9 to USB
  602. and.d (~(IO_MASK (R_GEN_CONFIG, dma9)
  603.    | IO_MASK (R_GEN_CONFIG, dma8)))
  604. | IO_STATE (R_GEN_CONFIG, dma9, usb)
  605. | IO_STATE (R_GEN_CONFIG, dma8, usb),$r0
  606. #endif
  608. #ifdef CONFIG_JULIETTE
  609. ; DMA channels 4 and 5 to EXTDMA0, for Juliette
  610. or.d   IO_STATE (R_GEN_CONFIG, dma5, extdma0)
  611. | IO_STATE (R_GEN_CONFIG, dma4, extdma0),$r0
  612. #endif
  614. #if defined(CONFIG_BLUETOOTH) && (defined(CONFIG_BLUETOOTH_RESET_G10) || defined(CONFIG_BLUETOOTH_RESET_G11))
  615. or.d   IO_STATE (R_GEN_CONFIG, g8_15dir, out),$r0
  616. #endif
  618. move.d $r0,[genconfig_shadow] ; init a shadow register of R_GEN_CONFIG
  620. #ifndef CONFIG_SVINTO_SIM
  621. move.d $r0,[R_GEN_CONFIG]
  623. #if 0
  624. moveq 4,$r0
  625. move.b $r0,[R_DMA_CH6_CMD] ; reset (ser0 dma out)
  626. move.b $r0,[R_DMA_CH7_CMD] ; reset (ser0 dma in)
  627. 1: move.b [R_DMA_CH6_CMD],$r0 ; wait for reset cycle to finish
  628. and.b 7,$r0
  629. cmp.b 4,$r0
  630. beq 1b
  631. nop
  632. 1: move.b [R_DMA_CH7_CMD],$r0 ; wait for reset cycle to finish
  633. and.b 7,$r0
  634. cmp.b 4,$r0
  635. beq 1b
  636. nop
  637. #endif
  639. moveq IO_STATE (R_DMA_CH8_CMD, cmd, reset),$r0
  640. move.b $r0,[R_DMA_CH8_CMD] ; reset (ser1 dma out)
  641. move.b $r0,[R_DMA_CH9_CMD] ; reset (ser1 dma in)
  642. 1: move.b [R_DMA_CH8_CMD],$r0 ; wait for reset cycle to finish
  643. andq IO_MASK (R_DMA_CH8_CMD, cmd),$r0
  644. cmpq IO_STATE (R_DMA_CH8_CMD, cmd, reset),$r0
  645. beq 1b
  646. nop
  647. 1: move.b [R_DMA_CH9_CMD],$r0 ; wait for reset cycle to finish
  648. andq IO_MASK (R_DMA_CH9_CMD, cmd),$r0
  649. cmpq IO_STATE (R_DMA_CH9_CMD, cmd, reset),$r0
  650. beq 1b
  651. nop
  653. ;; setup port PA and PB default initial directions and data
  654. ;; including their shadow registers
  656. move.b CONFIG_ETRAX_DEF_R_PORT_PA_DIR,$r0
  657. #if defined(CONFIG_BLUETOOTH) && defined(CONFIG_BLUETOOTH_RESET_PA7)
  658. or.b IO_STATE (R_PORT_PA_DIR, dir7, output),$r0
  659. #endif
  660. move.b $r0,[port_pa_dir_shadow]
  661. move.b $r0,[R_PORT_PA_DIR]
  662. move.b CONFIG_ETRAX_DEF_R_PORT_PA_DATA,$r0
  663. #if defined(CONFIG_BLUETOOTH) && defined(CONFIG_BLUETOOTH_RESET_PA7)
  664. #if defined(CONFIG_BLUETOOTH_RESET_ACTIVE_HIGH)
  665. and.b ~(1 << 7),$r0
  666. #else
  667. or.b (1 << 7),$r0
  668. #endif
  669. #endif
  670. move.b $r0,[port_pa_data_shadow]
  671. move.b $r0,[R_PORT_PA_DATA]
  673. move.b CONFIG_ETRAX_DEF_R_PORT_PB_CONFIG,$r0
  674. move.b $r0,[port_pb_config_shadow]
  675. move.b $r0,[R_PORT_PB_CONFIG]
  676. move.b CONFIG_ETRAX_DEF_R_PORT_PB_DIR,$r0
  677. #if defined(CONFIG_BLUETOOTH) && defined(CONFIG_BLUETOOTH_RESET_PB5)
  678. or.b IO_STATE (R_PORT_PB_DIR, dir5, output),$r0
  679. #endif
  680. move.b $r0,[port_pb_dir_shadow]
  681. move.b $r0,[R_PORT_PB_DIR]
  682. move.b CONFIG_ETRAX_DEF_R_PORT_PB_DATA,$r0
  683. #if defined(CONFIG_BLUETOOTH) && defined(CONFIG_BLUETOOTH_RESET_PB5)
  684. #if defined(CONFIG_BLUETOOTH_RESET_ACTIVE_HIGH)
  685. and.b ~(1 << 5),$r0
  686. #else
  687. or.b (1 << 5),$r0
  688. #endif
  689. #endif
  690. move.b $r0,[port_pb_data_shadow]
  691. move.b $r0,[R_PORT_PB_DATA]
  693. moveq   0, $r0
  694. move.d  $r0,[port_pb_i2c_shadow]
  695. move.d  $r0, [R_PORT_PB_I2C]
  697. moveq 0,$r0
  698. #if defined(CONFIG_BLUETOOTH) && defined(CONFIG_BLUETOOTH_RESET_G10)
  699. #if defined(CONFIG_BLUETOOTH_RESET_ACTIVE_HIGH)
  700. and.d ~(1 << 10),$r0
  701. #else
  702. or.d (1 << 10),$r0
  703. #endif
  704. #endif
  705. #if defined(CONFIG_BLUETOOTH) && defined(CONFIG_BLUETOOTH_RESET_G11)
  706. #if defined(CONFIG_BLUETOOTH_RESET_ACTIVE_HIGH)
  707. and.d ~(1 << 11),$r0
  708. #else
  709. or.d (1 << 11),$r0
  710. #endif
  711. #endif
  712. move.d $r0,[port_g_data_shadow]
  713. move.d $r0,[R_PORT_G_DATA]
  715. ;; setup the serial port 0 at 115200 baud for debug purposes
  717. moveq   IO_STATE (R_SERIAL0_XOFF, tx_stop, enable)
  718. | IO_STATE (R_SERIAL0_XOFF, auto_xoff, disable)
  719. | IO_FIELD (R_SERIAL0_XOFF, xoff_char, 0),$r0
  720. move.d $r0,[R_SERIAL0_XOFF] 
  722. ; 115.2kbaud for both transmit and receive
  723. move.b   IO_STATE (R_SERIAL0_BAUD, tr_baud, c115k2Hz)
  724. | IO_STATE (R_SERIAL0_BAUD, rec_baud, c115k2Hz),$r0
  725. move.b $r0,[R_SERIAL0_BAUD]
  727. ; Set up and enable the serial0 receiver.
  728. move.b   IO_STATE (R_SERIAL0_REC_CTRL, dma_err, stop)
  729. | IO_STATE (R_SERIAL0_REC_CTRL, rec_enable, enable)
  730. | IO_STATE (R_SERIAL0_REC_CTRL, rts_, active)
  731. | IO_STATE (R_SERIAL0_REC_CTRL, sampling, middle)
  732. | IO_STATE (R_SERIAL0_REC_CTRL, rec_stick_par, normal)
  733. | IO_STATE (R_SERIAL0_REC_CTRL, rec_par, even)
  734. | IO_STATE (R_SERIAL0_REC_CTRL, rec_par_en, disable)
  735. | IO_STATE (R_SERIAL0_REC_CTRL, rec_bitnr, rec_8bit),$r0
  736. move.b $r0,[R_SERIAL0_REC_CTRL] 
  738. ; Set up and enable the serial0 transmitter.
  739. move.b   IO_FIELD (R_SERIAL0_TR_CTRL, txd, 0)
  740. | IO_STATE (R_SERIAL0_TR_CTRL, tr_enable, enable)
  741. | IO_STATE (R_SERIAL0_TR_CTRL, auto_cts, disabled)
  742. | IO_STATE (R_SERIAL0_TR_CTRL, stop_bits, one_bit)
  743. | IO_STATE (R_SERIAL0_TR_CTRL, tr_stick_par, normal)
  744. | IO_STATE (R_SERIAL0_TR_CTRL, tr_par, even)
  745. | IO_STATE (R_SERIAL0_TR_CTRL, tr_par_en, disable)
  746. | IO_STATE (R_SERIAL0_TR_CTRL, tr_bitnr, tr_8bit),$r0
  747. move.b $r0,[R_SERIAL0_TR_CTRL]
  749. ;; setup the serial port 1 at 115200 baud for debug purposes
  751. moveq   IO_STATE (R_SERIAL1_XOFF, tx_stop, enable)
  752. | IO_STATE (R_SERIAL1_XOFF, auto_xoff, disable)
  753. | IO_FIELD (R_SERIAL1_XOFF, xoff_char, 0),$r0
  754. move.d $r0,[R_SERIAL1_XOFF] 
  756. ; 115.2kbaud for both transmit and receive
  757. move.b   IO_STATE (R_SERIAL1_BAUD, tr_baud, c115k2Hz)
  758. | IO_STATE (R_SERIAL1_BAUD, rec_baud, c115k2Hz),$r0
  759. move.b $r0,[R_SERIAL1_BAUD]
  761. ; Set up and enable the serial1 receiver.
  762. move.b   IO_STATE (R_SERIAL1_REC_CTRL, dma_err, stop)
  763. | IO_STATE (R_SERIAL1_REC_CTRL, rec_enable, enable)
  764. | IO_STATE (R_SERIAL1_REC_CTRL, rts_, active)
  765. | IO_STATE (R_SERIAL1_REC_CTRL, sampling, middle)
  766. | IO_STATE (R_SERIAL1_REC_CTRL, rec_stick_par, normal)
  767. | IO_STATE (R_SERIAL1_REC_CTRL, rec_par, even)
  768. | IO_STATE (R_SERIAL1_REC_CTRL, rec_par_en, disable)
  769. | IO_STATE (R_SERIAL1_REC_CTRL, rec_bitnr, rec_8bit),$r0
  770. move.b $r0,[R_SERIAL1_REC_CTRL] 
  772. ; Set up and enable the serial1 transmitter.
  773. move.b   IO_FIELD (R_SERIAL1_TR_CTRL, txd, 0)
  774. | IO_STATE (R_SERIAL1_TR_CTRL, tr_enable, enable)
  775. | IO_STATE (R_SERIAL1_TR_CTRL, auto_cts, disabled)
  776. | IO_STATE (R_SERIAL1_TR_CTRL, stop_bits, one_bit)
  777. | IO_STATE (R_SERIAL1_TR_CTRL, tr_stick_par, normal)
  778. | IO_STATE (R_SERIAL1_TR_CTRL, tr_par, even)
  779. | IO_STATE (R_SERIAL1_TR_CTRL, tr_par_en, disable)
  780. | IO_STATE (R_SERIAL1_TR_CTRL, tr_bitnr, tr_8bit),$r0
  781. move.b $r0,[R_SERIAL1_TR_CTRL]
  784. #ifdef CONFIG_ETRAX_SERIAL_PORT3
  785. ;; setup the serial port 3 at 115200 baud for debug purposes
  787. moveq   IO_STATE (R_SERIAL3_XOFF, tx_stop, enable)
  788. | IO_STATE (R_SERIAL3_XOFF, auto_xoff, disable)
  789. | IO_FIELD (R_SERIAL3_XOFF, xoff_char, 0),$r0
  790. move.d $r0,[R_SERIAL3_XOFF] 
  792. ; 115.2kbaud for both transmit and receive
  793. move.b   IO_STATE (R_SERIAL3_BAUD, tr_baud, c115k2Hz)
  794. | IO_STATE (R_SERIAL3_BAUD, rec_baud, c115k2Hz),$r0
  795. move.b $r0,[R_SERIAL3_BAUD]
  797. ; Set up and enable the serial3 receiver.
  798. move.b   IO_STATE (R_SERIAL3_REC_CTRL, dma_err, stop)
  799. | IO_STATE (R_SERIAL3_REC_CTRL, rec_enable, enable)
  800. | IO_STATE (R_SERIAL3_REC_CTRL, rts_, active)
  801. | IO_STATE (R_SERIAL3_REC_CTRL, sampling, middle)
  802. | IO_STATE (R_SERIAL3_REC_CTRL, rec_stick_par, normal)
  803. | IO_STATE (R_SERIAL3_REC_CTRL, rec_par, even)
  804. | IO_STATE (R_SERIAL3_REC_CTRL, rec_par_en, disable)
  805. | IO_STATE (R_SERIAL3_REC_CTRL, rec_bitnr, rec_8bit),$r0
  806. move.b $r0,[R_SERIAL3_REC_CTRL] 
  808. ; Set up and enable the serial3 transmitter.
  809. move.b   IO_FIELD (R_SERIAL3_TR_CTRL, txd, 0)
  810. | IO_STATE (R_SERIAL3_TR_CTRL, tr_enable, enable)
  811. | IO_STATE (R_SERIAL3_TR_CTRL, auto_cts, disabled)
  812. | IO_STATE (R_SERIAL3_TR_CTRL, stop_bits, one_bit)
  813. | IO_STATE (R_SERIAL3_TR_CTRL, tr_stick_par, normal)
  814. | IO_STATE (R_SERIAL3_TR_CTRL, tr_par, even)
  815. | IO_STATE (R_SERIAL3_TR_CTRL, tr_par_en, disable)
  816. | IO_STATE (R_SERIAL3_TR_CTRL, tr_bitnr, tr_8bit),$r0
  817. move.b $r0,[R_SERIAL3_TR_CTRL]
  818. #endif
  820. #endif /* CONFIG_SVINTO_SIM */
  822. jump start_kernel ; jump into the C-function start_kernel in init/main.c
  824. .data
  825. etrax_irv:
  826. .dword 0
  827. romfs_start:
  828. .dword 0
  829. romfs_length:
  830. .dword 0
  831. romfs_in_flash:
  832. .dword 0
  834. ;; put some special pages at the beginning of the kernel aligned
  835. ;; to page boundaries - the kernel cannot start until after this
  837. #ifdef CONFIG_CRIS_LOW_MAP
  838. swapper_pg_dir = 0x60002000
  839. #else
  840. swapper_pg_dir = 0xc0002000
  841. #endif
  843. .section ".data.init"
  844. #include "../lib/hw_settings.S"