开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 操作系统开发 > 查看源码
exif.asm
资源名称：DOS系统的源代码.rar　[点击查看]
上传用户：xiaoan1112
上传日期：2013-04-11
资源大小：19621k
文件大小：5k
源码类别：

操作系统开发

开发平台：

Visual C++

exif.asm：源码内容
  1. page 49,132
  2. TITLE exif - executors for IF and ELSE, DO/LOOP, and WHILE/WEND varients
  3. ;***
  4. ;exif - executors for IF and ELSE, DO/LOOP, and WHILE/WEND varients
  5. ;
  6. ; Copyright <C> 1986, Microsoft Corporation
  7. ;
  8. ;Purpose:
  9. ; Executors for IF and ELSE varients.
  10. ; Also contains Executors for WHILE/WEND, and DO/LOOP varients
  11. ;
  12. ;****************************************************************************
  14. .xlist
  15. include version.inc
  16. IncludeOnce executor
  17. IncludeOnce exint
  18. IncludeOnce opcontrl
  19. .list
  21. assumes cs, CODE
  22. assumes es, NOTHING
  23. assumes ss, DATA
  25. sBegin CODE
  27. EXTRN SetProgramMode:NEAR
  29. subttl IF
  30. page
  31. ;exStIfR8
  32. ;Purpose:
  33. ; These handle the case of
  34. ;    IF a!
  35. ; and
  36. ;    IF a#
  37. ;
  40. MakeExe exStR8While,opStWhile
  41. SkipExHeader
  42. MakeExe exStLoopR8Until,opStLoopUntil
  43. SkipExHeader
  44. MakeExe exStDoR8While,opStDoWhile
  45. SkipExHeader
  46. MakeExe exStElseIfR8,opStElseIf
  47. SkipExHeader
  48. MakeExe exStIfR8,opStIf
  49. SkipExHeader ;Fall through 
  50. MakeExe exStIfBlockR8,opStIfBlock
  51. ;Re-written with [4]
  52. fldz ;Put zero on stack
  53. fcompp ;Compare with zero and remove operands
  54. fstsw [Stat] ;Save result of comparison
  55. fwait
  56. mov ax,[Stat]
  57. sahf
  58. jz IfFalse
  59. jmp short IfTrue
  60. ;End of [4]
  62. MakeExe exStI4While,opStWhile
  63. SkipExHeader
  64. MakeExe exStLoopI4Until,opStLoopUntil
  65. SkipExHeader
  66. MakeExe exStDoI4While,opStDoWhile
  67. SkipExHeader
  68. MakeExe exStElseIfI4,opStElseIf
  69. SkipExHeader
  70. MakeExe exStIfI4,opStIf
  71. SkipExHeader
  72. MakeExe exStIfBlockI4,opStIfBlock
  73. pop ax
  74. pop dx
  75. AxDxZtest:
  76. or ax,dx ;PSW.Z set = FALSE
  77. jnz IfTrue ;TRUE
  78. IfFalse:
  79. mov si,PTRTX[si] ;Take the false branch
  80. DispMac
  82. MakeExe exStI2While,opStWhile
  83. SkipExHeader
  84. MakeExe exStLoopI2Until,opStLoopUntil
  85. SkipExHeader
  86. MakeExe exStDoI2While,opStDoWhile
  87. SkipExHeader
  88. MakeExe exStElseIfI2,opStElseIf
  89. SkipExHeader
  90. MakeExe exStIfBlockI2,opStIfBlock
  91. SkipExHeader
  92. MakeExe exStIfI2,opStIf
  93. pop cx ;I2 TRUE or FALSE
  94. jcxz IfFalse ;FALSE
  95. IfTrue:
  96. IfLabFalse:
  97. add si,2 ;Skip operand
  98. DispMac
  100. MakeExe exStDoI2Until,opStDoUntil
  101. SkipExHeader
  102. MakeExe exStLoopI2While,opStLoopWhile
  103. SkipExHeader
  104. MakeExe exStIfGotoLabI2,opStIfGotoLab
  105. SkipExHeader ;Fall into next executor
  106. MakeExe exStIfLabI2,opStIfLab
  107. pop cx
  108. jcxz IfLabFalse ;False case - fall through label
  109. IfLabTrue:
  110. mov si,PTRTX[si] ;TRUE - branch to label
  111. DispMac
  113. subttl IfLabDirect
  114. page
  115. ;IfLabDirect
  116. ;Purpose:
  117. ; Handle the case that there is an IfLab in a direct mode statment.
  118. ; This is kept separate from program mode IfLab as it is speed critical.
  119. ;
  120. MakeExe exStIfLabDirectI2,opStIfLabDirect
  121. xor dx,dx
  122. IfLabDirectCom:
  123. pop ax
  124. IfLabDirectIntCom:
  125. or ax,dx
  126. IfLabDirectFlag:
  127. jz IfLabFalse
  128. IfLabDirectTrue:
  129. mov si,PTRTX[si] ;Load start offset
  130. call SetProgramMode
  131. DispMac
  134. MakeExe exStIfLabDirectR8,opStIfLabDirect
  135. ;Re-written with [4]
  136. fldz ;Put zero on stack
  137. fcompp ;Compare with zero and remove operands
  138. fstsw [Stat] ;Save result of comparison
  139. fwait
  140. mov ax,[Stat]
  141. sahf
  142. jmp IfLabDirectFlag
  143. ;End of [4]
  145. MakeExe exStIfLabDirectI4,opStIfLabDirect
  146. pop dx
  147. jmp short IfLabDirectCom
  148. subttl IfLab
  149. page
  151. MakeExe exStDoI4Until,opStDoUntil
  152. SkipExHeader
  153. MakeExe exStLoopI4While,opStLoopWhile
  154. SkipExHeader
  155. MakeExe exStIfGotoLabI4,opStIfGotoLab
  156. SkipExHeader ;Fall into next executor
  157. MakeExe exStIfLabI4,opStIfLab
  158. pop dx
  159. IfLabFalseOrTrue:
  160. pop ax
  161. or ax,dx
  162. IfLabFlag:
  163. jz IfLabFalse ;FALSE - fall through label
  164. jmp short IfLabTrue ;TRUE - branch to label
  167. MakeExe exStDoR8Until,opStDoUntil
  168. SkipExHeader
  169. MakeExe exStLoopR8While,opStLoopWhile
  170. SkipExHeader
  171. MakeExe exStIfGotoLabR8,opStIfGotoLab
  172. SkipExHeader ;Fall into next executor
  173. MakeExe exStIfLabR8,opStIfLab
  174. ;Re-written with [4]
  175. fldz ;Put zero on stack
  176. fcompp ;Compare with zero and remove operands
  177. fstsw [Stat] ;Save result of comparison
  178. fwait
  179. mov ax,[Stat]
  180. sahf
  181. jmp IfLabFlag
  182. ;End of [4]
  184. subttl Else
  185. page
  186. MakeExe exStElseLabDirect,opStElseLabDirect
  187. mov si,PTRTX[si] ;Load start offset
  188. call SetProgramMode ;Set up for execution
  189. SkipExHeader ;Fall into next executor
  190. MakeExe exStDo,opStDo
  191. SkipExHeader
  192. MakeExe exStEndIfBlock,opStEndIfBlock
  193. SkipExHeader ;Fall into next executor
  194. MakeExe exStElseNop,opStElseNop
  195. DispMac ;Speed critical NOP for ElseNop
  197. MakeExe exStWend,opStWend
  198. SkipExHeader
  199. MakeExe exStLoop,opStLoop
  200. SkipExHeader
  201. MakeExe exStElseLab,opStElseLab
  202. SkipExHeader ;Fall into next executor
  203. MakeExe exStElse,opStElse
  204. mov si,PTRTX[si] ;Perform the branch
  205. DispMac ; and on with the show
  207. sEnd CODE
  208. end