开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 数据库系统 > MySQL数据库 > 查看源码
acinclude.m4
资源名称：mysql-3.23.35.tar.gz　[点击查看]
上传用户：tsgydb
上传日期：2007-04-14
资源大小：10674k
文件大小：30k
源码类别：

MySQL数据库

开发平台：

Visual C++

acinclude.m4：源码内容
  1. # Local macros for automake & autoconf
  3. # A local version of AC_CHECK_SIZEOF that includes sys/types.h
  4. dnl MYSQL_CHECK_SIZEOF(TYPE [, CROSS-SIZE])
  5. AC_DEFUN(MYSQL_CHECK_SIZEOF,
  6. [changequote(<<, >>)dnl
  7. dnl The name to #define.
  8. define(<<AC_TYPE_NAME>>, translit(sizeof_$1, [a-z *], [A-Z_P]))dnl
  9. dnl The cache variable name.
  10. define(<<AC_CV_NAME>>, translit(ac_cv_sizeof_$1, [ *], [_p]))dnl
  11. changequote([, ])dnl
  12. AC_MSG_CHECKING(size of $1)
  13. AC_CACHE_VAL(AC_CV_NAME,
  14. [AC_TRY_RUN([#include <stdio.h>
  15. #include <sys/types.h>
  16. #if STDC_HEADERS
  17. #include <stdlib.h>
  18. #include <stddef.h>
  19. #endif
  20. main()
  21. {
  22.   FILE *f=fopen("conftestval", "w");
  23.   if (!f) exit(1);
  24.   fprintf(f, "%dn", sizeof($1));
  25.   exit(0);
  26. }], AC_CV_NAME=`cat conftestval`, AC_CV_NAME=0, ifelse([$2], , , AC_CV_NAME=$2))])dnl
  27. AC_MSG_RESULT($AC_CV_NAME)
  28. AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME)
  29. undefine([AC_TYPE_NAME])dnl
  30. undefine([AC_CV_NAME])dnl
  31. ])
  33. #---START: Used in for client configure
  34. AC_DEFUN(MYSQL_TYPE_ACCEPT,
  35. [ac_save_CXXFLAGS="$CXXFLAGS"
  36. AC_CACHE_CHECK([base type of last arg to accept], mysql_cv_btype_last_arg_accept,
  37. AC_LANG_SAVE
  38. AC_LANG_CPLUSPLUS
  39. if test "$ac_cv_prog_gxx" = "yes"
  40. then
  41.   CXXFLAGS="$CXXFLAGS -Werror"
  42. fi
  43. mysql_cv_btype_last_arg_accept=none
  44. [AC_TRY_COMPILE([#if defined(inline)
  45. #undef inline
  46. #endif
  47. #include <stdlib.h>
  48. #include <sys/types.h>
  49. #include <sys/socket.h>
  50. ],
  51. [int a = accept(1, (struct sockaddr *) 0, (socklen_t *) 0); return (a != 0);],
  52. mysql_cv_btype_last_arg_accept=socklen_t)]
  53. if test $mysql_cv_btype_last_arg_accept = none; then
  54. [AC_TRY_COMPILE([#if defined(inline)
  55. #undef inline
  56. #endif
  57. #include <stdlib.h>
  58. #include <sys/types.h>
  59. #include <sys/socket.h>
  60. ],
  61. [int a = accept(1, (struct sockaddr *) 0, (size_t *) 0); return (a != 0);],
  62. mysql_cv_btype_last_arg_accept=size_t)]
  63. fi
  64. if test $mysql_cv_btype_last_arg_accept = none; then
  65. mysql_cv_btype_last_arg_accept=int
  66. fi)
  67. AC_LANG_RESTORE
  68. AC_DEFINE_UNQUOTED(SOCKET_SIZE_TYPE, $mysql_cv_btype_last_arg_accept)
  69. CXXFLAGS="$ac_save_CXXFLAGS"
  70. ])
  71. #---END:
  73. dnl Find type of qsort
  74. AC_DEFUN(MYSQL_TYPE_QSORT,
  75. [AC_CACHE_CHECK([return type of qsort], mysql_cv_type_qsort,
  76. [AC_TRY_COMPILE([#include <stdlib.h>
  77. #ifdef __cplusplus
  78. extern "C"
  79. #endif
  80. void qsort(void *base, size_t nel, size_t width,
  81.  int (*compar) (const void *, const void *));
  82. ],
  83. [int i;], mysql_cv_type_qsort=void, mysql_cv_type_qsort=int)])
  84. AC_DEFINE_UNQUOTED(RETQSORTTYPE, $mysql_cv_type_qsort)
  85. if test "$mysql_cv_type_qsort" = "void"
  86. then
  87.  AC_DEFINE_UNQUOTED(QSORT_TYPE_IS_VOID, 1)
  88. fi
  89. ])
  91. AC_DEFUN(MYSQL_TIMESPEC_TS,
  92. [AC_CACHE_CHECK([if struct timespec has a ts_sec member], mysql_cv_timespec_ts,
  93. [AC_TRY_COMPILE([#include <pthread.h>
  94. #ifdef __cplusplus
  95. extern "C"
  96. #endif
  97. ],
  98. [struct timespec abstime;
  100. abstime.ts_sec = time(NULL)+1;
  101. abstime.ts_nsec = 0;
  102. ], mysql_cv_timespec_ts=yes, mysql_cv_timespec_ts=no)])
  103. if test "$mysql_cv_timespec_ts" = "yes"
  104. then
  105.   AC_DEFINE(HAVE_TIMESPEC_TS_SEC)
  106. fi
  107. ])
  109. AC_DEFUN(MYSQL_TZNAME,
  110. [AC_CACHE_CHECK([if we have tzname variable], mysql_cv_tzname,
  111. [AC_TRY_COMPILE([#include <time.h>
  112. #ifdef __cplusplus
  113. extern "C"
  114. #endif
  115. ],
  116. [ tzset();
  117.   return tzname[0] != 0;
  118. ], mysql_cv_tzname=yes, mysql_cv_tzname=no)])
  119. if test "$mysql_cv_tzname" = "yes"
  120. then
  121.   AC_DEFINE(HAVE_TZNAME)
  122. fi
  123. ])
  125. AC_DEFUN(MYSQL_CHECK_ZLIB_WITH_COMPRESS, [
  126. save_LIBS="$LIBS"
  127. LIBS="-l$1 $LIBS"
  128. AC_CACHE_CHECK([if libz with compress], mysql_cv_compress,
  129. [AC_TRY_LINK([#include <zlib.h>
  130. #ifdef __cplusplus
  131. extern "C"
  132. #endif
  133. ],
  134. [ return compress(0, (unsigned long*) 0, "", 0);
  135. ], mysql_cv_compress=yes, mysql_cv_compress=no)])
  136. if test "$mysql_cv_compress" = "yes"
  137. then
  138.   AC_DEFINE(HAVE_COMPRESS)
  139. else
  140.   LIBS="$save_LIBS"
  141. fi
  142. ])
  144. #---START: Used in for client configure
  145. AC_DEFUN(MYSQL_CHECK_ULONG,
  146. [AC_MSG_CHECKING(for type ulong)
  147. AC_CACHE_VAL(ac_cv_ulong,
  148. [AC_TRY_RUN([#include <stdio.h>
  149. #include <sys/types.h>
  150. main()
  151. {
  152.   ulong foo;
  153.   foo++;
  154.   exit(0);
  155. }], ac_cv_ulong=yes, ac_cv_ulong=no, ac_cv_ulong=no)])
  156. AC_MSG_RESULT($ac_cv_ulong)
  157. if test "$ac_cv_ulong" = "yes"
  158. then
  159.   AC_DEFINE(HAVE_ULONG)
  160. fi
  161. ])
  163. AC_DEFUN(MYSQL_CHECK_UCHAR,
  164. [AC_MSG_CHECKING(for type uchar)
  165. AC_CACHE_VAL(ac_cv_uchar,
  166. [AC_TRY_RUN([#include <stdio.h>
  167. #include <sys/types.h>
  168. main()
  169. {
  170.   uchar foo;
  171.   foo++;
  172.   exit(0);
  173. }], ac_cv_uchar=yes, ac_cv_uchar=no, ac_cv_uchar=no)])
  174. AC_MSG_RESULT($ac_cv_uchar)
  175. if test "$ac_cv_uchar" = "yes"
  176. then
  177.   AC_DEFINE(HAVE_UCHAR)
  178. fi
  179. ])
  181. AC_DEFUN(MYSQL_CHECK_UINT,
  182. [AC_MSG_CHECKING(for type uint)
  183. AC_CACHE_VAL(ac_cv_uint,
  184. [AC_TRY_RUN([#include <stdio.h>
  185. #include <sys/types.h>
  186. main()
  187. {
  188.   uint foo;
  189.   foo++;
  190.   exit(0);
  191. }], ac_cv_uint=yes, ac_cv_uint=no, ac_cv_uint=no)])
  192. AC_MSG_RESULT($ac_cv_uint)
  193. if test "$ac_cv_uint" = "yes"
  194. then
  195.   AC_DEFINE(HAVE_UINT)
  196. fi
  197. ])
  199. #---END:
  201. AC_DEFUN(MYSQL_CHECK_FP_EXCEPT,
  202. [AC_MSG_CHECKING(for type fp_except)
  203. AC_CACHE_VAL(ac_cv_fp_except,
  204. [AC_TRY_RUN([#include <stdio.h>
  205. #include <sys/types.h>
  206. #include <ieeefp.h>
  207. main()
  208. {
  209.   fp_except foo;
  210.   foo++;
  211.   exit(0);
  212. }], ac_cv_fp_except=yes, ac_cv_fp_except=no, ac_cv_fp_except=no)])
  213. AC_MSG_RESULT($ac_cv_fp_except)
  214. if test "$ac_cv_fp_except" = "yes"
  215. then
  216.   AC_DEFINE(HAVE_FP_EXCEPT)
  217. fi
  218. ])
  220. # From fileutils-3.14/aclocal.m4
  222. # @defmac AC_PROG_CC_STDC
  223. # @maindex PROG_CC_STDC
  224. # @ovindex CC
  225. # If the C compiler in not in ANSI C mode by default, try to add an option
  226. # to output variable @code{CC} to make it so.  This macro tries various
  227. # options that select ANSI C on some system or another.  It considers the
  228. # compiler to be in ANSI C mode if it defines @code{__STDC__} to 1 and
  229. # handles function prototypes correctly.
  230. #
  231. # Patched by monty to only check if __STDC__ is defined. With the original 
  232. # check it's impossible to get things to work with the Sunpro compiler from
  233. # Workshop 4.2
  234. #
  235. # If you use this macro, you should check after calling it whether the C
  236. # compiler has been set to accept ANSI C; if not, the shell variable
  237. # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
  238. # code in ANSI C, you can make an un-ANSIfied copy of it by using the
  239. # program @code{ansi2knr}, which comes with Ghostscript.
  240. # @end defmac
  242. AC_DEFUN(AM_PROG_CC_STDC,
  243. [AC_REQUIRE([AC_PROG_CC])
  244. AC_MSG_CHECKING(for ${CC-cc} option to accept ANSI C)
  245. AC_CACHE_VAL(am_cv_prog_cc_stdc,
  246. [am_cv_prog_cc_stdc=no
  247. ac_save_CC="$CC"
  248. # Don't try gcc -ansi; that turns off useful extensions and
  249. # breaks some systems' header files.
  250. # AIX -qlanglvl=ansi
  251. # Ultrix and OSF/1 -std1
  252. # HP-UX -Aa -D_HPUX_SOURCE
  253. # SVR4 -Xc -D__EXTENSIONS__
  254. # removed "-Xc -D__EXTENSIONS__" beacause sun c++ does not like it.
  255. for ac_arg in "" -qlanglvl=ansi -std1 "-Aa -D_HPUX_SOURCE" 
  256. do
  257.   CC="$ac_save_CC $ac_arg"
  258.   AC_TRY_COMPILE(
  259. [#if !defined(__STDC__)
  260. choke me
  261. #endif
  262. /* DYNIX/ptx V4.1.3 can't compile sys/stat.h with -Xc -D__EXTENSIONS__. */
  263. #ifdef _SEQUENT_
  264. # include <sys/types.h>
  265. # include <sys/stat.h>
  266. #endif
  267. ], [
  268. int test (int i, double x);
  269. struct s1 {int (*f) (int a);};
  270. struct s2 {int (*f) (double a);};],
  271. [am_cv_prog_cc_stdc="$ac_arg"; break])
  272. done
  273. CC="$ac_save_CC"
  274. ])
  275. AC_MSG_RESULT($am_cv_prog_cc_stdc)
  276. case "x$am_cv_prog_cc_stdc" in
  277.   x|xno) ;;
  278.   *) CC="$CC $am_cv_prog_cc_stdc" ;;
  279. esac
  280. ])
  282. # serial 1
  284. AC_DEFUN(AM_PROG_INSTALL,
  285. [AC_REQUIRE([AC_PROG_INSTALL])
  286. test -z "$INSTALL_SCRIPT" && INSTALL_SCRIPT='${INSTALL_PROGRAM}'
  287. AC_SUBST(INSTALL_SCRIPT)dnl
  288. ])
  290. #
  291. # Check to make sure that the build environment is sane.
  292. #
  294. AC_DEFUN(AM_SANITY_CHECK,
  295. [AC_MSG_CHECKING([whether build environment is sane])
  296. sleep 1
  297. echo timestamp > conftestfile
  298. # Do this in a subshell so we don't clobber the current shell's
  299. # arguments.  FIXME: maybe try `-L' hack like GETLOADAVG test?
  300. if (set X `ls -t $srcdir/configure conftestfile`; test "[$]2" = conftestfile)
  301. then
  302.    # Ok.
  303.    :
  304. else
  305.    AC_MSG_ERROR([newly created file is older than distributed files!
  306. Check your system clock])
  307. fi
  308. rm -f conftest*
  309. AC_MSG_RESULT(yes)])
  311. # Orginal from bash-2.0 aclocal.m4, Changed to use termcap last by monty.
  312.  
  313. AC_DEFUN(MYSQL_CHECK_LIB_TERMCAP,
  314. [
  315. AC_CACHE_VAL(mysql_cv_termcap_lib,
  316. [AC_CHECK_LIB(ncurses, tgetent, mysql_cv_termcap_lib=libncurses,
  317.     [AC_CHECK_LIB(curses, tgetent, mysql_cv_termcap_lib=libcurses,
  318. [AC_CHECK_LIB(termcap, tgetent, mysql_cv_termcap_lib=libtermcap,
  319.     mysql_cv_termcap_lib=NOT_FOUND)])])])
  320. AC_MSG_CHECKING(for termcap functions library)
  321. if test $mysql_cv_termcap_lib = NOT_FOUND; then
  322. AC_MSG_ERROR([No curses/termcap library found])
  323. elif test $mysql_cv_termcap_lib = libtermcap; then
  324. TERMCAP_LIB=-ltermcap
  325. elif test $mysql_cv_termcap_lib = libncurses; then
  326. TERMCAP_LIB=-lncurses
  327. else
  328. TERMCAP_LIB=-lcurses
  329. fi
  330. AC_MSG_RESULT($TERMCAP_LIB)
  331. ])
  333. dnl Check type of signal routines (posix, 4.2bsd, 4.1bsd or v7)
  334. AC_DEFUN(MYSQL_SIGNAL_CHECK,
  335. [AC_REQUIRE([AC_TYPE_SIGNAL])
  336. AC_MSG_CHECKING(for type of signal functions)
  337. AC_CACHE_VAL(mysql_cv_signal_vintage,
  338. [
  339.   AC_TRY_LINK([#include <signal.h>],[
  340.     sigset_t ss;
  341.     struct sigaction sa;
  342.     sigemptyset(&ss); sigsuspend(&ss);
  343.     sigaction(SIGINT, &sa, (struct sigaction *) 0);
  344.     sigprocmask(SIG_BLOCK, &ss, (sigset_t *) 0);
  345.   ], mysql_cv_signal_vintage=posix,
  346.   [
  347.     AC_TRY_LINK([#include <signal.h>], [
  348. int mask = sigmask(SIGINT);
  349. sigsetmask(mask); sigblock(mask); sigpause(mask);
  350.     ], mysql_cv_signal_vintage=4.2bsd,
  351.     [
  352.       AC_TRY_LINK([
  353. #include <signal.h>
  354. RETSIGTYPE foo() { }], [
  355. int mask = sigmask(SIGINT);
  356. sigset(SIGINT, foo); sigrelse(SIGINT);
  357. sighold(SIGINT); sigpause(SIGINT);
  358.         ], mysql_cv_signal_vintage=svr3, mysql_cv_signal_vintage=v7
  359.     )]
  360.   )]
  361. )
  362. ])
  363. AC_MSG_RESULT($mysql_cv_signal_vintage)
  364. if test "$mysql_cv_signal_vintage" = posix; then
  365. AC_DEFINE(HAVE_POSIX_SIGNALS)
  366. elif test "$mysql_cv_signal_vintage" = "4.2bsd"; then
  367. AC_DEFINE(HAVE_BSD_SIGNALS)
  368. elif test "$mysql_cv_signal_vintage" = svr3; then
  369. AC_DEFINE(HAVE_USG_SIGHOLD)
  370. fi
  371. ])
  373. AC_DEFUN(MYSQL_CHECK_GETPW_FUNCS,
  374. [AC_MSG_CHECKING(whether programs are able to redeclare getpw functions)
  375. AC_CACHE_VAL(mysql_cv_can_redecl_getpw,
  376. [AC_TRY_COMPILE([#include <sys/types.h>
  377. #include <pwd.h>
  378. extern struct passwd *getpwent();], [struct passwd *z; z = getpwent();],
  379.   mysql_cv_can_redecl_getpw=yes,mysql_cv_can_redecl_getpw=no)])
  380. AC_MSG_RESULT($mysql_cv_can_redecl_getpw)
  381. if test $mysql_cv_can_redecl_getpw = no; then
  382. AC_DEFINE(HAVE_GETPW_DECLS)
  383. fi
  384. ])
  386. AC_DEFUN(MYSQL_HAVE_TIOCGWINSZ,
  387. [AC_MSG_CHECKING(for TIOCGWINSZ in sys/ioctl.h)
  388. AC_CACHE_VAL(mysql_cv_tiocgwinsz_in_ioctl,
  389. [AC_TRY_COMPILE([#include <sys/types.h>
  390. #include <sys/ioctl.h>], [int x = TIOCGWINSZ;],
  391.   mysql_cv_tiocgwinsz_in_ioctl=yes,mysql_cv_tiocgwinsz_in_ioctl=no)])
  392. AC_MSG_RESULT($mysql_cv_tiocgwinsz_in_ioctl)
  393. if test $mysql_cv_tiocgwinsz_in_ioctl = yes; then   
  394. AC_DEFINE(GWINSZ_IN_SYS_IOCTL)
  395. fi
  396. ])
  398. AC_DEFUN(MYSQL_HAVE_FIONREAD,
  399. [AC_MSG_CHECKING(for FIONREAD in sys/ioctl.h)
  400. AC_CACHE_VAL(mysql_cv_fionread_in_ioctl,
  401. [AC_TRY_COMPILE([#include <sys/types.h>
  402. #include <sys/ioctl.h>], [int x = FIONREAD;],
  403.   mysql_cv_fionread_in_ioctl=yes,mysql_cv_fionread_in_ioctl=no)])
  404. AC_MSG_RESULT($mysql_cv_fionread_in_ioctl)
  405. if test $mysql_cv_fionread_in_ioctl = yes; then   
  406. AC_DEFINE(FIONREAD_IN_SYS_IOCTL)
  407. fi
  408. ])
  410. AC_DEFUN(MYSQL_HAVE_TIOCSTAT,
  411. [AC_MSG_CHECKING(for TIOCSTAT in sys/ioctl.h)
  412. AC_CACHE_VAL(mysql_cv_tiocstat_in_ioctl,
  413. [AC_TRY_COMPILE([#include <sys/types.h>
  414. #include <sys/ioctl.h>], [int x = TIOCSTAT;],
  415.   mysql_cv_tiocstat_in_ioctl=yes,mysql_cv_tiocstat_in_ioctl=no)])
  416. AC_MSG_RESULT($mysql_cv_tiocstat_in_ioctl)
  417. if test $mysql_cv_tiocstat_in_ioctl = yes; then   
  418. AC_DEFINE(TIOCSTAT_IN_SYS_IOCTL)
  419. fi
  420. ])
  422. AC_DEFUN(MYSQL_STRUCT_DIRENT_D_INO,
  423. [AC_REQUIRE([AC_HEADER_DIRENT])
  424. AC_MSG_CHECKING(if struct dirent has a d_ino member)
  425. AC_CACHE_VAL(mysql_cv_dirent_has_dino,
  426. [AC_TRY_COMPILE([
  427. #include <stdio.h>
  428. #include <sys/types.h>
  429. #ifdef HAVE_UNISTD_H
  430. # include <unistd.h>
  431. #endif /* HAVE_UNISTD_H */
  432. #if defined(HAVE_DIRENT_H)
  433. # include <dirent.h>
  434. #else
  435. # define dirent direct
  436. # ifdef HAVE_SYS_NDIR_H
  437. #  include <sys/ndir.h>
  438. # endif /* SYSNDIR */
  439. # ifdef HAVE_SYS_DIR_H
  440. #  include <sys/dir.h>
  441. # endif /* SYSDIR */
  442. # ifdef HAVE_NDIR_H
  443. #  include <ndir.h>
  444. # endif
  445. #endif /* HAVE_DIRENT_H */
  446. ],[
  447. struct dirent d; int z; z = d.d_ino;
  448. ], mysql_cv_dirent_has_dino=yes, mysql_cv_dirent_has_dino=no)])
  449. AC_MSG_RESULT($mysql_cv_dirent_has_dino)
  450. if test $mysql_cv_dirent_has_dino = yes; then
  451. AC_DEFINE(STRUCT_DIRENT_HAS_D_INO)
  452. fi
  453. ])
  455. AC_DEFUN(MYSQL_TYPE_SIGHANDLER,
  456. [AC_MSG_CHECKING([whether signal handlers are of type void])
  457. AC_CACHE_VAL(mysql_cv_void_sighandler,
  458. [AC_TRY_COMPILE([#include <sys/types.h>
  459. #include <signal.h>
  460. #ifdef signal
  461. #undef signal
  462. #endif
  463. #ifdef __cplusplus
  464. extern "C"
  465. #endif
  466. void (*signal ()) ();],
  467. [int i;], mysql_cv_void_sighandler=yes, mysql_cv_void_sighandler=no)])dnl
  468. AC_MSG_RESULT($mysql_cv_void_sighandler)
  469. if test $mysql_cv_void_sighandler = yes; then
  470. AC_DEFINE(VOID_SIGHANDLER)
  471. fi
  472. ])
  474. AC_DEFUN(MYSQL_CXX_BOOL,
  475. [
  476. AC_REQUIRE([AC_PROG_CXX])
  477. AC_MSG_CHECKING(if ${CXX} supports bool types)
  478. AC_CACHE_VAL(mysql_cv_have_bool,
  479. [
  480. AC_LANG_SAVE
  481. AC_LANG_CPLUSPLUS
  482. AC_TRY_COMPILE(,[bool b = true;],
  483. mysql_cv_have_bool=yes,
  484. mysql_cv_have_bool=no)
  485. AC_LANG_RESTORE
  486. ])
  487. AC_MSG_RESULT($mysql_cv_have_bool)
  488. if test "$mysql_cv_have_bool" = yes; then
  489. AC_DEFINE(HAVE_BOOL)
  490. fi
  491. ])dnl
  493. AC_DEFUN(MYSQL_STACK_DIRECTION,
  494.  AC_CACHE_CHECK(stack direction for C alloca, ac_cv_c_stack_direction,
  495.  [AC_TRY_RUN([find_stack_direction ()
  496.  {
  497.    static char *addr = 0;
  498.    auto char dummy;
  499.    if (addr == 0)
  500.      {
  501.        addr = &dummy;
  502.        return find_stack_direction ();
  503.      }
  504.    else
  505.      return (&dummy > addr) ? 1 : -1;
  506.  }
  507.  main ()
  508.  {
  509.    exit (find_stack_direction() < 0);
  510.  }], ac_cv_c_stack_direction=1, ac_cv_c_stack_direction=-1,
  511.    ac_cv_c_stack_direction=0)])
  512.  AC_DEFINE_UNQUOTED(STACK_DIRECTION, $ac_cv_c_stack_direction)
  513. )dnl
  515. AC_DEFUN(MYSQL_FUNC_ALLOCA,
  516. [
  517. # Since we have heard that alloca fails on IRIX never define it on a SGI machine
  518. if test ! "$host_vendor" = "sgi"
  519. then
  520.  AC_REQUIRE_CPP()dnl Set CPP; we run AC_EGREP_CPP conditionally.
  521.  # The Ultrix 4.2 mips builtin alloca declared by alloca.h only works
  522.  # for constant arguments.  Useless!
  523.  AC_CACHE_CHECK([for working alloca.h], ac_cv_header_alloca_h,
  524.  [AC_TRY_LINK([#include <alloca.h>], [char *p = alloca(2 * sizeof(int));],
  525.    ac_cv_header_alloca_h=yes, ac_cv_header_alloca_h=no)])
  526.  if test $ac_cv_header_alloca_h = yes
  527.  then
  528. AC_DEFINE(HAVE_ALLOCA)
  529.  fi
  530.  
  531.  AC_CACHE_CHECK([for alloca], ac_cv_func_alloca_works,
  532.  [AC_TRY_LINK([
  533.  #ifdef __GNUC__
  534.  # define alloca __builtin_alloca
  535.  #else
  536.  # if HAVE_ALLOCA_H
  537.  #  include <alloca.h>
  538.  # else
  539.  #  ifdef _AIX
  540.   #pragma alloca
  541.  #  else
  542.  #   ifndef alloca /* predefined by HP cc +Olibcalls */
  543.  char *alloca ();
  544.  #   endif
  545.  #  endif
  546.  # endif
  547.  #endif
  548.  ], [char *p = (char *) alloca(1);],
  549.    ac_cv_func_alloca_works=yes, ac_cv_func_alloca_works=no)])
  550.  if test $ac_cv_func_alloca_works = yes; then
  551.    AC_DEFINE(HAVE_ALLOCA)
  552.  fi
  553.  
  554.  if test $ac_cv_func_alloca_works = no; then
  555.    # The SVR3 libPW and SVR4 libucb both contain incompatible functions
  556.    # that cause trouble.  Some versions do not even contain alloca or
  557.    # contain a buggy version.  If you still want to use their alloca,
  558.    # use ar to extract alloca.o from them instead of compiling alloca.c.
  559.    ALLOCA=alloca.o
  560.    AC_DEFINE(C_ALLOCA)
  561.  
  562.  AC_CACHE_CHECK(whether alloca needs Cray hooks, ac_cv_os_cray,
  563.  [AC_EGREP_CPP(webecray,
  564.  [#if defined(CRAY) && ! defined(CRAY2)
  565.  webecray
  566.  #else
  567.  wenotbecray
  568.  #endif
  569.  ], ac_cv_os_cray=yes, ac_cv_os_cray=no)])
  570.  if test $ac_cv_os_cray = yes; then
  571.  for ac_func in _getb67 GETB67 getb67; do
  572.    AC_CHECK_FUNC($ac_func, [AC_DEFINE_UNQUOTED(CRAY_STACKSEG_END, $ac_func)
  573.    break])
  574.  done
  575.  fi
  576.  fi
  577.  AC_SUBST(ALLOCA)dnl
  578. else
  579.  AC_MSG_RESULT("Skipped alloca tests")
  580. fi
  581. ])
  583. AC_DEFUN(MYSQL_CHECK_LONGLONG_TO_FLOAT,
  584. [
  585. AC_MSG_CHECKING(if conversion of longlong to float works)
  586. AC_CACHE_VAL(ac_cv_conv_longlong_to_float,
  587. [AC_TRY_RUN([#include <stdio.h>
  588. typedef long long longlong;
  589. main()
  590. {
  591.   longlong ll=1;
  592.   float f;
  593.   FILE *file=fopen("conftestval", "w");
  594.   f = (float) ll;
  595.   fprintf(file,"%gn",f);
  596.   close(file);
  597.   exit (0);
  598. }], ac_cv_conv_longlong_to_float=`cat conftestval`, ac_cv_conv_longlong_to_float=0, ifelse([$2], , , ac_cv_conv_longlong_to_float=$2))])dnl
  599. if test "$ac_cv_conv_longlong_to_float" = "1" -o "$ac_cv_conv_longlong_to_float" = "yes"
  600. then
  601.   ac_cv_conv_longlong_to_float=yes
  602. else
  603.   ac_cv_conv_longlong_to_float=no
  604. fi
  605. AC_MSG_RESULT($ac_cv_conv_longlong_to_float)
  606. ])
  608. dnl ---------------------------------------------------------------------------
  609. dnl Macro: MYSQL_CHECK_BDB
  610. dnl Sets HAVE_BERKELEY_DB if inst library is found
  611. dnl Makes sure db version is correct.
  612. dnl Looks in $srcdir for Berkeley distribution if not told otherwise
  613. dnl ---------------------------------------------------------------------------
  615. AC_DEFUN([MYSQL_CHECK_BDB], [
  616.   AC_ARG_WITH([berkeley-db],
  617.               [
  618.   --with-berkeley-db[=DIR]
  619.                           Use BerkeleyDB located in DIR],
  620.               [bdb="$withval"],
  621.               [bdb=no])
  623.   AC_ARG_WITH([berkeley-db-includes],
  624.               [
  625.   --with-berkeley-db-includes=DIR
  626.                           Find Berkeley DB headers in DIR],
  627.               [bdb_includes="$withval"],
  628.               [bdb_includes=default])
  630.   AC_ARG_WITH([berkeley-db-libs],
  631.               [
  632.   --with-berkeley-db-libs=DIR
  633.                           Find Berkeley DB libraries in DIR],
  634.               [bdb_libs="$withval"],
  635.               [bdb_libs=default])
  637.   AC_MSG_CHECKING([for BerkeleyDB])
  639. dnl     SORT OUT THE SUPPLIED ARGUMENTS TO DETERMINE WHAT TO DO
  640. dnl echo "DBG1: bdb='$bdb'; incl='$bdb_includes'; lib='$bdb_libs'"
  641.   have_berkeley_db=no
  642.   case "$bdb" in
  643.     no )
  644.       mode=no
  645.       AC_MSG_RESULT([no])
  646.       ;;
  647.     yes | default )
  648.       case "$bdb_includes---$bdb_libs" in
  649.         default---default )
  650.           mode=search-$bdb
  651.           AC_MSG_RESULT([searching...])
  652.           ;;
  653.         default---* | *---default | yes---* | *---yes )
  654.           AC_MSG_ERROR([if either 'includes' or 'libs' is specified, both must be specified])
  655.           ;;
  656.         * )
  657.           mode=supplied-two
  658.           AC_MSG_RESULT([supplied])
  659.           ;;
  660.       esac
  661.       ;;
  662.     * )
  663.       mode=supplied-one
  664.       AC_MSG_RESULT([supplied])
  665.       ;;
  666.   esac
  668. dnl echo "DBG2: [$mode] bdb='$bdb'; incl='$bdb_includes'; lib='$bdb_libs'"
  670.   case $mode in
  671.     no )
  672.       bdb_includes=
  673.       bdb_libs=
  674.       ;;
  675.     supplied-two )
  676.       MYSQL_CHECK_INSTALLED_BDB([$bdb_includes], [$bdb_libs])
  677.       case $bdb_dir_ok in
  678.         installed ) mode=yes ;;
  679.         * ) AC_MSG_ERROR([didn't find valid BerkeleyDB: $bdb_dir_ok]) ;;
  680.       esac
  681.       ;;
  682.     supplied-one )
  683.       MYSQL_CHECK_BDB_DIR([$bdb])
  684.       case $bdb_dir_ok in
  685.         source ) mode=compile ;;
  686.         installed ) mode=yes ;;
  687.         * ) AC_MSG_ERROR([didn't find valid BerkeleyDB: $bdb_dir_ok]) ;;
  688.       esac
  689.       ;;
  690.     search-* )
  691.       MYSQL_SEARCH_FOR_BDB
  692.       case $bdb_dir_ok in
  693.         source ) mode=compile ;;
  694.         installed ) mode=yes ;;
  695.         * )
  696.           # not found
  697.           case $mode in
  698.             *-yes ) AC_MSG_ERROR([no suitable BerkeleyDB found]) ;;
  699.             * ) mode=no ;;
  700.           esac
  701.          bdb_includes=
  702.          bdb_libs=
  703.           ;;
  704.       esac
  705.       ;;
  706.     *)
  707.       AC_MSG_ERROR([impossible case condition '$mode': please report this to bugs@lists.mysql.com])
  708.       ;;
  709.   esac
  711. dnl echo "DBG3: [$mode] bdb='$bdb'; incl='$bdb_includes'; lib='$bdb_libs'"
  712.   case $mode in
  713.     no )
  714.       AC_MSG_RESULT([Not using Berkeley DB])
  715.       ;;
  716.     yes )
  717.       have_berkeley_db="yes"
  718.       AC_MSG_RESULT([Using Berkeley DB in '$bdb_includes'])
  719.       ;;
  720.     compile )
  721.       have_berkeley_db="$bdb"
  722.       AC_MSG_RESULT([Compiling Berekeley DB in '$have_berkeley_db'])
  723.       ;;
  724.     * )
  725.       AC_MSG_ERROR([impossible case condition '$mode': please report this to bugs@lists.mysql.com])
  726.       ;;
  727.   esac
  729.   AC_SUBST(bdb_includes)
  730.   AC_SUBST(bdb_libs)
  731. ])
  733. AC_DEFUN([MYSQL_CHECK_INSTALLED_BDB], [
  734. dnl echo ["MYSQL_CHECK_INSTALLED_BDB ($1) ($2)"]
  735.   inc="$1"
  736.   lib="$2"
  737.   if test -f "$inc/db.h"
  738.   then
  739.     MYSQL_CHECK_BDB_VERSION([$inc/db.h],
  740.       [.*#define[  ]*], [[  ][  ]*])
  742.     if test X"$bdb_version_ok" = Xyes; then
  743.       save_LDFLAGS="$LDFLAGS"
  744.       LDFLAGS="-L$lib $LDFLAGS"
  745.       AC_CHECK_LIB(db,db_env_create, [
  746.         bdb_dir_ok=installed
  747.         MYSQL_TOP_BUILDDIR([inc])
  748.         MYSQL_TOP_BUILDDIR([lib])
  749.         bdb_includes="-I$inc"
  750.         bdb_libs="-L$lib -ldb"
  751.       ])
  752.       LDFLAGS="$save_LDFLAGS"
  753.     else
  754.       bdb_dir_ok="$bdb_version_ok"
  755.     fi
  756.   else
  757.     bdb_dir_ok="no db.h file in '$inc'"
  758.   fi
  759. ])
  761. AC_DEFUN([MYSQL_CHECK_BDB_DIR], [
  762. dnl ([$bdb])
  763. dnl echo ["MYSQL_CHECK_BDB_DIR ($1)"]
  764.   dir="$1"
  766.   MYSQL_CHECK_INSTALLED_BDB([$dir/include], [$dir/lib])
  768.   if test X"$bdb_dir_ok" != Xinstalled; then
  769.     # test to see if it's a source dir
  770.     rel="$dir/dist/RELEASE"
  771.     if test -f "$rel"; then
  772.       MYSQL_CHECK_BDB_VERSION([$rel], [], [=])
  773.       if test X"$bdb_version_ok" = Xyes; then
  774.         bdb_dir_ok=source
  775.         bdb="$dir"
  776.         MYSQL_TOP_BUILDDIR([dir])
  777.         bdb_includes="-I$dir/build_unix"
  778.         bdb_libs="-L$dir/build_unix -ldb"
  779.       else
  780.         bdb_dir_ok="$bdb_version_ok"
  781.       fi
  782.     else
  783.       bdb_dir_ok="'$dir' doesn't look like a BDB directory ($bdb_dir_ok)"
  784.     fi
  785.   fi
  786. ])
  788. AC_DEFUN([MYSQL_SEARCH_FOR_BDB], [
  789. dnl echo ["MYSQL_SEARCH_FOR_BDB"]
  790.   bdb_dir_ok="no BerkeleyDB found"
  792.   for test_dir in $srcdir/bdb $srcdir/db-*.*.* /usr/local/BerkeleyDB*; do
  793. dnl    echo "-----------> Looking at ($test_dir; `cd $test_dir && pwd`)"
  794.     MYSQL_CHECK_BDB_DIR([$test_dir])
  795.     if test X"$bdb_dir_ok" = Xsource || test X"$bdb_dir_ok" = Xinstalled; then
  796. dnl echo "-----------> Found it ($bdb), ($srcdir)"
  797. dnl     This is needed so that 'make distcheck' works properly (VPATH build).
  798. dnl     VPATH build won't work if bdb is not under the source tree; but in
  799. dnl     that case, hopefully people will just make and install inside the
  800. dnl     tree, or install BDB first, and then use the installed version.
  801. case "$bdb" in
  802. "$srcdir/"* ) bdb=`echo "$bdb" | sed -e "s,^$srcdir/,,"` ;;
  803. esac
  804.         break
  805.     fi
  806.   done
  807. ])
  809. dnl MYSQL_CHECK_BDB_VERSION takes 3 arguments:
  810. dnl     1)  the file to look in
  811. dnl     2)  the search pattern before DB_VERSION_XXX
  812. dnl     3)  the search pattern between DB_VERSION_XXX and the number
  813. dnl It assumes that the number is the last thing on the line
  814. AC_DEFUN([MYSQL_CHECK_BDB_VERSION], [
  815.   db_major=`sed -e '/^[$2]DB_VERSION_MAJOR[$3]/ !d' -e 's///' [$1]`
  816.   db_minor=`sed -e '/^[$2]DB_VERSION_MINOR[$3]/ !d' -e 's///' [$1]`
  817.   db_patch=`sed -e '/^[$2]DB_VERSION_PATCH[$3]/ !d' -e 's///' [$1]`
  818.   test -z "$db_major" && db_major=0
  819.   test -z "$db_minor" && db_minor=0
  820.   test -z "$db_patch" && db_patch=0
  822.   # This is ugly, but about as good as it can get
  823.   mysql_bdb=
  824.   if test $db_major -eq 3 && test $db_minor -eq 2 && test $db_patch -eq 3
  825.   then
  826.     mysql_bdb=h
  827.   elif test $db_major -eq 3 && test $db_minor -eq 2 && test $db_patch -eq 9
  828.   then
  829.     want_bdb_version="3.2.9a" # hopefully this will stay up-to-date
  830.     mysql_bdb=a
  831.   fi
  833.   if test -n "$mysql_bdb" && 
  834. grep "DB_VERSION_STRING.*:.*$mysql_bdb: " [$1] > /dev/null
  835.   then
  836.     bdb_version_ok=yes
  837.   else
  838.     bdb_version_ok="invalid version $db_major.$db_minor.$db_patch"
  839.     bdb_version_ok="$bdb_version_ok (must be version 3.2.3h or $want_bdb_version)"
  840.   fi
  841. ])
  843. AC_DEFUN([MYSQL_TOP_BUILDDIR], [
  844.   case "$[$1]" in
  845.     /* ) ;; # don't do anything with an absolute path
  846.     "$srcdir"/* )
  847.       # If BDB is under the source directory, we need to look under the
  848.       # build directory for bdb/build_unix.
  849.       # NOTE: I'm being lazy, and assuming the user did not specify
  850.       # something like --with-berkeley-db=bdb (it would be missing "./").
  851.       [$1]="$(top_builddir)/"`echo "$[$1]" | sed -e "s,^$srcdir/,,"`
  852.       ;;
  853.     * )
  854.       AC_MSG_ERROR([The BDB directory must be directly under the MySQL source directory, or be specified using the full path. ('$srcdir'; '$[$1]')])
  855.       ;;
  856.   esac
  857.   if test X"$[$1]" != "/"
  858.   then
  859.     [$1]=`echo $[$1] | sed -e 's,/$,,'`
  860.   fi
  861. ])
  863. dnl ---------------------------------------------------------------------------
  864. dnl END OF MYSQL_CHECK_BDB SECTION
  865. dnl ---------------------------------------------------------------------------
  867. dnl ---------------------------------------------------------------------------
  868. dnl Macro: MYSQL_CHECK_INNOBASE
  869. dnl Sets HAVE_INNOBASE_DB if --with-innobase is used
  870. dnl ---------------------------------------------------------------------------
  872. AC_DEFUN([MYSQL_CHECK_INNOBASE], [
  873.   AC_ARG_WITH([innobase],
  874.               [
  875.   --with-innobase         Use Innobase],
  876.               [innobase="$withval"],
  877.               [innobase=no])
  879.   AC_MSG_CHECKING([for Innobase])
  881.   have_innobase_db=no
  882.   innobase_includes=
  883.   innobase_libs=
  884.   case "$innobase" in
  885.     yes )
  886.       AC_MSG_RESULT([Using Innobase])
  887.       AC_DEFINE(HAVE_INNOBASE_DB)
  888.       have_innobase_db="yes"
  889.       innobase_includes="-I../innobase/include"
  890. dnl Some libs are listed several times, in order for gcc to sort out
  891. dnl circular references.
  892.       innobase_libs="
  893.  ../innobase/usr/libusr.a
  894.  ../innobase/odbc/libodbc.a
  895.  ../innobase/srv/libsrv.a
  896.  ../innobase/que/libque.a
  897.  ../innobase/dict/libdict.a
  898.  ../innobase/ibuf/libibuf.a
  899.  ../innobase/row/librow.a
  900.  ../innobase/pars/libpars.a
  901.  ../innobase/btr/libbtr.a
  902.  ../innobase/trx/libtrx.a
  903.  ../innobase/read/libread.a
  904.  ../innobase/usr/libusr.a
  905.  ../innobase/buf/libbuf.a
  906.  ../innobase/ibuf/libibuf.a
  907.  ../innobase/eval/libeval.a
  908.  ../innobase/log/liblog.a
  909.  ../innobase/fsp/libfsp.a
  910.  ../innobase/fut/libfut.a
  911.  ../innobase/fil/libfil.a
  912.  ../innobase/lock/liblock.a
  913.  ../innobase/mtr/libmtr.a
  914.  ../innobase/page/libpage.a
  915.  ../innobase/rem/librem.a
  916.  ../innobase/thr/libthr.a
  917.  ../innobase/com/libcom.a
  918.  ../innobase/sync/libsync.a
  919.  ../innobase/data/libdata.a
  920.  ../innobase/mach/libmach.a
  921.  ../innobase/ha/libha.a
  922.  ../innobase/dyn/libdyn.a
  923.  ../innobase/mem/libmem.a
  924.  ../innobase/sync/libsync.a
  925.  ../innobase/ut/libut.a
  926.  ../innobase/os/libos.a
  927.  ../innobase/ut/libut.a"
  929.       AC_CHECK_LIB(rt, aio_read, [innobase_libs="$innobase_libs -lrt"])
  930.       ;;
  931.     * )
  932.       AC_MSG_RESULT([Not using Innobase])
  933.       ;;
  934.   esac
  936.   AC_SUBST(innobase_includes)
  937.   AC_SUBST(innobase_libs)
  938. ])
  940. dnl ---------------------------------------------------------------------------
  941. dnl END OF MYSQL_CHECK_INNOBASE SECTION
  942. dnl ---------------------------------------------------------------------------
  944. dnl ---------------------------------------------------------------------------
  945. dnl Got this from the GNU tar 1.13.11 distribution
  946. dnl by Paul Eggert <eggert@twinsun.com>
  947. dnl ---------------------------------------------------------------------------
  949. dnl By default, many hosts won't let programs access large files;
  950. dnl one must use special compiler options to get large-file access to work.
  951. dnl For more details about this brain damage please see:
  952. dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
  954. dnl Written by Paul Eggert <eggert@twinsun.com>.
  956. dnl Internal subroutine of AC_SYS_LARGEFILE.
  957. dnl AC_SYS_LARGEFILE_FLAGS(FLAGSNAME)
  958. AC_DEFUN(AC_SYS_LARGEFILE_FLAGS,
  959.   [AC_CACHE_CHECK([for $1 value to request large file support],
  960.      ac_cv_sys_largefile_$1,
  961.      [if ($GETCONF LFS_$1) >conftest.1 2>conftest.2 && test ! -s conftest.2
  962.       then
  963.         ac_cv_sys_largefile_$1=`cat conftest.1`
  964.       else
  965. ac_cv_sys_largefile_$1=no
  966. ifelse($1, CFLAGS,
  967.   [case "$host_os" in
  968.    # HP-UX 10.20 requires -D__STDC_EXT__ with gcc 2.95.1.
  969. changequote(, )dnl
  970.    hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)
  971. changequote([, ])dnl
  972.      if test "$GCC" = yes; then
  973.        ac_cv_sys_largefile_CFLAGS=-D__STDC_EXT__
  974.      fi
  975.      ;;
  976.    # IRIX 6.2 and later require cc -n32.
  977. changequote(, )dnl
  978.    irix6.[2-9]* | irix6.1[0-9]* | irix[7-9].* | irix[1-9][0-9]*)
  979. changequote([, ])dnl
  980.      if test "$GCC" != yes; then
  981.        ac_cv_sys_largefile_CFLAGS=-n32
  982.      fi
  983.    esac
  984.    if test "$ac_cv_sys_largefile_CFLAGS" != no; then
  985.      ac_save_CC="$CC"
  986.      CC="$CC $ac_cv_sys_largefile_CFLAGS"
  987.      AC_TRY_LINK(, , , ac_cv_sys_largefile_CFLAGS=no)
  988.      CC="$ac_save_CC"
  989.    fi])
  990.       fi
  991.       rm -f conftest*])])
  993. dnl Internal subroutine of AC_SYS_LARGEFILE.
  994. dnl AC_SYS_LARGEFILE_SPACE_APPEND(VAR, VAL)
  995. AC_DEFUN(AC_SYS_LARGEFILE_SPACE_APPEND,
  996.   [case $2 in
  997.    no) ;;
  998.    ?*)
  999.      case "[$]$1" in
  1000.      '') $1=$2 ;;
  1001.      *) $1=[$]$1' '$2 ;;
  1002.      esac ;;
  1003.    esac])
  1005. dnl Internal subroutine of AC_SYS_LARGEFILE.
  1006. dnl AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, CACHE-VAR, COMMENT, CODE-TO-SET-DEFAULT)
  1007. AC_DEFUN(AC_SYS_LARGEFILE_MACRO_VALUE,
  1008.   [AC_CACHE_CHECK([for $1], $2,
  1009.      [$2=no
  1010. changequote(, )dnl
  1011.       $4
  1012.       for ac_flag in $ac_cv_sys_largefile_CFLAGS no; do
  1013. case "$ac_flag" in
  1014. -D$1)
  1015.   $2=1 ;;
  1016. -D$1=*)
  1017.   $2=`expr " $ac_flag" : '[^=]*=(.*)'` ;;
  1018. esac
  1019.       done
  1020. changequote([, ])dnl
  1021.       ])
  1022.    if test "[$]$2" != no; then
  1023.      AC_DEFINE_UNQUOTED([$1], [$]$2, [$3])
  1024.    fi])
  1026. AC_DEFUN(AC_SYS_LARGEFILE,
  1027.   [AC_REQUIRE([AC_CANONICAL_HOST])
  1028.    AC_ARG_ENABLE(largefile,
  1029.      [  --disable-large-files   Omit support for large files])
  1030.    if test "$enable_largefile" != no; then
  1031.      AC_CHECK_TOOL(GETCONF, getconf)
  1032.      AC_SYS_LARGEFILE_FLAGS(CFLAGS)
  1033.      AC_SYS_LARGEFILE_FLAGS(LDFLAGS)
  1034.      AC_SYS_LARGEFILE_FLAGS(LIBS)
  1036.      for ac_flag in $ac_cv_sys_largefile_CFLAGS no; do
  1037.        case "$ac_flag" in
  1038.        no) ;;
  1039.        -D_FILE_OFFSET_BITS=*) ;;
  1040.        -D_LARGEFILE_SOURCE | -D_LARGEFILE_SOURCE=*) ;;
  1041.        -D_LARGE_FILES | -D_LARGE_FILES=*) ;;
  1042.        -D?* | -I?*)
  1043.  AC_SYS_LARGEFILE_SPACE_APPEND(CPPFLAGS, "$ac_flag") ;;
  1044.        *)
  1045.  AC_SYS_LARGEFILE_SPACE_APPEND(CFLAGS, "$ac_flag") ;;
  1046.        esac
  1047.      done
  1048.      AC_SYS_LARGEFILE_SPACE_APPEND(LDFLAGS, "$ac_cv_sys_largefile_LDFLAGS")
  1049.      AC_SYS_LARGEFILE_SPACE_APPEND(LIBS, "$ac_cv_sys_largefile_LIBS")
  1050.      AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS,
  1051.        ac_cv_sys_file_offset_bits,
  1052.        [Number of bits in a file offset, on hosts where this is settable.],
  1053.        [case "$host_os" in
  1054. # HP-UX 10.20 and later
  1055. hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)
  1056.   ac_cv_sys_file_offset_bits=64 ;;
  1057. esac])
  1058.      AC_SYS_LARGEFILE_MACRO_VALUE(_LARGEFILE_SOURCE,
  1059.        ac_cv_sys_largefile_source,
  1060.        [Define to make fseeko etc. visible, on some hosts.],
  1061.        [case "$host_os" in
  1062. # HP-UX 10.20 and later
  1063. hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)
  1064.   ac_cv_sys_largefile_source=1 ;;
  1065. esac])
  1066.      AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES,
  1067.        ac_cv_sys_large_files,
  1068.        [Define for large files, on AIX-style hosts.],
  1069.        [case "$host_os" in
  1070. # AIX 4.2 and later
  1071. aix4.[2-9]* | aix4.1[0-9]* | aix[5-9].* | aix[1-9][0-9]*)
  1072.   ac_cv_sys_large_files=1 ;;
  1073. esac])
  1074.    fi
  1075.   ])