开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
ld.script.in
资源名称：linux-2.4.20.tar.gz　[点击查看]
上传用户：jlfgdled
上传日期：2013-04-10
资源大小：33168k
文件大小：4k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

ld.script.in：源码内容
  1. OUTPUT_ARCH(mips)
  2. ENTRY(kernel_entry)
  3. SECTIONS
  4. {
  5.   /* Read-only sections, merged into text segment: */
  6.   . = @@LOADADDR@@;
  7.   .init          : { *(.init) } =0
  8.   .text      :
  9.   {
  10.     _ftext = . ;
  11.     *(.text)
  12.     *(.rodata)
  13.     *(.rodata1)
  14.     /* .gnu.warning sections are handled specially by elf32.em.  */
  15.     *(.gnu.warning)
  16.   } =0
  17.   .kstrtab : { *(.kstrtab) }
  19.   . = ALIGN(16); /* Exception table */
  20.   __start___ex_table = .;
  21.   __ex_table : { *(__ex_table) }
  22.   __stop___ex_table = .;
  24.   __start___dbe_table = .; /* Exception table for data bus errors */
  25.   __dbe_table : { *(__dbe_table) }
  26.   __stop___dbe_table = .;
  28.   __start___ksymtab = .; /* Kernel symbol table */
  29.   __ksymtab : { *(__ksymtab) }
  30.   __stop___ksymtab = .;
  32.   _etext = .;
  34.   . = ALIGN(8192);
  35.   .data.init_task : { *(.data.init_task) }
  37.   /* Startup code */
  38.   . = ALIGN(4096);
  39.   __init_begin = .;
  40.   .text.init : { *(.text.init) }
  41.   .data.init : { *(.data.init) }
  42.   . = ALIGN(16);
  43.   __setup_start = .;
  44.   .setup.init : { *(.setup.init) }
  45.   __setup_end = .;
  46.   __initcall_start = .;
  47.   .initcall.init : { *(.initcall.init) }
  48.   __initcall_end = .;
  49.   . = ALIGN(4096); /* Align double page for init_task_union */
  50.   __init_end = .;
  52.   . = ALIGN(4096);
  53.   .data.page_aligned : { *(.data.idt) }
  55.   . = ALIGN(32);
  56.   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  58.   .fini      : { *(.fini)    } =0
  59.   .reginfo : { *(.reginfo) }
  60.   /* Adjust the address for the data segment.  We want to adjust up to
  61.      the same address within the page on the next page up.  It would
  62.      be more correct to do this:
  63.        . = .;
  64.      The current expression does not correctly handle the case of a
  65.      text segment ending precisely at the end of a page; it causes the
  66.      data segment to skip a page.  The above expression does not have
  67.      this problem, but it will currently (2/95) cause BFD to allocate
  68.      a single segment, combining both text and data, for this case.
  69.      This will prevent the text segment from being shared among
  70.      multiple executions of the program; I think that is more
  71.      important than losing a page of the virtual address space (note
  72.      that no actual memory is lost; the page which is skipped can not
  73.      be referenced).  */
  74.   . = .;
  75.   .data    :
  76.   {
  77.     _fdata = . ;
  78.     *(.data)
  80.    /* Align the initial ramdisk image (INITRD) on page boundaries. */
  81.    . = ALIGN(4096);
  82.    __rd_start = .;
  83.    *(.initrd)
  84.    __rd_end = .;
  85.    . = ALIGN(4096);
  87.     CONSTRUCTORS
  88.   }
  89.   .data1   : { *(.data1) }
  90.   _gp = . + 0x8000;
  91.   .lit8 : { *(.lit8) }
  92.   .lit4 : { *(.lit4) }
  93.   .ctors         : { *(.ctors)   }
  94.   .dtors         : { *(.dtors)   }
  95.   .got           : { *(.got.plt) *(.got) }
  96.   .dynamic       : { *(.dynamic) }
  97.   /* We want the small data sections together, so single-instruction offsets
  98.      can access them all, and initialized data all before uninitialized, so
  99.      we can shorten the on-disk segment size.  */
  100.   .sdata     : { *(.sdata) }
  101.   . = ALIGN(4);
  102.   _edata  =  .;
  103.   PROVIDE (edata = .);
  105.   __bss_start = .;
  106.   _fbss = .;
  107.   .sbss      : { *(.sbss) *(.scommon) }
  108.   .bss       :
  109.   {
  110.    *(.dynbss)
  111.    *(.bss)
  112.    *(COMMON)
  113.    .  = ALIGN(4);
  114.   _end = . ;
  115.   PROVIDE (end = .);
  116.   }
  118.   /* Sections to be discarded */
  119.   /DISCARD/ :
  120.   {
  121.         *(.text.exit)
  122.         *(.data.exit)
  123.         *(.exitcall.exit)
  124.   }
  126.   /* This is the MIPS specific mdebug section.  */
  127.   .mdebug : { *(.mdebug) }
  128.   /* These are needed for ELF backends which have not yet been
  129.      converted to the new style linker.  */
  130.   .stab 0 : { *(.stab) }
  131.   .stabstr 0 : { *(.stabstr) }
  132.   /* DWARF debug sections.
  133.      Symbols in the .debug DWARF section are relative to the beginning of the
  134.      section so we begin .debug at 0.  It's not clear yet what needs to happen
  135.      for the others.   */
  136.   .debug          0 : { *(.debug) }
  137.   .debug_srcinfo  0 : { *(.debug_srcinfo) }
  138.   .debug_aranges  0 : { *(.debug_aranges) }
  139.   .debug_pubnames 0 : { *(.debug_pubnames) }
  140.   .debug_sfnames  0 : { *(.debug_sfnames) }
  141.   .line           0 : { *(.line) }
  142.   /* These must appear regardless of  .  */
  143.   .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
  144.   .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
  145.   .comment : { *(.comment) }
  146.   .note : { *(.note) }
  147. }