交通/航空行业

开发平台：
Visual Basic

frmAcc.frm：源码内容
							VERSION 5.00
Object = "{5E9E78A0-531B-11CF-91F6-C2863C385E30}#1.0#0"; "MSFLXGRD.OCX"
Begin VB.Form frmAcc 
   Caption         =   "车辆事故列表"
   ClientHeight    =   4140
   ClientLeft      =   60
   ClientTop       =   348
   ClientWidth     =   6792
   Icon            =   "frmAcc.frx":0000
   LinkTopic       =   "Form1"
   MDIChild        =   -1  'True
   ScaleHeight     =   4140
   ScaleWidth      =   6792
   WindowState     =   2  'Maximized
   Begin MSFlexGridLib.MSFlexGrid msgList 
      Height          =   3135
      Left            =   240
      TabIndex        =   1
      Top             =   600
      Width           =   6255
      _ExtentX        =   11028
      _ExtentY        =   5525
      _Version        =   393216
      Cols            =   4
      FixedCols       =   3
      AllowUserResizing=   1
   End
   Begin VB.Label lblTitle 
      Caption         =   "事    故    列    表"
      BeginProperty Font 
         Name            =   "宋体"
         Size            =   12
         Charset         =   134
         Weight          =   700
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      ForeColor       =   &H8000000D&
      Height          =   255
      Left            =   240
      TabIndex        =   0
      Top             =   240
      Width           =   3015
   End
End
Attribute VB_Name = "frmAcc"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Public txtSQL As String
Dim mrc As ADODB.Recordset
Dim MsgText As String
Private Sub Form_Load()
    ShowTitle
    ShowData
    flagaEdit = True
    
End Sub
Private Sub Form_Resize()
    If Me.WindowState <> vbMinimized And fMainForm.WindowState <> vbMinimized Then
        '边界处理
        If Me.ScaleHeight < 10 * lblTitle.Height Then
            
            Exit Sub
        End If
        If Me.ScaleWidth < lblTitle.Width + lblTitle.Width / 2 Then
            
            Exit Sub
        End If
        '控制控件的位置
                
        lblTitle.Top = lblTitle.Height
        lblTitle.Left = (Me.Width - lblTitle.Width) / 2
        
        msgList.Top = lblTitle.Top + lblTitle.Height + lblTitle.Height / 2
        msgList.Width = Me.ScaleWidth - 200
        msgList.Left = Me.ScaleLeft + 100
        msgList.Height = Me.ScaleHeight - msgList.Top - 200
    End If
End Sub
Public Sub RecordEdit()
    Dim intCount As Integer
    
    If msgList.Rows > 1 Then
        gintmode = EDIT
        intCount = msgList.Row
        gsSql = " where sgid='" & Trim(msgList.TextMatrix(msgList.Row, 1)) & "' and sgdate=cdate('" & Format(msgList.TextMatrix(msgList.Row, 2), "yyyy-mm-dd") & "') and sgplace='" & Trim(msgList.TextMatrix(msgList.Row, 3)) & "'"
        frmAcc1.Show 1
        ShowData
        Call MovCursor(intCount, msgList)
    Else
        Call RecordAdd
    End If
End Sub
Public Sub FormClose()
    Unload Me
End Sub
'删除记录
Public Sub RecordDelete()
    Dim sSql As String
    Dim intCount As Integer
    
  On Error GoTo myErr
    
    If msgList.Rows > 1 Then
        If MsgBox("真的要删除这条文件记录么？", vbOKCancel + vbExclamation, "警告") = vbOK Then
            intCount = msgList.Row
            sSql = "delete from " & msTableName & " where sgid='" & Trim(msgList.TextMatrix(msgList.Row, 1)) & "' and sgdate='" & Format(msgList.TextMatrix(msgList.Row, 2), "yyyy-mm-dd") & "' and sgplace='" & Trim(msgList.TextMatrix(msgList.Row, 3)) & "'"
            dbHuaxia.Execute sSql, dbSQLPassThrough
            ShowData
            If msgList.Rows > 1 Then
                If intCount = msgList.Rows Then
                    MovCursor msgList.Rows - 1, msgList
                Else
                    MovCursor intCount, msgList
                End If
            End If
        End If
    End If
    
    Exit Sub
    
myErr:
    ShowError
