开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
entry.S
资源名称：linux-2.4.20.tar.gz　[点击查看]
上传用户：jlfgdled
上传日期：2013-04-10
资源大小：33168k
文件大小：30k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

entry.S：源码内容
  1. /*
  2.  *  arch/s390/kernel/entry.S
  3.  *    S390 low-level entry points.
  4.  *
  5.  *  S390 version
  6.  *    Copyright (C) 1999,2000 IBM Deutschland Entwicklung GmbH, IBM Corporation
  7.  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
  8.  *               Hartmut Penner (hp@de.ibm.com),
  9.  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
  10.  */
  12. #include <linux/sys.h>
  13. #include <linux/linkage.h>
  14. #include <linux/config.h>
  15. #include <asm/cache.h>
  16. #include <asm/lowcore.h>
  17. #include <asm/errno.h>
  18. #include <asm/smp.h>
  19. #include <asm/ptrace.h>
  21. #include "asm-offsets.h"
  23. /*
  24.  * Stack layout for the system_call stack entry.
  25.  * The first few entries are identical to the user_regs_struct.
  26.  */
  27. SP_PTREGS    =  STACK_FRAME_OVERHEAD 
  28. SP_PSW       =  STACK_FRAME_OVERHEAD + PT_PSWMASK
  29. SP_R0        =  STACK_FRAME_OVERHEAD + PT_GPR0
  30. SP_R1        =  STACK_FRAME_OVERHEAD + PT_GPR1
  31. SP_R2        =  STACK_FRAME_OVERHEAD + PT_GPR2
  32. SP_R3        =  STACK_FRAME_OVERHEAD + PT_GPR3
  33. SP_R4        =  STACK_FRAME_OVERHEAD + PT_GPR4
  34. SP_R5        =  STACK_FRAME_OVERHEAD + PT_GPR5
  35. SP_R6        =  STACK_FRAME_OVERHEAD + PT_GPR6
  36. SP_R7        =  STACK_FRAME_OVERHEAD + PT_GPR7
  37. SP_R8        =  STACK_FRAME_OVERHEAD + PT_GPR8
  38. SP_R9        =  STACK_FRAME_OVERHEAD + PT_GPR9
  39. SP_R10       =  STACK_FRAME_OVERHEAD + PT_GPR10
  40. SP_R11       =  STACK_FRAME_OVERHEAD + PT_GPR11
  41. SP_R12       =  STACK_FRAME_OVERHEAD + PT_GPR12
  42. SP_R13       =  STACK_FRAME_OVERHEAD + PT_GPR13
  43. SP_R14       =  STACK_FRAME_OVERHEAD + PT_GPR14
  44. SP_R15       =  STACK_FRAME_OVERHEAD + PT_GPR15
  45. SP_AREGS     =  STACK_FRAME_OVERHEAD + PT_ACR0
  46. SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + PT_ORIGGPR2
  47. /* Now the additional entries */
  48. SP_TRAP      =  (SP_ORIG_R2+GPR_SIZE)
  49. SP_SIZE      =  (SP_TRAP+4)
  51. /*
  52.  * Base Address of this Module --- saved in __LC_ENTRY_BASE
  53.  */
  54.        .globl entry_base
  55. entry_base:
  57. #define BASED(name) name-entry_base(%r13)
  59. /*
  60.  * Register usage in interrupt handlers:
  61.  *    R9  - pointer to current task structure
  62.  *    R13 - pointer to literal pool
  63.  *    R14 - return register for function calls
  64.  *    R15 - kernel stack pointer
  65.  */
  67.         .macro  SAVE_ALL_BASE
  68.         stm     %r13,%r15,__LC_SAVE_AREA
  69.         basr    %r13,0                    #  temp base pointer
  70. 0: stam    %a2,%a4,__LC_SAVE_AREA+12
  71.         l       %r13,.Lentry_base-0b(%r13)# load &entry_base to %r13
  72. .endm
  74.         .macro  SAVE_ALL psworg,sync      # system entry macro
  75.         tm      psworg+1,0x01            # test problem state bit
  76. .if sync
  77.         bz      BASED(1f)                 # skip stack setup save
  78. .else
  79.         bnz     BASED(0f)                 # from user -> load kernel stack
  80. l %r14,__LC_ASYNC_STACK   # are we already on the async stack ?
  81. slr     %r14,%r15
  82. sra %r14,13
  83. be BASED(1f)
  84.         l       %r15,__LC_ASYNC_STACK     # load async. stack
  85. b BASED(1f)
  86. .endif
  87. 0:      l       %r15,__LC_KERNEL_STACK    # problem state -> load ksp
  88. lam %a2,%a4,BASED(.Lc_ac)   # set ac.reg. 2 to primary space
  89.   # and ac.reg. 4 to home space
  90. 1:      s       %r15,BASED(.Lc_spsize)    # make room for registers & psw
  91.         n       %r15,BASED(.Lc0xfffffff8) # align stack pointer to 8
  92.         stm     %r0,%r12,SP_R0(%r15)      # store gprs 0-12 to kernel stack
  93.         st      %r2,SP_ORIG_R2(%r15)      # store original content of gpr 2
  94.         mvc     SP_R13(12,%r15),__LC_SAVE_AREA  # move R13-R15 to stack
  95.         stam    %a0,%a15,SP_AREGS(%r15)   # store access registers to kst.
  96.         mvc     SP_AREGS+8(12,%r15),__LC_SAVE_AREA+12 # store ac. regs
  97.         mvc     SP_PSW(8,%r15),psworg    # move user PSW to stack
  98.         la      %r0,psworg               # store trap indication
  99.         st      %r0,SP_TRAP(%r15)
  100.         xc      0(4,%r15),0(%r15)         # clear back chain
  101.         .endm
  103.         .macro  RESTORE_ALL sync          # system exit macro
  104.         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)  # move user PSW to lowcore
  105.         lam     %a0,%a15,SP_AREGS(%r15)   # load the access registers
  106.         lm      %r0,%r15,SP_R0(%r15)      # load gprs 0-15 of user
  107.         ni      __LC_RETURN_PSW+1,0xfd    # clear wait state bit
  108.         lpsw    __LC_RETURN_PSW           # back to caller
  109.         .endm
  111.         .macro  GET_CURRENT
  112. l %r9,BASED(.Lc0xffffe000)  # load pointer to task_struct to %r9
  113. al %r9,__LC_KERNEL_STACK
  114.         .endm
  117. /*
  118.  * Scheduler resume function, called by switch_to
  119.  *  gpr2 = (task_struct *) prev
  120.  *  gpr3 = (task_struct *) next
  121.  * Returns:
  122.  *  gpr2 = prev
  123.  */
  124.         .globl  resume
  125. resume:
  126.         basr    %r1,0
  127. resume_base:
  128. tm __THREAD_per(%r3),0xe8 # new process is using per ?
  129. bz resume_noper-resume_base(%r1) # if not we're fine
  130.         stctl   %c9,%c11,24(%r15) # We are using per stuff
  131.         clc     __THREAD_per(12,%r3),24(%r15)
  132.         be      resume_noper-resume_base(%r1) # we got away w/o bashing TLB's
  133.         lctl    %c9,%c11,__THREAD_per(%r3) # Nope we didn't
  134. resume_noper:
  135.         stm     %r6,%r15,24(%r15)       # store resume registers of prev task
  136. st %r15,__THREAD_ksp(%r2) # store kernel stack to prev->tss.ksp
  137. l %r15,__THREAD_ksp(%r3) # load kernel stack from next->tss.ksp
  138. stam    %a2,%a2,__THREAD_ar2(%r2) # store kernel access reg. 2
  139. stam    %a4,%a4,__THREAD_ar4(%r2) # store kernel access reg. 4
  140. lam     %a2,%a2,__THREAD_ar2(%r3) # load kernel access reg. 2
  141. lam     %a4,%a4,__THREAD_ar4(%r3) # load kernel access reg. 4
  142. lm %r6,%r15,24(%r15) # load resume registers of next task
  143. ahi %r3,8192
  144. st %r3,__LC_KERNEL_STACK # __LC_KERNEL_STACK = new kernel stack
  145. br %r14
  147. /*
  148.  * do_softirq calling function. We want to run the softirq functions on the
  149.  * asynchronous interrupt stack.
  150.  */
  151. .global do_call_softirq
  152. do_call_softirq:
  153. stm %r12,%r15,24(%r15)
  154. lr %r12,%r15
  155.         basr    %r13,0
  156. do_call_base:
  157. l %r0,__LC_ASYNC_STACK
  158. slr     %r0,%r15
  159. sra %r0,13
  160. be 0f-do_call_base(%r13)
  161. l %r15,__LC_ASYNC_STACK
  162. 0: sl %r15,.Lc_overhead-do_call_base(%r13)
  163.         st %r12,0(%r15) # store backchain
  164. l %r1,.Ldo_softirq-do_call_base(%r13)
  165. basr %r14,%r1
  166. lm %r12,%r15,24(%r12)
  167. br %r14
  169. /*
  170.  * SVC interrupt handler routine. System calls are synchronous events and
  171.  * are executed with interrupts enabled.
  172.  */
  174. .globl  system_call
  175. system_call:
  176. SAVE_ALL_BASE
  177.         SAVE_ALL __LC_SVC_OLD_PSW,1
  178. lh %r8,0x8a   # get svc number from lowcore
  179.         sll     %r8,2
  180.         GET_CURRENT               # load pointer to task_struct to R9
  181.         stosm   24(%r15),0x03     # reenable interrupts
  182.         l       %r8,sys_call_table-entry_base(%r8,%r13) # get system call addr.
  183.         tm      __TASK_ptrace+3(%r9),0x02 # PT_TRACESYS
  184.         bnz     BASED(sysc_tracesys)
  185.         basr    %r14,%r8          # call sys_xxxx
  186.         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
  187.                                   # ATTENTION: check sys_execve_glue before
  188.                                   # changing anything here !!
  190. sysc_return:
  191.         tm      SP_PSW+1(%r15),0x01 # returning to user ?
  192.         bno     BASED(sysc_leave) # no-> skip resched & signal
  193. #
  194. # check, if reschedule is needed
  195. #
  196.         icm     %r0,15,__TASK_need_resched(%r9)
  197.         bnz     BASED(sysc_reschedule)
  198.         icm     %r0,15,__TASK_sigpending(%r9)
  199.         bnz     BASED(sysc_signal_return)
  200. sysc_leave:
  201. stnsm   24(%r15),0xfc     # disable I/O and ext. interrupts
  202.         RESTORE_ALL 1
  204. #
  205. # call do_signal before return
  206. #
  207. sysc_signal_return:     
  208.         la      %r2,SP_PTREGS(%r15) # load pt_regs
  209.         sr      %r3,%r3           # clear *oldset
  210.         l       %r1,BASED(.Ldo_signal)
  211. la      %r14,BASED(sysc_leave)
  212.         br      %r1               # return point is sysc_leave
  213. #
  214. # call schedule with sysc_return as return-address
  215. #
  216. sysc_reschedule:        
  217.         l       %r1,BASED(.Lschedule)
  218. la      %r14,BASED(sysc_return)
  219.         br      %r1               # call scheduler, return to sysc_return
  220. #
  221. # call trace before and after sys_call
  222. #
  223. sysc_tracesys:
  224. la %r11,BASED(sysc_return)
  226. #
  227. # call syscall_trace before and after system call
  228. # special linkage: %r11 contains the return address for trace_svc
  229. #
  230. trace_svc:
  231.         l       %r1,BASED(.Ltrace)
  232. l       %r7,BASED(.Lc_ENOSYS)
  233. st      %r7,SP_R2(%r15)   # give sysc_trace an -ENOSYS retval
  234.         basr    %r14,%r1
  235. l       %r2,SP_R2(%r15)
  236. cr      %r2,%r7   # compare with saved -ENOSYS
  237. be      BASED(trace_svc_go) # strace changed the syscall ?
  238. sll     %r2,24
  239. srl     %r2,22
  240.         l       %r8,sys_call_table-entry_base(%r2,%r13) # get system call addr.
  241. trace_svc_go:
  242. lm      %r3,%r6,SP_R3(%r15)
  243. l       %r2,SP_ORIG_R2(%r15)
  244.         basr    %r14,%r8          # call sys_xxx
  245.         st      %r2,SP_R2(%r15)   # store return value
  246.         l       %r1,BASED(.Ltrace)
  247. lr %r14,%r11   # return point is in %r11
  248.         br      %r1
  250. #
  251. # a new process exits the kernel with ret_from_fork
  252. #
  253.         .globl  ret_from_fork
  254. ret_from_fork:  
  255.         basr    %r13,0
  256.         l       %r13,.Lentry_base-.(%r13)  # setup base pointer to &entry_base
  257.         GET_CURRENT               # load pointer to task_struct to R9
  258.         stosm   24(%r15),0x03     # reenable interrupts
  259.         sr      %r0,%r0           # child returns 0
  260.         st      %r0,SP_R2(%r15)   # store return value (change R2 on stack)
  261.         l       %r1,BASED(.Lschedtail)
  262. la      %r14,BASED(sysc_return)
  263.         br      %r1               # call schedule_tail, return to sysc_return
  265. #
  266. # clone, fork, vfork, exec and sigreturn need glue,
  267. # because they all expect pt_regs as parameter,
  268. # but are called with different parameter.
  269. # return-address is set up above
  270. #
  271. sys_clone_glue: 
  272.         la      %r2,SP_PTREGS(%r15)    # load pt_regs
  273.         l       %r1,BASED(.Lclone)
  274.         br      %r1                   # branch to sys_clone
  276. sys_fork_glue:  
  277.         la      %r2,SP_PTREGS(%r15)    # load pt_regs
  278.         l       %r1,BASED(.Lfork)
  279.         br      %r1                   # branch to sys_fork
  281. sys_vfork_glue: 
  282.         la      %r2,SP_PTREGS(%r15)    # load pt_regs
  283.         l       %r1,BASED(.Lvfork)
  284.         br      %r1                   # branch to sys_vfork
  286. sys_execve_glue:        
  287.         la      %r2,SP_PTREGS(%r15)   # load pt_regs
  288.         l       %r1,BASED(.Lexecve)
  289. lr      %r12,%r14             # save return address
  290.         basr    %r14,%r1              # call sys_execve
  291.         ltr     %r2,%r2               # check if execve failed
  292.         bnz     0(%r12)               # it did fail -> store result in gpr2
  293.         b       4(%r12)               # SKIP ST 2,SP_R2(15) after BASR 14,8
  294.                                       # in system_call/sysc_tracesys
  296. sys_sigreturn_glue:     
  297.         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
  298.         l       %r1,BASED(.Lsigreturn)
  299.         br      %r1                   # branch to sys_sigreturn
  301. sys_rt_sigreturn_glue:     
  302.         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
  303.         l       %r1,BASED(.Lrt_sigreturn)
  304.         br      %r1                   # branch to sys_sigreturn
  306. #
  307. # sigsuspend and rt_sigsuspend need pt_regs as an additional
  308. # parameter and they have to skip the store of %r2 into the
  309. # user register %r2 because the return value was set in 
  310. # sigsuspend and rt_sigsuspend already and must not be overwritten!
  311. #
  313. sys_sigsuspend_glue:    
  314.         lr      %r5,%r4               # move mask back
  315.         lr      %r4,%r3               # move history1 parameter
  316.         lr      %r3,%r2               # move history0 parameter
  317.         la      %r2,SP_PTREGS(%r15)   # load pt_regs as first parameter
  318.         l       %r1,BASED(.Lsigsuspend)
  319. la      %r14,4(%r14)          # skip store of return value
  320.         br      %r1                   # branch to sys_sigsuspend
  322. sys_rt_sigsuspend_glue: 
  323.         lr      %r4,%r3               # move sigsetsize parameter
  324.         lr      %r3,%r2               # move unewset parameter
  325.         la      %r2,SP_PTREGS(%r15)   # load pt_regs as first parameter
  326.         l       %r1,BASED(.Lrt_sigsuspend)
  327. la      %r14,4(%r14)          # skip store of return value
  328.         br      %r1                   # branch to sys_rt_sigsuspend
  330. sys_sigaltstack_glue:
  331.         la      %r4,SP_PTREGS(%r15)   # load pt_regs as parameter
  332.         l       %r1,BASED(.Lsigaltstack)
  333.         br      %r1                   # branch to sys_sigreturn
  335. .globl  sys_call_table
  336. sys_call_table:
  337.         .long  sys_ni_syscall            /* 0 */
  338.         .long  sys_exit
  339.         .long  sys_fork_glue
  340.         .long  sys_read
  341.         .long  sys_write
  342.         .long  sys_open                  /* 5 */
  343.         .long  sys_close
  344.         .long  sys_ni_syscall           /* old waitpid syscall holder */
  345.         .long  sys_creat
  346.         .long  sys_link
  347.         .long  sys_unlink                /* 10 */
  348.         .long  sys_execve_glue
  349.         .long  sys_chdir
  350.         .long  sys_time
  351.         .long  sys_mknod
  352.         .long  sys_chmod                /* 15 */
  353.         .long  sys_lchown16
  354.         .long  sys_ni_syscall           /* old break syscall holder */
  355.         .long  sys_ni_syscall           /* old stat syscall holder */
  356.         .long  sys_lseek
  357.         .long  sys_getpid               /* 20 */
  358.         .long  sys_mount
  359.         .long  sys_oldumount
  360.         .long  sys_setuid16
  361.         .long  sys_getuid16
  362.         .long  sys_stime                /* 25 */
  363.         .long  sys_ptrace
  364.         .long  sys_alarm
  365.         .long  sys_ni_syscall           /* old fstat syscall holder */
  366.         .long  sys_pause
  367.         .long  sys_utime                /* 30 */
  368.         .long  sys_ni_syscall           /* old stty syscall holder */
  369.         .long  sys_ni_syscall           /* old gtty syscall holder */
  370.         .long  sys_access
  371.         .long  sys_nice
  372.         .long  sys_ni_syscall           /* 35 */  /* old ftime syscall holder */
  373.         .long  sys_sync
  374.         .long  sys_kill
  375.         .long  sys_rename
  376.         .long  sys_mkdir
  377.         .long  sys_rmdir                /* 40 */
  378.         .long  sys_dup
  379.         .long  sys_pipe
  380.         .long  sys_times
  381.         .long  sys_ni_syscall           /* old prof syscall holder */
  382.         .long  sys_brk                  /* 45 */
  383.         .long  sys_setgid16
  384.         .long  sys_getgid16
  385.         .long  sys_signal
  386.         .long  sys_geteuid16
  387.         .long  sys_getegid16            /* 50 */
  388.         .long  sys_acct
  389.         .long  sys_umount
  390.         .long  sys_ni_syscall           /* old lock syscall holder */
  391.         .long  sys_ioctl
  392.         .long  sys_fcntl                /* 55 */
  393.         .long  sys_ni_syscall           /* old mpx syscall holder */
  394.         .long  sys_setpgid
  395.         .long  sys_ni_syscall           /* old ulimit syscall holder */
  396.         .long  sys_ni_syscall           /* old uname syscall holder */
  397.         .long  sys_umask                /* 60 */
  398.         .long  sys_chroot
  399.         .long  sys_ustat
  400.         .long  sys_dup2
  401.         .long  sys_getppid
  402.         .long  sys_getpgrp              /* 65 */
  403.         .long  sys_setsid
  404.         .long  sys_sigaction
  405.         .long  sys_ni_syscall           /* old sgetmask syscall holder */
  406.         .long  sys_ni_syscall           /* old ssetmask syscall holder */
  407.         .long  sys_setreuid16           /* 70 */
  408.         .long  sys_setregid16
  409.         .long  sys_sigsuspend_glue
  410.         .long  sys_sigpending
  411.         .long  sys_sethostname
  412.         .long  sys_setrlimit            /* 75 */
  413.         .long  sys_old_getrlimit
  414.         .long  sys_getrusage
  415.         .long  sys_gettimeofday
  416.         .long  sys_settimeofday
  417.         .long  sys_getgroups16          /* 80 */
  418.         .long  sys_setgroups16
  419.         .long  sys_ni_syscall           /* old select syscall holder */
  420.         .long  sys_symlink
  421.         .long  sys_ni_syscall           /* old lstat syscall holder */
  422.         .long  sys_readlink             /* 85 */
  423.         .long  sys_uselib
  424.         .long  sys_swapon
  425.         .long  sys_reboot
  426.         .long  sys_ni_syscall           /* old readdir syscall holder */
  427.         .long  old_mmap                 /* 90 */
  428.         .long  sys_munmap
  429.         .long  sys_truncate
  430.         .long  sys_ftruncate
  431.         .long  sys_fchmod
  432.         .long  sys_fchown16              /* 95 */
  433.         .long  sys_getpriority
  434.         .long  sys_setpriority
  435.         .long  sys_ni_syscall            /* old profil syscall holder */
  436.         .long  sys_statfs
  437.         .long  sys_fstatfs               /* 100 */
  438.         .long  sys_ioperm
  439.         .long  sys_socketcall
  440.         .long  sys_syslog
  441.         .long  sys_setitimer
  442.         .long  sys_getitimer             /* 105 */
  443.         .long  sys_newstat
  444.         .long  sys_newlstat
  445.         .long  sys_newfstat
  446.         .long  sys_ni_syscall            /* old uname syscall holder */
  447.         .long  sys_ni_syscall            /* 110 */ /* iopl for i386 */
  448.         .long  sys_vhangup
  449.         .long  sys_ni_syscall            /* old "idle" system call */
  450.         .long  sys_ni_syscall            /* vm86old for i386 */
  451.         .long  sys_wait4
  452.         .long  sys_swapoff               /* 115 */
  453.         .long  sys_sysinfo
  454.         .long  sys_ipc
  455.         .long  sys_fsync
  456.         .long  sys_sigreturn_glue
  457.         .long  sys_clone_glue            /* 120 */
  458.         .long  sys_setdomainname
  459.         .long  sys_newuname
  460.         .long  sys_ni_syscall            /* modify_ldt for i386 */
  461.         .long  sys_adjtimex
  462.         .long  sys_mprotect              /* 125 */
  463.         .long  sys_sigprocmask
  464.         .long  sys_create_module
  465.         .long  sys_init_module
  466.         .long  sys_delete_module
  467.         .long  sys_get_kernel_syms       /* 130 */
  468.         .long  sys_quotactl
  469.         .long  sys_getpgid
  470.         .long  sys_fchdir
  471.         .long  sys_bdflush
  472.         .long  sys_sysfs                 /* 135 */
  473.         .long  sys_personality
  474.         .long  sys_ni_syscall            /* for afs_syscall */
  475.         .long  sys_setfsuid16
  476.         .long  sys_setfsgid16
  477.         .long  sys_llseek                /* 140 */
  478.         .long  sys_getdents
  479.         .long  sys_select
  480.         .long  sys_flock
  481.         .long  sys_msync
  482.         .long  sys_readv                 /* 145 */
  483.         .long  sys_writev
  484.         .long  sys_getsid
  485.         .long  sys_fdatasync
  486.         .long  sys_sysctl
  487.         .long  sys_mlock                 /* 150 */
  488.         .long  sys_munlock
  489.         .long  sys_mlockall
  490.         .long  sys_munlockall
  491.         .long  sys_sched_setparam
  492.         .long  sys_sched_getparam        /* 155 */
  493.         .long  sys_sched_setscheduler
  494.         .long  sys_sched_getscheduler
  495.         .long  sys_sched_yield
  496.         .long  sys_sched_get_priority_max
  497.         .long  sys_sched_get_priority_min  /* 160 */
  498.         .long  sys_sched_rr_get_interval
  499.         .long  sys_nanosleep
  500.         .long  sys_mremap
  501.         .long  sys_setresuid16
  502.         .long  sys_getresuid16           /* 165 */
  503.         .long  sys_ni_syscall            /* for vm86 */
  504.         .long  sys_query_module
  505.         .long  sys_poll
  506.         .long  sys_nfsservctl
  507.         .long  sys_setresgid16           /* 170 */
  508.         .long  sys_getresgid16
  509.         .long  sys_prctl
  510.         .long  sys_rt_sigreturn_glue
  511.         .long  sys_rt_sigaction
  512.         .long  sys_rt_sigprocmask        /* 175 */
  513.         .long  sys_rt_sigpending
  514.         .long  sys_rt_sigtimedwait
  515.         .long  sys_rt_sigqueueinfo
  516.         .long  sys_rt_sigsuspend_glue
  517.         .long  sys_pread                 /* 180 */
  518.         .long  sys_pwrite
  519.         .long  sys_chown16
  520.         .long  sys_getcwd
  521.         .long  sys_capget
  522.         .long  sys_capset                /* 185 */
  523.         .long  sys_sigaltstack_glue
  524.         .long  sys_sendfile
  525.         .long  sys_ni_syscall            /* streams1 */
  526.         .long  sys_ni_syscall            /* streams2 */
  527.         .long  sys_vfork_glue            /* 190 */
  528.         .long  sys_getrlimit
  529. .long  sys_mmap2
  530.         .long  sys_truncate64
  531.         .long  sys_ftruncate64
  532.         .long  sys_stat64                /* 195 */
  533.         .long  sys_lstat64
  534.         .long  sys_fstat64
  535. .long  sys_lchown
  536. .long  sys_getuid
  537. .long  sys_getgid  /* 200 */
  538. .long  sys_geteuid
  539. .long  sys_getegid
  540. .long  sys_setreuid
  541. .long  sys_setregid
  542. .long  sys_getgroups             /* 205 */
  543. .long  sys_setgroups
  544. .long  sys_fchown
  545. .long  sys_setresuid
  546. .long  sys_getresuid
  547. .long  sys_setresgid             /* 210 */
  548. .long  sys_getresgid
  549. .long  sys_chown
  550. .long  sys_setuid
  551. .long  sys_setgid
  552. .long  sys_setfsuid              /* 215 */
  553. .long  sys_setfsgid
  554.         .long  sys_pivot_root
  555.         .long  sys_mincore
  556.         .long  sys_madvise
  557. .long  sys_getdents64  /* 220 */
  558.         .long  sys_fcntl64 
  559. .long  sys_ni_syscall
  560. .long  sys_ni_syscall
  561. .long  sys_ni_syscall  /* 224 - reserved for setxattr  */
  562. .long  sys_ni_syscall            /* 225 - reserved for lsetxattr */
  563. .long  sys_ni_syscall  /* 226 - reserved for fsetxattr */
  564. .long  sys_ni_syscall  /* 227 - reserved for getxattr  */
  565. .long  sys_ni_syscall  /* 228 - reserved for lgetxattr */
  566. .long  sys_ni_syscall  /* 229 - reserved for fgetxattr */
  567. .long  sys_ni_syscall  /* 230 - reserved for listxattr */
  568. .long  sys_ni_syscall  /* 231 - reserved for llistxattr */
  569. .long  sys_ni_syscall  /* 232 - reserved for flistxattr */
  570. .long  sys_ni_syscall  /* 233 - reserved for removexattr */
  571. .long  sys_ni_syscall  /* 234 - reserved for lremovexattr */
  572. .long  sys_ni_syscall  /* 235 - reserved for fremovexattr */
  573. .long  sys_gettid
  574. .long  sys_tkill
  575. .rept  255-237
  576. .long  sys_ni_syscall
  577. .endr
  579. /*
  580.  * Program check handler routine
  581.  */
  583.         .globl  pgm_check_handler
  584. pgm_check_handler:
  585. /*
  586.  * First we need to check for a special case:
  587.  * Single stepping an instruction that disables the PER event mask will
  588.  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
  589.  * For a single stepped SVC the program check handler gets control after
  590.  * the SVC new PSW has been loaded. But we want to execute the SVC first and
  591.  * then handle the PER event. Therefore we update the SVC old PSW to point
  592.  * to the pgm_check_handler and branch to the SVC handler after we checked
  593.  * if we have to load the kernel stack register.
  594.  * For every other possible cause for PER event without the PER mask set
  595.  * we just ignore the PER event (FIXME: is there anything we have to do
  596.  * for LPSW?).
  597.  */
  598. SAVE_ALL_BASE
  599.         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
  600.         bnz     BASED(pgm_per)           # got per exception -> special case
  601. SAVE_ALL __LC_PGM_OLD_PSW,1
  602.         l       %r7,BASED(.Ljump_table)
  603.         lh      %r8,__LC_PGM_INT_CODE
  604.         sll     %r8,2
  605. GET_CURRENT
  606.         l       %r7,0(%r8,%r7)  # load address of handler routine
  607.         la      %r2,SP_PTREGS(%r15)  # address of register-save area
  608.         l       %r3,__LC_PGM_ILC         # load program interruption code
  609. la      %r14,BASED(sysc_return)
  610. br      %r7  # branch to interrupt-handler
  612. #
  613. # handle per exception
  614. #
  615. pgm_per:
  616.         tm      __LC_PGM_OLD_PSW,0x40    # test if per event recording is on
  617.         bnz     BASED(pgm_per_std)       # ok, normal per event from user space
  618. # ok its one of the special cases, now we need to find out which one
  619.         clc     __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
  620.         be      BASED(pgm_svcper)
  621. # no interesting special case, ignore PER event
  622.         lm      %r13,%r15,__LC_SAVE_AREA
  623. lpsw    0x28
  625. #
  626. # Normal per exception
  627. #
  628. pgm_per_std:
  629. SAVE_ALL __LC_PGM_OLD_PSW,1
  630. GET_CURRENT
  631. la %r4,0x7f
  632. l %r3,__LC_PGM_ILC  # load program interruption code
  633.         nr      %r4,%r3                  # clear per-event-bit and ilc
  634.         be      BASED(pgm_per_only)      # only per or per+check ?
  635.         l       %r1,BASED(.Ljump_table)
  636.         sll     %r4,2
  637.         l       %r1,0(%r4,%r1)  # load address of handler routine
  638.         la      %r2,SP_PTREGS(%r15)  # address of register-save area
  639. basr    %r14,%r1  # branch to interrupt-handler
  640. pgm_per_only:
  641. la      %r2,SP_PTREGS(15)  # address of register-save area
  642.         l       %r1,BASED(.Lhandle_per)  # load adr. of per handler
  643.         la      %r14,BASED(sysc_return)  # load adr. of system return
  644.         br      %r1  # branch to handle_per_exception
  646. #
  647. # it was a single stepped SVC that is causing all the trouble
  648. #
  649. pgm_svcper:
  650. SAVE_ALL __LC_SVC_OLD_PSW,1
  651.         GET_CURRENT               # load pointer to task_struct to R9
  652. lh %r8,0x8a   # get svc number from lowcore
  653.         sll     %r8,2
  654.         stosm   24(%r15),0x03     # reenable interrupts
  655.         l       %r8,sys_call_table-entry_base(%r8,%r13) # get system call addr.
  656.         tm      __TASK_ptrace+3(%r9),0x02 # PT_TRACESYS
  657.         bnz     BASED(pgm_tracesys)
  658.         basr    %r14,%r8          # call sys_xxxx
  659.         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
  660.                                   # ATTENTION: check sys_execve_glue before
  661.                                   # changing anything here !!
  663. pgm_svcret:
  664.         icm     %r0,15,__TASK_sigpending(%r9)
  665.         bz      BASED(pgm_svcper_nosig)
  666. la %r2,SP_PTREGS(%r15) # load pt_regs
  667. sr %r3,%r3   # clear *oldset
  668. l %r1,BASED(.Ldo_signal)
  669. basr %r4,%r1   # call do_signal
  671. pgm_svcper_nosig:
  672.         mvi     SP_TRAP+3(%r15),0x28     # set trap indication to pgm check
  673. la      %r2,SP_PTREGS(15)        # address of register-save area
  674.         l       %r1,BASED(.Lhandle_per)  # load adr. of per handler
  675.         la      %r14,BASED(sysc_return)  # load adr. of system return
  676.         br      %r1                      # branch to handle_per_exception
  677. #
  678. # call trace before and after sys_call
  679. #
  680. pgm_tracesys:
  681. la %r11,BASED(pgm_svcret)
  682. b BASED(trace_svc)
  684. /*
  685.  * IO interrupt handler routine
  686.  */
  688.         .globl io_int_handler
  689. io_int_handler:
  690. SAVE_ALL_BASE
  691.         SAVE_ALL __LC_IO_OLD_PSW,0
  692.         GET_CURRENT               # load pointer to task_struct to R9
  693.         l       %r1,BASED(.Ldo_IRQ)        # load address of do_IRQ
  694.         la      %r2,SP_PTREGS(%r15) # address of register-save area
  695.         sr      %r3,%r3
  696.         icm     %r3,3,__LC_SUBCHANNEL_NR   # load subchannel nr & extend to int
  697.         l       %r4,__LC_IO_INT_PARM       # load interuption parm
  698. l       %r5,__LC_IO_INT_WORD       # load interuption word
  699.         basr    %r14,%r1          # branch to standard irq handler
  701. io_return:
  702. #
  703. # check, if bottom-half has to be done
  704. #
  705.         l       %r1,__TASK_processor(%r9)
  706.         sll     %r1,L1_CACHE_SHIFT
  707.         al      %r1,BASED(.Lirq_stat) # get address of irq_stat
  708.         icm     %r0,15,0(%r1)         # test irq_stat[#cpu].__softirq_pending
  709.         bnz     BASED(io_handle_bottom_half)
  710. io_return_bh:
  712.         tm      SP_PSW+1(%r15),0x01 # returning to user ?
  713.         bno     BASED(io_leave)   # no-> skip resched & signal
  714.         stosm   24(%r15),0x03     # reenable interrupts
  715. #
  716. # check, if reschedule is needed
  717. #
  718.         icm     %r0,15,__TASK_need_resched(%r9)
  719.         bnz     BASED(io_reschedule)
  720.         icm     %r0,15,__TASK_sigpending(%r9)
  721.         bnz     BASED(io_signal_return)
  722. io_leave:
  723.         stnsm   24(%r15),0xfc            # disable I/O and ext. interrupts
  724.         RESTORE_ALL 0
  726. #
  727. # call do_softirq
  728. #
  729. io_handle_bottom_half:
  730.         l       %r1,BASED(.Ldo_softirq)
  731.         la      %r14,BASED(io_return_bh)
  732.         br      %r1               # call do_softirq
  734. #
  735. # call schedule with io_return as return-address
  736. #
  737. io_reschedule:        
  738.         l       %r1,BASED(.Lschedule)
  739. la      %r14,BASED(io_return)
  740.         br      %r1               # call scheduler, return to io_return
  742. #
  743. # call do_signal before return
  744. #
  745. io_signal_return:     
  746.         la      %r2,SP_PTREGS(%r15) # load pt_regs
  747.         sr      %r3,%r3           # clear *oldset
  748.         l       %r1,BASED(.Ldo_signal)
  749. la      %r14,BASED(io_leave)
  750.         br      %r1               # return point is io_leave
  752. /*
  753.  * External interrupt handler routine
  754.  */
  756.         .globl  ext_int_handler
  757. ext_int_handler:
  758. SAVE_ALL_BASE
  759.         SAVE_ALL __LC_EXT_OLD_PSW,0
  760.         GET_CURRENT                    # load pointer to task_struct to R9
  761. lh %r6,__LC_EXT_INT_CODE  # get interruption code
  762. lr %r1,%r6        # calculate index = code & 0xff
  763. n %r1,BASED(.Lc0xff)
  764. sll %r1,2
  765. l %r7,BASED(.Lext_hash)
  766. l %r7,0(%r1,%r7)        # get first list entry for hash value
  767. ltr %r7,%r7        # == NULL ?
  768. bz BASED(io_return)       # yes, nothing to do, exit
  769. ext_int_loop:
  770. ch %r6,8(%r7)        # compare external interrupt code
  771. bne BASED(ext_int_next)
  772. l %r1,4(%r7)        # get handler address
  773. la %r2,SP_PTREGS(%r15)    # address of register-save area
  774. lr %r3,%r6        # interruption code
  775. basr %r14,%r1        # call handler
  776. ext_int_next:
  777. icm %r7,15,0(%r7)        # next list entry
  778. bnz BASED(ext_int_loop)
  779. b BASED(io_return)
  781. /*
  782.  * Machine check handler routines
  783.  */
  785.         .globl mcck_int_handler
  786. mcck_int_handler:
  787. SAVE_ALL_BASE
  788.         SAVE_ALL __LC_MCK_OLD_PSW,0
  789. l       %r1,BASED(.Ls390_mcck)
  790. basr    %r14,%r1   # call machine check handler
  791. mcck_return:
  792.         RESTORE_ALL 0
  794. #ifdef CONFIG_SMP
  795. /*
  796.  * Restart interruption handler, kick starter for additional CPUs
  797.  */
  798.         .globl restart_int_handler
  799. restart_int_handler:
  800.         l       %r15,__LC_SAVE_AREA+60 # load ksp
  801.         lctl    %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
  802.         lam     %a0,%a15,__LC_AREGS_SAVE_AREA
  803.         stosm   0(%r15),0x04           # now we can turn dat on
  804.         lm      %r6,%r15,24(%r15)      # load registers from clone
  805.         basr    %r14,0
  806.         l       %r14,restart_addr-.(%r14)
  807.         br      %r14                   # branch to start_secondary
  808. restart_addr:
  809.         .long   start_secondary
  810. #else
  811. /*
  812.  * If we do not run with SMP enabled, let the new CPU crash ...
  813.  */
  814.         .globl restart_int_handler
  815. restart_int_handler:
  816.         basr    %r1,0
  817. restart_base:
  818.         lpsw    restart_crash-restart_base(%r1)
  819.         .align 8
  820. restart_crash:
  821.         .long  0x000a0000,0x00000000
  822. restart_go:
  823. #endif
  825. /*
  826.  * Integer constants
  827.  */
  828.                .align 4
  829. .Lc0xfffffff8: .long  -8           # to align stack pointer to 8
  830. .Lc0xffffe000: .long  -8192        # to round stack pointer to &task_struct
  831. .Lc8191:       .long  8191
  832. .Lc_spsize:    .long  SP_SIZE
  833. .Lc_overhead:  .long  STACK_FRAME_OVERHEAD
  834. .Lc_ac:        .long  0,0,1
  835. .Lc_ENOSYS:    .long  -ENOSYS
  836. .Lc4:          .long  4
  837. .Lc20:         .long  20
  838. .Lc0x1202:     .long  0x1202
  839. .Lc0x1004:     .long  0x1004
  840. .Lc0x2401:     .long  0x2401
  841. .Lc0x4000:     .long  0x4000
  842. .Lc0xff:       .long  0xff
  843. .Lc128:        .long  128
  845. /*
  846.  * Symbol constants
  847.  */
  848. .Ls390_mcck:   .long  s390_do_machine_check
  849. .Ldo_IRQ:      .long  do_IRQ
  850. .Ldo_signal:   .long  do_signal
  851. .Ldo_softirq:  .long  do_softirq
  852. .Lentry_base:  .long  entry_base
  853. .Lext_hash:    .long  ext_int_hash
  854. .Lhandle_per:  .long  handle_per_exception
  855. .Lirq_stat:    .long  irq_stat
  856. .Ljump_table:  .long  pgm_check_table
  857. .Lschedule:    .long  schedule
  858. .Lclone:       .long  sys_clone
  859. .Lexecve:      .long  sys_execve
  860. .Lfork:        .long  sys_fork
  861. .Lrt_sigreturn:.long  sys_rt_sigreturn
  862. .Lrt_sigsuspend:
  863.                .long  sys_rt_sigsuspend
  864. .Lsigreturn:   .long  sys_sigreturn
  865. .Lsigsuspend:  .long  sys_sigsuspend
  866. .Lsigaltstack: .long  sys_sigaltstack
  867. .Ltrace:       .long  syscall_trace
  868. .Lvfork:       .long  sys_vfork
  870. .Lschedtail:   .long  schedule_tail