开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Linux/Unix编程 > 查看源码
e100lpslave.S
资源名称：linux-2.4.20.tar.gz　[点击查看]
上传用户：jlfgdled
上传日期：2013-04-10
资源大小：33168k
文件大小：11k
源码类别：

Linux/Unix编程

开发平台：

Unix_Linux

e100lpslave.S：源码内容
  1. ;; $Id: e100lpslave.S,v 1.3 2001/06/21 16:55:26 olof Exp $
  2. ;;
  3. ;; Etrax100 slave network<->parport forwarder
  4. ;;
  5. ;; Copyright (c) 1999 Bjorn Wesen, Axis Communications AB
  6. ;;
  7. ;; We got 784 bytes (par loader size) to do DMA forwarding
  8. ;; between DMA0/1 (ethernet) and DMA3/4 (par port 0 RX/1 TX)
  9. ;;
  11. #include <linux/config.h>
  12. #if 0
  13. #define ASSEMBLER_MACROS_ONLY
  14. #endif
  15. #include <asm/sv_addr_ag.h>
  17. #define BUFSIZE 0x600
  19. ;; R_IRQ_READ2
  21. #define DMA1EOPBIT 3
  22. #define DMA0EOPBIT 1
  23. #define DMA3EOPBIT 7
  24. #define DMA4DESCBIT 8
  26. ;; R_IRQ_READ0
  28. #define PAR0ECPCMDBIT 11
  30. ;; get host CMDs
  32. #include "e100lpslave.h"
  34. start:
  35. ;; disable interrupts. we are not going to use them at all.
  37. di
  39. ;; setup DMA connections and port configuration
  41. movu.w 0x84, r0 ; DMA2/3/4/5 to par ports
  42. move.d r0, [R_GEN_CONFIG]
  44. ;; setup port PA dirs and turn on the LED to show were alive
  46. movu.w 0x0cfb, r0 ; PA2-PA3 out, PA2 inactive
  47. move.d r0, [R_PORT_PA_SET]
  49. ;; enable MDIO output pin
  50. moveq IO_STATE(R_NETWORK_MGM_CTRL, mdoe, enable), r0
  51. move.d r0, [R_NETWORK_MGM_CTRL]
  53. ;; accept broadcast frames, and enable station address 0
  54. moveq IO_STATE(R_NETWORK_REC_CONFIG, broadcast, receive) | 
  55. IO_STATE(R_NETWORK_REC_CONFIG, ma0, enable), r0
  56. move.d r0, [R_NETWORK_REC_CONFIG]
  58. ;; use MII CLK mode, and enable the controller
  59. moveq IO_STATE(R_NETWORK_GEN_CONFIG, phy, mii_clk) | 
  60. IO_STATE(R_NETWORK_GEN_CONFIG, enable, on), r0
  61. move.d r0, [R_NETWORK_GEN_CONFIG]
  63. move.d IO_STATE(R_PAR0_CONFIG, ioe,     noninv)    |  
  64. IO_STATE(R_PAR0_CONFIG, iseli,   noninv)    |  
  65. IO_STATE(R_PAR0_CONFIG, iautofd, noninv)    |  
  66. IO_STATE(R_PAR0_CONFIG, istrb,   noninv)    |  
  67. IO_STATE(R_PAR0_CONFIG, iinit,   noninv)    |  
  68. IO_STATE(R_PAR0_CONFIG, iperr,   noninv)    |  
  69. IO_STATE(R_PAR0_CONFIG, iack,    noninv)    |  
  70. IO_STATE(R_PAR0_CONFIG, ibusy,   noninv)    |  
  71. IO_STATE(R_PAR0_CONFIG, ifault,  noninv)    |  
  72. IO_STATE(R_PAR0_CONFIG, isel,    noninv)    |  
  73. IO_STATE(R_PAR0_CONFIG, dma, enable)        |  
  74. IO_STATE(R_PAR0_CONFIG, rle_in, disable)    |  
  75. IO_STATE(R_PAR0_CONFIG, rle_out, disable)   |  
  76. IO_STATE(R_PAR0_CONFIG, enable, on)         |  
  77. IO_STATE(R_PAR0_CONFIG, force, on)          |  
  78. IO_STATE(R_PAR0_CONFIG, mode, ecp_rev), r0 ; Reverse ECP - PAR0 is RX
  80. move.d r0, [R_PAR0_CONFIG]
  82. move.d IO_STATE(R_PAR1_CONFIG, ioe,     noninv)    |  
  83. IO_STATE(R_PAR1_CONFIG, iseli,   noninv)    |  
  84. IO_STATE(R_PAR1_CONFIG, iautofd, noninv)    |  
  85. IO_STATE(R_PAR1_CONFIG, istrb,   noninv)    |  
  86. IO_STATE(R_PAR1_CONFIG, iinit,   noninv)    |  
  87. IO_STATE(R_PAR1_CONFIG, iperr,   inv)       |  
  88. IO_STATE(R_PAR1_CONFIG, iack,    noninv)    |  
  89. IO_STATE(R_PAR1_CONFIG, ibusy,   noninv)    |  
  90. IO_STATE(R_PAR1_CONFIG, ifault,  noninv)    |  
  91. IO_STATE(R_PAR1_CONFIG, isel,    noninv)    |  
  92. IO_STATE(R_PAR1_CONFIG, dma, enable)        |  
  93. IO_STATE(R_PAR1_CONFIG, rle_in, disable)    |  
  94. IO_STATE(R_PAR1_CONFIG, rle_out, disable)   |  
  95. IO_STATE(R_PAR1_CONFIG, enable, on)         |  
  96. IO_STATE(R_PAR1_CONFIG, force, on)          |  
  97. IO_STATE(R_PAR1_CONFIG, mode, ecp_fwd), r0 ; Forward ECP - PAR1 is TX
  99. move.d r0, [R_PAR1_CONFIG]
  101. moveq IO_FIELD(R_PAR1_DELAY, setup, 0), r0    ; setup time of value * 160 + 20 == 20 ns
  102. move.d r0, [R_PAR1_DELAY]
  104. ;; we got four descriptors, that can be active at the same time:
  105. ;; 1) from network
  106. ;; 2) to parport
  107. ;; 3) from parport
  108. ;; 4) to network
  109. ;;
  110. ;; we got four buffers, each can hold a max packet (we use 1536 bytes)
  111. ;; buffers 1 and 2 are used from network to parport, while
  112. ;; buffers 3 and 4 are used from parport to network.
  113. ;; 
  114. ;; a double buffering scheme is used, so that new data can be read
  115. ;; into a buffer pair while the last data is written out from the
  116. ;; last buffer. if the read buffer is done before the write buffer,
  117. ;; the reading will halt until the writing is done, at which point
  118. ;; writing starts from the newly read and reading can start with
  119. ;; the newly written.
  120. ;; 
  122. move.d R_DMA_CH0_FIRST, r1   ; we use this as base for subsequent DMA ops
  123. moveq IO_STATE(R_DMA_CH1_CMD, cmd, start), r6
  124. move.d FN1desc, r7
  125. move.d R_IRQ_READ0, r9
  127. ;; start receiving from network
  129. jsr startdmaFPTN
  130. jsr startdmaFNTP
  134. ;; ------------------- MAIN LOOP
  136. ;; IRQ bits: parport rcv is par0_ecp_cmd, then dma3_eop
  137. ;;              network rcv is dma1_eop
  138. ;;              parport tx  is dma4_desc
  139. ;;              network tx  is dma0_eop
  141. mainloop:
  143. ;; ------- first handle the parport -> network link
  145. ;; check if we got something from the parport
  147. move.d [r9], r0 ; r0 <- *R_IRQ_READ0
  148. btstq PAR0ECPCMDBIT, r0
  149. bpl noparecp
  150. nop
  152. ;; ack it by reading PAR0_STATUS_DATA
  154. move.d [R_PAR0_STATUS_DATA], r0
  156. ;; trigger EOP on DMA3 (par0 incoming channel)
  158. moveq IO_STATE(R_SET_EOP, ch3_eop, set), r0
  159. move.d r0, [R_SET_EOP]
  161. noparecp:
  163. ;; if we simultaneously have parport rx EOP and
  164. ;; network TX eop, we can swap buffers and start a new RX/TX
  166. move.d [r9 + (R_IRQ_READ2 - R_IRQ_READ0)], r0
  167. btstq DMA3EOPBIT, r0 ; check parport rx
  168. bpl noswap1
  169. btstq DMA0EOPBIT, r0 ; check network tx
  170. bpl noswap1
  171. nop
  173. ;; prepare to swap buffer ptrs (FN3b <-> TN4b)
  175. move.d [r4 = r7 + 56], r0; FP3b
  176. move.d [r3 = r7 + 72], r2; TN4b
  178. ;; but first check if this was a Host Command Packet
  180. move.d [r0], r5 ; r5 <- first 4 bytes in PAR-received packet
  181. bne handle_command ; if non-zero, it was a host command
  182. addq 4, r0 ; skip command (in delay slot - handle_command requires this)
  183. move.d r0, [r3] ; write to To Network descriptor
  184. subq 4, r2 ; undo the skipping done last swap
  185. move.d r2, [r4] ; write to From Parport descriptor
  187. ;; clear the interrupts
  189. moveq IO_STATE(R_DMA_CH0_CLR_INTR, clr_eop, do), r0
  190. move.b r0, [r1 + (R_DMA_CH0_CLR_INTR - R_DMA_CH0_FIRST)]
  191. move.b r0, [r1 + (R_DMA_CH3_CLR_INTR - R_DMA_CH0_FIRST)]
  193. ;; copy received length to outgoing network length
  195. move.w [r7 + 60], r0 ; FPhlen
  196. subq 4, r0 ; skip command
  197. move.w r0, [r7 + 64] ; TN4desc
  199. ;; restart DMAs
  201. jsr startdmaFPTN
  203. #ifdef CONFIG_ETRAX_ETHERNET_LPSLAVE_HAS_LEDS
  204. #if defined(CONFIG_ETRAX_NETWORK_LED_ON_WHEN_LINK)
  205. ;; Turn off the LED signaling an outgoing network packet
  206. movu.b [LEDOff], r0
  207. #elif defined(CONFIG_ETRAX_NETWORK_LED_ON_WHEN_ACTIVITY)
  208. ;; Light the LED signaling an outgoing network packet
  209. movu.b [LEDAmber], r0
  210. #else
  211. #error "Define either CONFIG_ETRAX_NETWORK_LED_ON_WHEN_LINK or CONFIG_ETRAX_NETWORK_LED_ON_WHEN_ACTIVITY"
  212. #endif 
  213. move.b r0, [R_PORT_PA_DATA]
  214. move.d 0x00011000, r0
  215. move.d r0,[LEDCount]
  216. #endif
  218. noswap1:
  219. ;; ----- now check the network -> parport link
  222. ;; if we simultaneously have network rx EOP and
  223. ;; parport TX desc, we can swap buffers and start a new RX/TX
  225. move.d [r9 + (R_IRQ_READ2 - R_IRQ_READ0)], r0
  226. btstq DMA1EOPBIT, r0 ; check network rx
  227. bpl noswap2
  228. btstq DMA4DESCBIT, r0 ; check parport tx
  229. bpl noswap2
  230. nop
  232. ;; prepare to swap buffer ptrs (FP1b <-> TP2b)
  234. move.d [r4 = r7 +  8], r0; FN1b
  235. move.d [r3 = r7 + 24], r2; TP2b
  236. move.d r0, [r3] ; write to To Parport descriptor
  237. move.d r2, [r4] ; write to From Network descriptor
  239. ;; clear the interrupts
  241. moveq IO_STATE(R_DMA_CH1_CLR_INTR, clr_eop, do) | 
  242. IO_STATE(R_DMA_CH1_CLR_INTR, clr_descr, do), r0
  243. move.b r0, [r1 + (R_DMA_CH1_CLR_INTR - R_DMA_CH0_FIRST)]
  244. move.b r0, [r1 + (R_DMA_CH4_CLR_INTR - R_DMA_CH0_FIRST)]
  246. ;; copy received network length to outgoing parport length
  248. move.w [r7 + 12], r0 ; FNhlen
  249. move.w r0, [r7 + 16] ; TP2desc
  251. ;; restart DMAs
  253. jsr startdmaFNTP
  254. #if 0
  255. #ifdef CONFIG_ETRAX_ETHERNET_LPSLAVE_HAS_LEDS
  256. ;; Light the LED signaling an incoming networkpacket
  257. movu.b 0xFB, r0
  258. move.b r0, [R_PORT_PA_DATA]
  259. move.d 0x00010000, r0
  260. move.d r0,[LEDCount]
  261. #endif
  262. #endif
  264. noswap2:
  265. #ifdef CONFIG_ETRAX_ETHERNET_LPSLAVE_HAS_LEDS
  267. ;; Count down LED counter, and turn off the network LED if required
  268. move.d [LEDCount], r0
  269. beq mainloop
  270. nop
  272. subq 1, r0
  273. move.d r0, [LEDCount]
  274. bne mainloop
  275. nop
  277. #if defined(CONFIG_ETRAX_NETWORK_LED_ON_WHEN_LINK)
  278. ;; Light the network LED , and start over the main loop
  279. movu.b [LEDAmber], r0
  280. #elif defined(CONFIG_ETRAX_NETWORK_LED_ON_WHEN_ACTIVITY)
  281. ;; Turn off the network LED, and start over the main loop
  282. movu.b [LEDOff], r0
  283. #else
  284. #error "Define either CONFIG_ETRAX_NETWORK_LED_ON_WHEN_LINK or CONFIG_ETRAX_NETWORK_LED_ON_WHEN_ACTIVITY"
  285. #endif
  286. move.b r0, [R_PORT_PA_DATA]
  287. #endif
  289. ba mainloop
  290. nop
  292. ;; --- some useful subroutines.
  294. handle_command:
  295. ;; handle command. we also need to clear the PAR0 RX EOP IRQ, and 
  296. ;; restart the PAR0 dma. command is in R5, packet after cmd is in R0
  298. moveq IO_STATE(R_DMA_CH3_CLR_INTR, clr_eop, do), r2
  299. move.b r2, [r1 + (R_DMA_CH3_CLR_INTR - R_DMA_CH0_FIRST)]
  301. cmpq HOST_CMD_SETMAC, r5
  302. bne no_setmac
  303. nop
  305. ;; copy station address (6 bytes) from packet to hardware
  307. move.d [r0+], r2
  308. move.d R_NETWORK_SA_0, r3
  309. move.d r2, [r3]
  310. move.w [r0], r2
  311. move.w r2, [r3 + 4] 
  313. no_setmac:
  314. move noswap1, SRP
  315. ba startdmaFP
  316. nop
  318. ;; start DMAs, from parport and to network
  320. startdmaFPTN:
  322. ;; start transmitting to the network (CH0)
  324. move.d TN4desc, r8
  325. move.d r8, [r1] ; TN4desc -> FIRST0
  326. move.b r6, [r1 + (R_DMA_CH0_CMD - R_DMA_CH0_FIRST)] ; start -> CMD0
  328. startdmaFP:
  330. ;; start receiving from parport (CH3)
  332. move.d FP3desc, r8
  333. move.d r8, [r1 + (R_DMA_CH3_FIRST - R_DMA_CH0_FIRST)]  ; FP3desc -> FIRST3
  334. move.b r6, [r1 + (R_DMA_CH3_CMD - R_DMA_CH0_FIRST)] ; start -> CMD3
  336. ret
  337. nop
  339. ;; start DMAs, from network and to parport
  341. startdmaFNTP:
  343. ;; start transmitting to the parport (CH4)
  345. move.d TP2desc, r8
  346. move.d r8, [r1 + (R_DMA_CH4_FIRST - R_DMA_CH0_FIRST)] ; TP2desc -> FIRST4
  347. move.b r6, [r1 + (R_DMA_CH4_CMD - R_DMA_CH0_FIRST)] ; start -> CMD4
  349. ;; start receiving from network (CH1) (r7 already contains FN1desc)
  351. move.d r7, [r1 + (R_DMA_CH1_FIRST - R_DMA_CH0_FIRST)]  ; FN1desc -> FIRST1
  352. move.b r6, [r1 + (R_DMA_CH1_CMD - R_DMA_CH0_FIRST)] ; start -> CMD1
  354. ret
  355. nop
  357. ;; --- DMA descriptors - each descriptor is 4 longwords (16 bytes)
  358. ;; DONT MOVE THESE AROUND. Due to the as/ld "hole-in-the-head",
  359. ;; we cant write stuff like (TP2b - TP2desc) but the offsets
  360. ;; have to be hardcoded.
  362. .data
  364. ;; 0 from network
  365. FN1desc:
  366. .word BUFSIZE ; sw_len
  367. .word 0x0001 ; ctrl, d_eol is only flag we need
  368. .dword 0 ; next
  369. FN1b: .dword buffers ; buffer 1 8
  370. .word 0 ; hw_len
  371. .word 0 ; status
  373. ;; 16 to parport
  374. TP2desc:
  375. .word 2 ; sw_len, filled in by code 
  376. .word 0x0004 ; ctrl, d_wait because ecp cmd in next
  377. .dword TP2desc2 ; next
  378. TP2b: .dword buffers + BUFSIZE ; buffer 2 24
  379. .word 0 ; hw_len
  380. .word 0 ; status
  382. ;; 32 to parport second descriptor, for the ECP command
  383. TP2desc2:
  384. .word 0x0001 ; sw_len, 1 byte (ecp command) 
  385. .word 0x0019 ; ctrl, d_ecp | d_eol | d_int
  386. .dword 0 ; next
  387. .dword TP2desc2 ; buffer, dont care
  388. .word 0 ; hw_len
  389. .word 0 ; status
  391. ;; 48 from parport
  392. FP3desc:
  393. .word BUFSIZE ; sw_len
  394. .word 0x0001 ; ctrl, d_eol is only flag we need
  395. .dword 0 ; next
  396. FP3b: .dword buffers + BUFSIZE * 2 ; 56 buffer 3
  397. FPhlen: .word 0 ; 60 hw_len
  398. .word 0 ; status
  400. ;; 64 to network
  401. TN4desc:
  402. .word 2 ; sw_len, filled in by code 
  403. .word 0x0007 ; ctrl, d_eop | d_eol | d_wait
  404. .dword 0 ; next
  405. TN4b: .dword buffers + BUFSIZE * 3 + 4 ; 72 buffer 4 (the +4 is to offset the anti-skipping)
  406. .word 0 ; hw_len
  407. .word 0 ; status
  409. #ifdef CONFIG_ETRAX_ETHERNET_LPSLAVE_HAS_LEDS
  410. LEDCount:
  411. .dword 0
  412. LEDOff:
  413. .word 0xff
  414. LEDGreen:
  415. .word 0xfb
  416. LEDRed:
  417. .word 0xf7
  418. LEDAmber:
  419. .word 0xf3
  420. LED:
  421. .word 0xf7
  422. #endif
  424. ;; after the prog we put the buffers. not in the asm program, we just use
  425. ;; the address generated
  427. buffers:
  429. ;; END