End Sub
Public Sub RecordRefresh()
    '设置msSql
    msSql = msSelect & msTableName & " where sgdate>='" & Format(DateAdd("m", -1, Now), "yyyy-mm-dd") & "' and sgdate<='" & Format(Now, "yyyy-mm-dd") & "'" & msOrderBy
        
    '显示数据
    msBarText = "当前数据时间范围：" & Format(DateAdd("m", -1, Now), "yyyy-mm-dd") & "至" & Format(Now, "yyyy-mm-dd")
    
    ShowData
    '重新设置打印时排序顺序
    sOrder0 = "+ {sgdate}"
    sOrder1 = ""
End Sub
Public Sub RecordAdd()
    gintmode = Add
    frmAcc1.Show 1
    ShowData
End Sub
Public Sub RecordFind()
    frmAcc2.Show 1
    
    If Trim(frmAcc2.sQSql & " ") <> "" Then
        msSql = msSelect & msTableName & " where" & frmAcc2.sQSql
        msSql = msSql & msOrderBy
        
        ShowData
    End If
    Unload frmAcc2
End Sub
Private Sub Form_Unload(Cancel As Integer)
    flagaEdit = False
    gintaMode = 0
End Sub
'详细显示记录
Public Sub RecordView()
    If msgList.Rows > 1 = False Then
        gintmode = View
        gsSql = " where sgid='" & Trim(msgList.TextMatrix(msgList.Row, 1)) & "' and sgdate=cdate('" & Format(msgList.TextMatrix(msgList.Row, 2), "yyyy-mm-dd") & "') and sgplace='" & Trim(msgList.TextMatrix(msgList.Row, 3)) & "'"
        frmAcc1.Show 1
    End If
End Sub
'显示Grid的内容
Private Sub ShowData()
    
    Dim j As Integer
    Dim i As Integer
  
  
    Set mrc = ExecuteSQL(txtSQL, MsgText)
        With msgList
        .Rows = 1
        
        Do While Not mrc.EOF
            .Rows = .Rows + 1
            For i = 1 To mrc.Fields.Count
                Select Case mrc.Fields(i - 1).Type
                    Case adDBDate
                        .TextMatrix(.Rows - 1, i) = Format(mrc.Fields(i - 1) & "", "yyyy-mm-dd")
                    Case Else
                        .TextMatrix(.Rows - 1, i) = mrc.Fields(i - 1) & ""
                End Select
            Next i
            mrc.MoveNext
        Loop
    End With
    mrc.Close
End Sub
'显示Grid表头
Private Sub ShowTitle()
    Dim i As Integer
    
    With msgList
        .Cols = 11
        .TextMatrix(0, 1) = "车号"
        .TextMatrix(0, 2) = "时间"
        .TextMatrix(0, 3) = "地点"
        .TextMatrix(0, 4) = "原因"
        .TextMatrix(0, 5) = "司机"
        .TextMatrix(0, 6) = "对方单位"
        .TextMatrix(0, 7) = "对方车号"
        .TextMatrix(0, 8) = "处理方式"
        .TextMatrix(0, 9) = "处理金额"
        .TextMatrix(0, 10) = "备注"
        
        
        '固定表头
        .FixedRows = 1
                
        '设置各列的对齐方式
        For i = 0 To 8
            .ColAlignment(i) = 0
        Next i
        .ColAlignment(9) = 7
        .ColAlignment(10) = 0
        
        '表头项居中
        .FillStyle = flexFillRepeat
        .Col = 0
        .Row = 0
        .RowSel = 1
        .ColSel = .Cols - 1
        .CellAlignment = 4
        
        '设置单元大小
        .ColWidth(0) = 300
        .ColWidth(1) = 1000
        .ColWidth(2) = 1000
        .ColWidth(3) = 3000
        .ColWidth(4) = 3000
        .ColWidth(5) = 1000
        .ColWidth(6) = 3000
        .ColWidth(7) = 1000
        .ColWidth(8) = 3000
        .ColWidth(9) = 1000
        .ColWidth(10) = 1000
        .Row = 1
        
    End With
End Sub
Private Sub msgList_MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
    '右键弹出
    If Button = 2 And Shift = 0 Then
        PopupMenu fMainForm.menuAccident
    End If
    
End Sub

						